Programme d’exemple 3: MM_S3_Vis_Path

Vous consultez actuellement la documentation pour la dernière version (2.1.2). Pour accéder à une autre version, cliquez sur le bouton "Changer de version" situé dans le coin supérieur droit de la page.

■ Si vous n’êtes pas sûr de la version du produit que vous utilisez, veuillez contacter le support technique Mech-Mind pour obtenir de l’aide.

Présentation du programme

Description

Le robot déclenche l’exécution du projet Mech-Vision, puis obtient la trajectoire planifiée pour la prise et la dépose.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/FANUC/sample/MM_S3_Vis_Path path.

Project

Projet Mech-Vision

Le projet Mech-Vision doit contenir une étape Planification de trajectoire, et le paramètre Type de port de l’étape Sortie doit être défini sur Prédéfini (trajectoire robot).

Prerequisites

  1. Vous avez configuré la communication de l’Interface Standard.

  2. Étalonnage automatique est terminé.
Ce programme d’exemple est fourni uniquement à titre de référence. Avant d’utiliser le programme, veuillez le modifier en fonction du scénario réel.

Description du programme

Cette partie décrit le programme d’exemple MM_S3_Vis_Path.

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project and get planned path ;
   4:  !Mech-Mind, 2023-12-25 ;
   5:  !-------------------------------- ;
   6:   ;
   7:  !set current uframe NO. to 0 ;
   8:  UFRAME_NUM=0 ;
   9:  !set current tool NO. to 1 ;
  10:  UTOOL_NUM=1 ;
  11:  !move to robot home position ;
  12:J P[1] 100% FINE    ;
  13:  !initialize communication ;
  14:  !parameters(initialization is ;
  15:  !required only once) ;
  16:  CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  17:  !move to image-capturing position ;
  18:L P[2] 1000mm/sec FINE    ;
  19:  !trigger NO.1 Mech-Vision project ;
  20:  CALL MM_START_VIS(1,0,2,10) ;
  21:  !get planned path from NO.1 ;
  22:  !Mech-Vision project; 2nd ;
  23:  !argument (1) means getting pose ;
  24:  !in JPs ;
  25:  CALL MM_GET_VISP(1,1,51,52,53) ;
  26:  !check whether planned path has ;
  27:  !been got from Mech-Vision ;
  28:  !successfully ;
  29:  IF R[53]<>1103,JMP LBL[99] ;
  30:  !save waypoints of the planned ;
  31:  !path to local variables one ;
  32:  !by one ;
  33:  CALL MM_GET_JPS(1,60,70,80) ;
  34:  CALL MM_GET_JPS(2,61,71,81) ;
  35:  CALL MM_GET_JPS(3,62,72,82) ;
  36:  !follow the planned path to pick ;
  37:  !move to approach waypoint ;
  38:  !of picking ;
  39:J PR[60] 50% FINE    ;
  40:  !move to picking waypoint ;
  41:J PR[61] 10% FINE    ;
  42:  !add object grasping logic here, ;
  43:  !such as "DO[1]=ON" ;
  44:  PAUSE ;
  45:  !move to departure waypoint ;
  46:  !of picking ;
  47:J PR[62] 50% FINE    ;
  48:  !move to intermediate waypoint ;
  49:  !of placing ;
  50:J P[3] 50% CNT100    ;
  51:  !move to approach waypoint ;
  52:  !of placing ;
  53:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  54:  !move to placing waypoint ;
  55:L P[4] 300mm/sec FINE    ;
  56:  !add object releasing logic here, ;
  57:  !such as "DO[1]=OFF" ;
  58:  PAUSE ;
  59:  !move to departure waypoint ;
  60:  !of placing ;
  61:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  62:  !move back to robot home position ;
  63:J P[1] 100% FINE    ;
  64:  END ;
  65:   ;
  66:  LBL[99:vision error] ;
  67:  !add error handling logic here ;
  68:  !according to different ;
  69:  !error codes ;
  70:  !e.g.: status=1003 means no ;
  71:  !point cloud in ROI ;
  72:  !e.g.: status=1002 means no ;
  73:  !vision results ;
  74:  PAUSE ;

Le flux de travail correspondant au code du programme d’exemple ci‑dessus est illustré dans la figure ci‑dessous.

sample3

Le tableau ci‑dessous explique le programme ci‑dessus. Vous pouvez cliquer sur l’hyperlien du nom de commande pour en afficher la description détaillée.

Feature Code and description

