Programme d’exemple 14: MM_S14_Vis_GetUserData

Vous consultez actuellement la documentation pour la dernière version (2.1.2). Pour accéder à une autre version, cliquez sur le bouton "Changer de version" situé dans le coin supérieur droit de la page.

■ Si vous n’êtes pas sûr de la version du produit que vous utilisez, veuillez contacter le support technique Mech-Mind pour obtenir de l’aide.

Introduction du programme

Description

Lorsque le robot obtient le résultat de vision, le robot obtient également les données de sortie personnalisées du projet Mech-Vision.

Chemin du fichier

Vous pouvez accéder au répertoire d’installation de Mech-Vision et Mech-Viz et trouver le fichier en utilisant le chemin Communication Component/Robot_Interface/FANUC/sample/MM_S14_Vis_GetUserData.

Projet

Projet Mech-Vision (un ou plusieurs ports personnalisés doivent être ajoutés à l’étape Sortie)

Prérequis

Vous avez configuré la communication de l’Interface standard.
Calibration automatique est terminée.

Ce programme d’exemple est fourni à titre de référence uniquement. Avant d’utiliser le programme, veuillez le modifier en fonction du scénario réel.

Description du programme

Cette partie décrit le programme d’exemple MM_S14_Vis_GetUserData.

Par rapport au programme d’exemple MM_S1_Vis_Basic, ce programme d’exemple ne contient que la modification suivante (le code de cette modification est en gras). Ainsi, seule la modification est décrite dans la partie suivante. Pour plus d’informations sur les parties de MM_S14_Vis_GetUserData qui sont identiques à celles de MM_S1_Vis_Basic, voir Programme d’exemple 1: MM_S1_Vis_Basic.

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project and get vision result ;
   4:  !and custom data using ;
   5:  !command 110 ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  UFRAME_NUM=0 ;
  11:  !set current tool NO. to 1 ;
  12:  UTOOL_NUM=1 ;
  13:  !move to robot home position ;
  14:J P[1] 100% FINE    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  19:  !move to image-capturing position ;
  20:L P[2] 1000mm/sec FINE    ;
  21:  !trigger NO.1 Mech-Vision project ;
  22:  CALL MM_START_VIS(1,0,2,10) ;
  23:  !get vision result from NO.1 ;
  24:  !Mech-Vision project ;
  25:  CALL MM_GET_DY_DT(1,51,53) ;
  26:  !check whether vision result has ;
  27:  !been got from Mech-Vision ;
  28:  !successfully ;
  29:  IF R[53]<>1100,JMP LBL[99] ;
  30:  !save first vision point data to ;
  31:  !local variables ;
  32:  CALL MM_GET_DYPOS(1,60,70,90) ;
  33:  !save received custom data ;
  34:  R[10]=R[90]    ;
  35:  R[11]=R[91]    ;
  36:  R[12]=R[92]    ;
  37:  !move to intermediate waypoint ;
  38:  !of picking ;
  39:J P[3] 50% CNT100    ;
  40:  !move to approach waypoint ;
  41:  !of picking ;
  42:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1]    ;
  43:  !move to picking waypoint ;
  44:L PR[60] 300mm/sec FINE    ;
  45:  !add object grasping logic here, ;
  46:  !such as "DO[1]=ON" ;
  47:  PAUSE ;
  48:  !move to departure waypoint ;
  49:  !of picking ;
  50:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1]    ;
  51:  !move to intermediate waypoint ;
  52:  !of placing ;
  53:J P[4] 50% CNT100    ;
  54:  !move to approach waypoint ;
  55:  !of placing ;
  56:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  57:  !move to placing waypoint ;
  58:L P[5] 300mm/sec FINE    ;
  59:  !add object releasing logic here, ;
  60:  !such as "DO[1]=OFF" ;
  61:  PAUSE ;
  62:  !move to departure waypoint ;
  63:  !of placing ;
  64:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  65:  !move back to robot home position ;
  66:J P[1] 100% FINE    ;
  67:  END ;
  68:   ;
  69:  LBL[99:vision error] ;
  70:  !add error handling logic here ;
  71:  !according to different ;
  72:  !error codes ;
  73:  !e.g.: status=1003 means no ;
  74:  !point cloud in ROI ;
  75:  !e.g.: status=1002 means no ;
  76:  !vision results ;
  77:  PAUSE ;

