Programme d’exemple 14: MM_S14_Vis_GetUserData
Introduction du programme
Description |
Lorsque le robot obtient le résultat de vision, le robot obtient également les données personnalisées du projet Mech-Vision. |
||
Chemin du fichier |
Vous pouvez accéder au répertoire d’installation de Mech-Vision et Mech-Viz et trouver le fichier en utilisant le chemin
|
||
Projet |
Projet Mech-Vision (un ou plusieurs ports personnalisés doivent être ajoutés à la Sortie Étape) |
||
Prérequis |
|
| Ce programme d’exemple est fourni à titre de référence uniquement. Avant d’utiliser le programme, veuillez modifier le programme selon le scénario réel. |
Description du programme
Cette section décrit le programme d’exemple MM_S14_Vis_GetUserData.
| Comparé au programme d’exemple MM_S1_Vis_Basic, ce programme d’exemple contient uniquement la modification suivante (le code de cette modification est en gras). Par conséquent, seule la modification est décrite dans la section suivante. Pour des informations sur les parties de MM_S14_Vis_GetUserData qui sont cohérentes avec celles de MM_S1_Vis_Basic, voir Programme d’exemple 1: MM_S1_Vis_Basic. |
MODULE MM_S14_Vis_GetUserData
!----------------------------------------------------------
! FUNCTION: trigger Mech-Vision project and get vision result
! and custom data using command 110
! Mech-Mind, 2023-12-25
!----------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num offset_x:=0;
LOCAL VAR num offset_y:=0;
LOCAL VAR num offset_z:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];
PROC Sample_14()
!set the acceleration parameters
AccSet 50, 50;
!set the velocity parameters
VelSet 50, 1000;
!move to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
!initialize communication parameters (initialization is required only once)
MM_Init_Socket "127.0.0.1",50000,300;
!move to image-capturing position
MoveL camera_capture,v1000,fine,gripper1;
!open socket connection
MM_Open_Socket;
!trigger NO.1 Mech-Vision project
MM_Start_Vis 1,0,2,snap_jps;
!get vision result from NO.1 Mech-Vision project
MM_Get_DyData 1,pose_num,status;
!check whether vision result has been got from Mech-Vision successfully
IF status<>1100 THEN
!add error handling logic here according to different error codes
!e.g.: status=1003 means no point cloud in ROI
!e.g.: status=1002 means no vision result
Stop;
ENDIF
!close socket connection
MM_Close_Socket;
!save first vision point data to local variables
MM_Get_DyPose 1,pickpoint,label;
!save received custom data
offset_x:=MM_UserData{1};
offset_y:=MM_UserData{2};
offset_z:=MM_UserData{3};
!move to intermediate waypoint of picking
MoveJ pick_waypoint,v1000,z50,gripper1;
!move to approach waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
!move to picking waypoint
MoveL pickpoint,v300,fine,gripper1;
!add object grasping logic here, such as "setdo DO_1, 1;"
Stop;
!move to departure waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
!move to intermediate waypoint of placing
MoveJ drop_waypoint,v1000,z50,gripper1;
!move to approach waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
!move to placing waypoint
MoveL drop,v300,fine,gripper1;
!add object releasing logic here, such as "setdo DO_1, 0;"
Stop;
!move to departure waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
!move back to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULELe flux de travail correspondant au code du programme d’exemple ci-dessus est présenté dans la figure ci-dessous.
Le tableau ci-dessous décrit le code en gras. Vous pouvez cliquer sur l’hyperlien du nom de la commande pour voir sa description détaillée.
| Fonctionnalité | Code et description | ||||
|---|---|---|---|---|---|
Obtenir le résultat de vision (y compris les données personnalisées) |
L’instruction complète indique que le robot obtient le résultat de vision du projet Mech-Vision avec un identifiant de 1. Le résultat de vision inclut des données personnalisées.
|
||||
Enregistrer le résultat de vision (y compris les données personnalisées) |
L’instruction complète enregistre le TCP, l’étiquette et les données personnalisées du premier point de vision dans les variables spécifiées. Le code ci-dessus affecte les données personnalisées MM_UserData{1}, MM_UserData{2} et MM_UserData{3} qui représentent trois points de vision (points de passage de prise) à offset_x, offset_y et offset_z, respectivement.
|