Définir le repère de référence

 
   7:  !set current uframe NO. to 0 ;
   8:  UFRAME_NUM=0 ;
   9:  !set current tool NO. to 1 ;
  10:  UTOOL_NUM=1 ;

  • UFRAME_NUM=0: Définit le repère utilisateur sélectionné sur 0. 0 indique le repère monde.

  • UTOOL_NUM=1: Définit le repère outil sélectionné sur 1. Vous devez spécifier le repère outil représenté par 1.

Les deux instructions ci‑dessus définissent les repères utilisateur et outil sélectionnés.

Aller à la position d’origine

 
  11:  !move to robot home position ;
  12:J P[1] 100% FINE    ;

  • J: La commande de mouvement en articulation du robot, indiquant que le robot se déplace le long d’un arc vers une position spécifiée.

  • P[1]: Spécifie la position cible vers laquelle le robot se déplace, c’est‑à‑dire la position d’origine enseignée. La position d’origine est généralement une position sûre où le robot est éloigné des objets de travail et de l’équipement environnant.

  • 100%: Le pourcentage de la vitesse maximale relative de déplacement.

  • FINE: Le robot marque une brève pause à l’arrivée sur une position cible avant de passer à la suivante.

L’instruction complète indique que le robot se déplace vers la position d’origine enseignée en utilisant un mouvement en articulation.

Vous devez enseigner à l’avance la position d’origine (P[1]). Pour des instructions détaillées, reportez‑vous au manuel officiel FANUC.

Initialiser les paramètres de communication

 
  13:  !initialize communication ;
  14:  !parameters(initialization is ;
  15:  !required only once) ;
  16:  CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;

  • MM_INIT_SKT: La commande pour initialiser la communication.

  • '8': Le numéro de port du robot.

  • '127.0.0.1': L’adresse IP de l’IPC.

  • 50000: Le numéro de port de l’IPC.

  • 5: Indique que le délai d’expiration de communication est de 5 minutes.

L’instruction complète indique que le robot établit la connexion avec le système de vision en spécifiant, via la commande MM_INIT_SKT, l’adresse IP, le numéro de port et le délai d’expiration de la cible de communication (l’IPC).

Veuillez modifier l’adresse IP et le numéro de port de l’IPC selon la situation réelle. L’adresse IP et le numéro de port doivent être cohérents avec ceux définis dans le système de vision.

Aller à la position de capture d’image

 
  17:  !move to image-capturing position ;
  18:L P[2] 1000mm/sec FINE    ;

  • L: La commande de mouvement linéaire du robot. Cette commande indique de déplacer le robot le long d’une trajectoire linéaire vers une position spécifiée.

  • P[2]: Spécifie la position cible vers laquelle le robot se déplace, à savoir la position de capture d’image enseignée. La position de capture d’image correspond à la position du robot à partir de laquelle la caméra montée sur le robot capture des images. À cette position, le bras du robot ne doit pas obstruer le champ de vision de la caméra.

L’ensemble de la commande indique que le robot se déplace en mouvement linéaire vers la position de capture d’image, avec une vitesse de 1000 mm/s.

Vous devez enseigner à l’avance la position de capture d’image (P[2]). Pour des instructions détaillées, reportez‑vous au manuel officiel FANUC.

Déclencher l’exécution du projet Mech-Vision

 
  19:  !trigger NO.1 Mech-Vision project ;
  20:  CALL MM_START_VIS(1,0,2,10) ;

  • MM_START_VIS: La commande pour déclencher l’exécution du projet Mech-Vision.

  • 1: L’ID du projet Mech-Vision.

  • 0: Il est attendu que le projet Mech-Vision renvoie tous les points de passage.

  • 2: Spécifie que la pose de la bride du robot doit être fournie au projet Mech-Vision.

  • 10: Le registre de position PR[10], qui stocke des positions articulaires personnalisées. Dans ce programme d’exemple, ces positions n’ont pas d’utilité pratique, mais l’ID du registre de position doit être spécifié.

L’instruction complète indique que le robot déclenche le système de vision pour exécuter le projet Mech-Vision avec l’ID 1 et s’attend à ce que le projet Mech-Vision renvoie tous les points de passage.