Le flux de travail correspondant au code du programme d’exemple ci-dessus est présenté dans la figure ci-dessous.

Le tableau ci-dessous décrit le code en gras. Vous pouvez cliquer sur l’hyperlien du nom de la commande pour afficher sa description détaillée.

Fonctionnalité Code et description

Obtenir le résultat de vision (y compris les données personnalisées)

  23:  !get vision result from NO.1 ;
  24:  !Mech-Vision project ;
  25:  CALL MM_GET_DY_DT(1,51,53) ;

Pour un projet Mech-Vision, les données personnalisées font référence aux données de sortie des ports personnalisés du projet Mech-Vision.

MM_GET_DY_DT: La commande permettant d’obtenir le résultat de vision. Les points de vision obtenus par cette commande contiennent des données de sortie personnalisées en plus des poses et des étiquettes, tandis que les points de vision obtenus par la commande MM_GET_VIS ne contiennent pas de données de sortie personnalisées.
1: L’ID du projet Mech-Vision.
51: Le registre numérique R[51], qui stocke le nombre de points de vision renvoyés par le système de vision.
53: Le registre numérique R[53], qui stocke le code d’état d’exécution de la commande.

L’ensemble de l’instruction indique que le robot obtient le résultat de vision à partir du projet Mech-Vision avec un ID de 1. Le résultat de vision inclut des données personnalisées.

Le résultat de vision renvoyé est enregistré dans la mémoire du robot et ne peut pas être obtenu directement. Pour accéder aux données personnalisées dans le résultat de vision, vous devez enregistrer le résultat de vision à une étape ultérieure.

Stocker le résultat de vision (y compris les données personnalisées)

  30:  !save first vision point data to ;
  31:  !local variables ;
  32:  CALL MM_GET_DYPOS(1,60,70,90) ;

MM_GET_DYPOS: La commande pour stocker le résultat de vision. Cette commande stocke les données personnalisées en plus des poses et des étiquettes. Cependant, MM_GET_POS ne peut stocker que les poses, les étiquettes et les ID d’outil et ne peut pas stocker les données personnalisées. De plus, MM_GET_DYPOS enregistre les données personnalisées des points de vision qui ont été stockées dans la mémoire du robot dans le registre spécifié.
1: Le premier point de vision est stocké.
60: Le registre de position PR[60], qui stocke le TCP du premier point de vision, c’est-à-dire le TCP du point de préhension.
70: Le registre numérique R[70], qui stocke l’étiquette du premier point de vision.
90: Les registres numériques à partir de R[90]. Les données personnalisées du premier point de vision seront stockées séquentiellement dans des registres à partir du registre numérique R[90].

L’ensemble de l’instruction stocke le TCP, l’étiquette et les données personnalisées du premier point de vision dans les registres spécifiés.

  33:  !save received custom data ;
  34:  R[10]=R[90]    ;
  35:  R[11]=R[91]    ;
  36:  R[12]=R[92]    ;

Le code ci-dessus affecte les trois éléments de données personnalisées du point de vision (point de préhension) dans R[90], R[91] et R[92] respectivement à R[10], R[11] et R[12].

Vous pouvez définir la signification de R[10], R[11] et R[12]. Par exemple, les valeurs de R[10], R[11] et R[12] pourraient représenter les décalages du robot le long des axes XYZ lors du déplacement vers le point de préhension.

Cette page est-elle utile ?

Laisser un commentaire

Merci pour votre soutien !

Veuillez nous indiquer comment améliorer :

Nous accordons de l’importance à votre vie privée

Nous utilisons des cookies pour vous offrir la meilleure expérience possible sur notre site web. En continuant à utiliser le site, vous reconnaissez accepter l’utilisation des cookies. Si vous refusez, un cookie unique sera utilisé pour garantir que vous ne soyez pas suivi ou reconnu lors de votre visite sur ce site.

J’accepte

Je n’accepte pas