Obtenir la trajectoire planifiée

 
  21:  !get planned path from NO.1 ;
  22:  !Mech-Vision project; 2nd ;
  23:  !argument (1) means getting pose ;
  24:  !in JPs ;
  25:  CALL MM_GET_VISP(1,1,51,52,53) ;

  • MM_GET_VISP: La commande pour obtenir la trajectoire planifiée par Mech-Vision.

  • Premier 1: Spécifie l’ID du projet Mech-Vision.

  • Deuxième 1: Spécifie le type de pose des points de passage obtenus comme positions articulaires.

  • 51: Le registre numérique R[51], qui stocke le nombre de points de passage renvoyés par le système de vision.

  • 52: Le registre numérique R[52], qui stocke le numéro de séquence du point de passage Vision Move (point de prise) dans la trajectoire.

  • 53: Le registre numérique R[53], qui stocke le code d’état d’exécution de la commande.

L’instruction complète indique que le robot obtient la trajectoire planifiée auprès du projet Mech-Vision ayant l’ID 1.

La trajectoire planifiée renvoyée est enregistrée dans la mémoire du robot et ne peut pas être obtenue directement. Pour y accéder, vous devez la stocker dans une étape ultérieure. 
  26:  !check whether planned path has ;
  27:  !been got from Mech-Vision ;
  28:  !successfully ;
  29:  IF R[53]<>1103,JMP LBL[99] ;

  • “IF A,JMP B”: Si la condition A est remplie, le programme saute au point B et y exécute les instructions.

  • <>: Différent de.

Cette instruction signifie que lorsque le code d’état dans R[53] est 1103, le robot a obtenu la trajectoire planifiée avec succès ; sinon, une exception s’est produite dans le système de vision et le programme sautera à LBL[99] pour exécuter les instructions qui s’y trouvent. Voici le code à LBL[99].

  66:  LBL[99:vision error] ;
  67:  !add error handling logic here ;
  68:  !according to different ;
  69:  !error codes ;
  70:  !e.g.: status=1003 means no ;
  71:  !point cloud in ROI ;
  72:  !e.g.: status=1002 means no ;
  73:  !vision results ;
  74:  PAUSE ;

Vous pouvez effectuer l’opération correspondante en fonction du code d’erreur spécifique. Dans ce programme d’exemple, tous les codes d’erreur sont traités de la même manière, en arrêtant l’exécution du programme à l’aide de la commande PAUSE.

Stocker la trajectoire planifiée

 
  30:  !save waypoints of the planned ;
  31:  !path to local variables one ;
  32:  !by one ;
  33:  CALL MM_GET_JPS(1,60,70,80) ;
  34:  CALL MM_GET_JPS(2,61,71,81) ;
  35:  CALL MM_GET_JPS(3,62,72,82) ;

  • MM_GET_JPS: La commande pour stocker la trajectoire planifiée.

  • 1: Stocke le premier point de passage.

  • 60: Le registre de position PR[60], qui stocke les positions articulaires du premier point de passage.

  • 70: Le registre numérique R[70], qui stocke l’étiquette du premier point de passage.

  • 80: Le registre numérique R[80], qui stocke l’ID d’outil du premier point de passage.

L’ensemble de la commande “CALL MM_GET_JPS(1,60,70,80)” stocke les positions articulaires, l’étiquette et l’ID d’outil du premier point de passage dans les registres spécifiés.

Dans cet exemple, la trajectoire planifiée par Mech-Vision se compose de trois points de passage : le premier est le point d’approche de la prise (PR[60]), le deuxième est le point de prise (PR[61]) et le troisième est le point de départ de la prise (PR[62]). Veuillez stocker la trajectoire planifiée en fonction du projet Mech-Vision réel.

Aller au point d’approche de la prise

 
  36:  !follow the planned path to pick ;
  37:  !move to approach waypoint ;
  38:  !of picking ;
  39:J PR[60] 50% FINE    ;

Le robot se déplace vers le point d’approche de la prise (la position représentée par PR[60]).

Aller au point de prise

 
  40:  !move to picking waypoint ;
  41:J PR[61] 10% FINE    ;

Le robot se déplace vers le point de prise (la position représentée par PR[61]).

Définir des commandes DO pour effectuer la prise

 
  42:  !add object grasping logic here, ;
  43:  !such as "DO[1]=ON" ;
  44:  PAUSE ;

Après que le robot s’est déplacé jusqu’au point de prise, vous pouvez définir une commande DO (telle que “DO[1]=ON”) pour contrôler l’outil du robot afin d’effectuer la prise. Veuillez définir les commandes DO en fonction de la situation réelle.

PAUSE indique l’arrêt de l’exécution du programme. Si vous avez ajouté une instruction pour définir une commande DO, vous pouvez supprimer l’instruction PAUSE ici.

Aller au point de départ de la prise

 
  45:  !move to departure waypoint ;
  46:  !of picking ;
  47:J PR[62] 50% FINE    ;

Le robot se déplace vers le point de départ de la prise (la position représentée par PR[62]).

Aller au point de passage intermédiaire

 
  48:  !move to intermediate waypoint ;
  49:  !of placing ;
  50:J P[3] 50% CNT100    ;

  • P[3]: Spécifie la position cible vers laquelle le robot se déplace, qui est le point de passage intermédiaire.

  • CNT: Le robot approche la position cible mais ne s’y arrête pas ; il continue plutôt vers la position suivante. Le nombre qui suit indique le degré d’approche de la position cible ; une valeur plus grande signifie qu’il reste plus éloigné de la position cible.

L’ensemble de la commande déplace le robot, en mouvement articulaire, vers un certain point de passage intermédiaire entre le point de départ de la prise et le point d’approche de la dépose.

  • L’ajout de points de passage intermédiaires permet d’assurer un mouvement fluide du robot et d’éviter des collisions inutiles. Vous pouvez ajouter plusieurs points de passage intermédiaires selon la situation réelle.

  • Vous devez enseigner à l’avance le point de passage intermédiaire (P[3]). Pour savoir comment enseigner le point de passage, reportez‑vous au manuel officiel FANUC.

Déplacer le robot vers le point d’approche de la dépose

 
  51:  !move to approach waypoint ;
  52:  !of placing ;
  53:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;

  • P[4]: Le point de dépose. Vous devez enseigner à l’avance le point de dépose (P[4]). Pour savoir comment enseigner le point de passage, reportez‑vous au manuel officiel FANUC.

  • “Tool_Offset,PR[2]”: Le robot ajuste sa position par rapport au point de dépose (P[4]) en utilisant l’offset spécifié dans PR[2]. Dans ce cas, vous n’avez besoin de définir que la valeur de l’axe Z de PR[2]. Par exemple, définir l’axe Z à -100 et toutes les autres valeurs à 0 signifie que la position se situe 100 mm en dessous du point de dépose le long de l’axe Z (c’est‑à‑dire que le robot se déplacera 100 mm au‑dessus du point de dépose pour atteindre le point d’approche de la dépose).

L’ajout de points d’approche pour la dépose peut empêcher le robot d’entrer en collision avec des objets (comme des bacs) présents dans la scène lors des déplacements. Vous pouvez modifier la valeur de PR[2] en fonction du scénario réel pour garantir l’absence de collision pendant l’approche.

Aller au point de dépose

 
  54:  !move to placing waypoint ;
  55:L P[4] 300mm/sec FINE    ;

Le robot se déplace du point d’approche de la dépose vers le point de dépose.

Définir des commandes DO pour effectuer la dépose

 
  56:  !add object releasing logic here, ;
  57:  !such as "DO[1]=OFF" ;
  58:  PAUSE ;

Après que le robot s’est déplacé jusqu’au point de dépose, vous pouvez définir une commande DO (telle que “DO[1]=OFF”) pour contrôler l’outil du robot afin d’effectuer la dépose. Veuillez définir les commandes DO en fonction de la situation réelle.

PAUSE indique l’arrêt de l’exécution du programme. Si vous avez ajouté une instruction pour définir une commande DO, vous pouvez supprimer l’instruction PAUSE ici.

Déplacer le robot vers le point de départ de la dépose

 
  59:  !move to departure waypoint ;
  60:  !of placing ;
  61:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;

Le robot se déplace vers une position au‑dessus du point de dépose et atteint le point de départ de la dépose.

L’ajout de points de départ pour la dépose peut empêcher le robot d’entrer en collision avec des objets (comme des bacs) présents dans la scène lors des déplacements. Vous pouvez modifier la valeur de PR[2] en fonction du scénario réel pour garantir l’absence de collision pendant le départ.

Aller à la position d’origine

 
  62:  !move back to robot home position ;
  63:J P[1] 100% FINE    ;

Le robot se déplace à nouveau du point de départ de la dépose vers la position d’origine.

Cette page est-elle utile ?

Veuillez nous indiquer comment améliorer :

Nous accordons de l’importance à votre vie privée

Nous utilisons des cookies pour vous offrir la meilleure expérience possible sur notre site web. En continuant à utiliser le site, vous reconnaissez accepter l’utilisation des cookies. Si vous refusez, un cookie unique sera utilisé pour garantir que vous ne soyez pas suivi ou reconnu lors de votre visite sur ce site.

  • Préférence
  • J’accepte
  • Je n’accepte pas