Programme d’exemple 3 : MM_S3_Vis_Path

Vous consultez actuellement la documentation pour la dernière version (2.1.2). Pour accéder à une autre version, cliquez sur le bouton "Changer de version" situé dans le coin supérieur droit de la page.

■ Si vous n’êtes pas sûr de la version du produit que vous utilisez, veuillez contacter le support technique Mech-Mind pour obtenir de l’aide.

Introduction du programme

Description

Le robot déclenche l’exécution du projet Mech-Vision, puis obtient la trajectoire planifiée pour la prise et la dépose.

Chemin du fichier

Vous pouvez accéder au répertoire d’installation de Mech-Vision et Mech-Viz et trouver le fichier en utilisant le chemin Communication Component/Robot_Interface/ABB/sample/MM_S3_Vis_Path.

Pour RobotWare6, l’extension de fichier est .mod. Pour RobotWare7, veuillez modifier l’extension de fichier de .mod à .modx.

Projet

Projet Mech-Vision

Le projet Mech-Vision doit contenir une étape Planification de trajectoire, et le paramètre Port Type de l’étape Sortie doit être défini sur Prédéfini (trajectoire du robot).

Prérequis

  1. Vous avez configuré la communication de l’interface standard.

  2. L’étalonnage automatique est terminé.
Ce programme d’exemple est fourni à titre de référence uniquement. Avant d’utiliser le programme, veuillez le modifier en fonction du scénario réel.

Description du programme

Cette partie décrit le programme d’exemple MM_S3_Vis_Path.

MODULE MM_S3_Vis_Path
!----------------------------------------------------------
! FUNCTION: trigger Mech-Vision project and get planned path
! Mech-Mind, 2023-12-25
!----------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num toolid{5}:=[0,0,0,0,0];
LOCAL VAR num vis_pose_num:=0;
LOCAL VAR num count:=0;
LOCAL VAR num label{5}:=[0,0,0,0,0];
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS jointtarget jps{5}:=
[
    [[-9.7932,85.483,6.0459,-20.5518,-3.0126,-169.245],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.653,95.4782,-4.3661,-23.6568,-2.6275,-165.996],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.653,95.4782,-4.3661,-23.6568,-2.6275,-165.996],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.653,95.4782,-4.3661,-23.6568,-2.6275,-165.996],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.7932,85.483,6.0459,-20.5518,-3.0126,-169.245],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]]
];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

PROC Sample_3()
    !set the acceleration parameters
    AccSet 50, 50;
    !set the velocity parameters
    VelSet 50, 1000;
    !move to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
    !initialize communication parameters (initialization is required only once)
    MM_Init_Socket "127.0.0.1",50000,300;
    !move to image-capturing position
    MoveL camera_capture,v1000,fine,gripper1;
    !open socket connection
    MM_Open_Socket;
    !trigger NO.1 Mech-Vision project
    MM_Start_Vis 1,0,2,snap_jps;
    !get planned path from NO.1 Mech-Vision project; 2nd argument (1) means getting pose in JPs
    MM_Get_VisPath 1,1,pose_num,vis_pose_num,status;
    !check whether planned path has been got from Mech-Vision successfully
    IF status<>1103 THEN
        !add error handling logic here according to different error codes
        !e.g.: status=1003 means no point cloud in ROI
        !e.g.: status=1002 means no vision results
        Stop;
    ENDIF
    !close socket connection
    MM_Close_Socket;
    !save waypoints of the planned path to local variables one by one
    MM_Get_Jps 1,jps{1},label{1},toolid{1};
    MM_Get_JPS 2,jps{2},label{2},toolid{2};
    MM_Get_JPS 3,jps{3},label{3},toolid{3};
    !follow the planned path to pick
    !move to approach waypoint of picking
    MoveAbsJ jps{1},v1000,fine,gripper1;
    !move to picking waypoint
    MoveAbsJ jps{2},v1000,fine,gripper1;
    !add object grasping logic here, such as "setdo DO_1, 1;"
    Stop;
    !move to departure waypoint of picking
    MoveAbsJ jps{3},v1000,fine,gripper1;
    !move to intermediate waypoint of placing
    MoveJ drop_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move to placing waypoint
    MoveL drop,v300,fine,gripper1;
    !add object releasing logic here, such as "setdo DO_1, 0;"
    Stop;
    !move to departure waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move back to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULE

Le flux de travail correspondant au code de l’exemple ci-dessus est illustré dans la figure ci-dessous.

sample3

Le tableau ci-dessous explique le programme ci-dessus. Vous pouvez cliquer sur le lien hypertexte du nom de commande pour afficher sa description détaillée.

Fonctionnalité Code et description

Définir des variables

 
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num toolid{5}:=[0,0,0,0,0];
LOCAL VAR num vis_pose_num:=0;
LOCAL VAR num count:=0;
LOCAL VAR num label{5}:=[0,0,0,0,0];
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS jointtarget jps{5}:=
[
    [[-9.7932,85.483,6.0459,-20.5518,-3.0126,-169.245],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.653,95.4782,-4.3661,-23.6568,-2.6275,-165.996],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.653,95.4782,-4.3661,-23.6568,-2.6275,-165.996],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.653,95.4782,-4.3661,-23.6568,-2.6275,-165.996],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]],
    [[-9.7932,85.483,6.0459,-20.5518,-3.0126,-169.245],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]]
];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

Définissez des variables locales. Les variables locales ci-dessus ne sont valables que dans ce programme.

Enseignez la position de départ (variable home), la pose d’entrée du projet Mech-Vision (variable snap_jps), la position de capture d’image (variable camera_capture), le point intermédiaire de dépose (variable drop_waypoint) et le point de dépose (variable drop), et définissez à l’avance les données de l’outil (variable gripper1).

Pour savoir comment enseigner un point de passage, consultez la section Teach Calibration Start Point dans le document d’étalonnage.

Configurer l’accélération et la vitesse

 
!set the acceleration parameters
AccSet 50, 50;
!set the velocity parameters
VelSet 50, 1000;

  • AccSet 50, 50 : Limite l’accélération à 50 % de la valeur normale et le taux d’accélération à 50 % de la valeur normale.

  • VelSet 50, 1000 : Définit la vitesse à 50 % de la vitesse programmée et la vitesse TCP maximale à 1000 mm/s.

Se déplacer vers la position de départ

 
!move to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

  • MoveAbsJ : La commande de mouvement en position absolue du robot ABB, indiquant que chaque axe de joint du robot se déplace indépendamment vers une position spécifiée.

  • home : Spécifie la position cible vers laquelle le robot se déplace, c.-à-d. la position de départ enseignée. La position de départ est généralement une position sûre où le robot est éloigné des objets et des équipements environnants.

  • \NoEOffs : Spécifie que le mouvement n’est pas affecté par des axes externes.

  • v3000 : Spécifie que la vitesse du robot est de 3000 mm/s.

  • fine : Déplace le robot vers la position spécifiée.

  • gripper1 : Spécifie l’ID de l’outil utilisé par le robot lorsqu’il se déplace.

L’ensemble de la commande indique que le robot se déplace vers la position de départ enseignée, sans l’influence d’axes externes, à une vitesse de 3000 mm/s.

Initialiser les paramètres de communication

 
!initialize communication parameters (initialization is required only once)
MM_Init_Socket "127.0.0.1",50000,300;

Le robot envoie la commande MM_Init_Socket pour définir l’adresse IP, le numéro de port et la durée de temporisation de l’objet de communication (l’IPC) sur 127.0.0.1, 50000 et 300 secondes.

Veuillez modifier l’adresse IP et le numéro de port de l’IPC selon la situation réelle. L’adresse IP et le numéro de port doivent être cohérents avec ceux configurés dans le système de vision.

Se déplacer vers la position de capture d’image

 
!move to image-capturing position
MoveL camera_capture,v1000,fine,gripper1;

  • MoveL : La commande de mouvement linéaire du robot ABB. Cette commande spécifie de déplacer le robot le long d’une trajectoire linéaire jusqu’à une position donnée.

  • camera_capture : Spécifie la position cible vers laquelle le robot se déplace, c.-à-d. la position de capture d’image enseignée. La position de capture d’image fait référence à la position du robot à laquelle la caméra montée sur le robot capture des images. À cette position, le bras du robot ne doit pas obstruer le champ de vision (FOV) de la caméra.

L’ensemble de la commande indique que le robot se déplace avec précision en mouvement linéaire vers la position de capture d’image, à une vitesse de 1000 mm/s.

Établir la communication

 
!open socket connection
MM_Open_Socket;

La communication TCP entre le robot et le système de vision est établie à l’aide de la commande MM_Open_Socket.

Déclencher l’exécution du projet Mech-Vision

 
!trigger NO.1 Mech-Vision project
MM_Start_Vis 1,0,2,snap_jps;

  • MM_Start_Vis : La commande qui déclenche l’exécution du projet Mech-Vision.

  • 1 : L’ID du projet Mech-Vision.

  • 0 : Le projet Mech-Vision doit renvoyer tous les points de passage.

  • 2 : Indique que la pose de la bride du robot doit être fournie au projet Mech-Vision.

  • snap_jps : Positions articulaires personnalisées. Les positions articulaires de ce programme d’exemple n’ont pas d’utilité pratique mais doivent être définies.

L’ensemble de l’instruction indique que le robot déclenche le système de vision pour exécuter le projet Mech-Vision avec un ID de 1 et s’attend à ce que le projet Mech-Vision renvoie tous les points de passage.

Obtenir la trajectoire planifiée

 
!get planned path from NO.1 Mech-Vision project; 2nd argument (1) means getting pose in JPs
MM_Get_VisPath 1,1,pose_num,vis_pose_num,status;

  • MM_Get_VisPath : La commande permettant d’obtenir la trajectoire planifiée depuis Mech-Vision.

  • Premier 1 : Spécifie l’ID du projet Mech-Vision.

  • Deuxième 1 : Spécifie le type de pose des points de passage obtenus comme positions articulaires.

  • pose_num : La variable qui stocke le nombre de points de passage renvoyés par le système de vision.

  • vis_pose_num : La variable qui stocke le numéro de séquence du point de mouvement de vision (point de prise) dans la trajectoire.

  • status : La variable qui stocke le code d’état d’exécution de la commande.

L’ensemble de l’instruction indique que le robot obtient la trajectoire planifiée à partir du projet Mech-Vision dont l’ID est 1.

La trajectoire planifiée renvoyée est enregistrée dans la mémoire du robot et ne peut pas être obtenue directement. Pour y accéder, vous devez la stocker à l’étape suivante. 
!check whether planned path has been got from Mech-Vision successfully
IF status<>1103 THEN
    !add error handling logic here according to different error codes
    !e.g.: status=1003 means no point cloud in ROI
    !e.g.: status=1002 means no vision results
    Stop;
ENDIF

Lorsque le code d’état est 1103, le robot a obtenu avec succès la trajectoire planifiée. Sinon, une erreur s’est produite dans le système de vision. Vous pouvez effectuer l’opération correspondante en fonction du code d’erreur spécifique.

Fermer la communication

 
!close socket connection
MM_Close_Socket;

La communication TCP entre le robot et le système de vision est fermée à l’aide de la commande MM_Close_Socket.

Enregistrer la trajectoire planifiée

 
!save waypoints of the planned path to local variables one by one
MM_Get_JPS 1,jps{1},label{1},toolid{1};
MM_Get_JPS 2,jps{2},label{2},toolid{2};
MM_Get_JPS 3,jps{3},label{3},toolid{3};

  • MM_Get_Jps : La commande permettant d’enregistrer la trajectoire planifiée.

  • 1 : Enregistre le premier point de passage.

  • jps{1} : La variable qui stocke les positions articulaires du premier point de passage.

  • label{1} : La variable qui stocke l’étiquette du premier point de passage.

  • toolid{1} : La variable qui stocke l’ID de l’outil correspondant au premier point de passage.

L’ensemble de la commande « MM_Get_JPS 1,jps{1},label{1},toolid{1}; » enregistre les positions articulaires, l’étiquette et l’ID de l’outil du premier point de passage dans les variables spécifiées.

Dans cet exemple, la trajectoire planifiée par Mech-Vision se compose de trois points de passage : le premier point est le point d’approche de la prise, le deuxième point est le point de prise, et le troisième point est le point de départ de la prise. Veuillez enregistrer la trajectoire planifiée en fonction du projet Mech-Vision réel.

Se déplacer vers le point d’approche de la prise

 
!move to approach waypoint of picking
MoveAbsJ jps{1},v1000,fine,gripper1;

Le robot se déplace vers le point d’approche de la prise (la position représentée par jps{1}).

Se déplacer vers le point de prise

 
!move to picking waypoint
MoveAbsJ jps{2},v300,fine,gripper1;

Le robot se déplace vers le point de prise (la position représentée par jps{2}).

Configurer des sorties numériques (DO) pour effectuer la prise

 
!add object grasping logic here, such as "setdo DO_1, 1;"
Stop;

Après que le robot s’est déplacé vers le point de prise, vous pouvez configurer une DO (par exemple setdo DO_1, 1;) pour contrôler le robot afin d’utiliser l’outil pour effectuer la prise. Veuillez configurer les DO en fonction de la situation réelle.

Stop indique que l’exécution du programme est mise en pause. Si vous avez ajouté une instruction pour configurer une DO, vous pouvez supprimer l’instruction Stop ici.

Se déplacer vers le point de départ de la prise

 
!move to departure waypoint of picking
MoveAbsJ jps{3},v1000,fine,gripper1;

Le robot se déplace vers le point de départ de la prise (la position représentée par jps{3}).

Se déplacer vers le point intermédiaire

 
!move to intermediate waypoint of placing
MoveJ drop_waypoint,v1000,z50,gripper1;

  • MoveJ : La commande de mouvement en position articulaire du robot ABB, indiquant que le robot se déplace le long d’un arc vers une position spécifiée.

  • drop_waypoint : Spécifie la position cible vers laquelle le robot se déplace, c.-à-d. le point intermédiaire.

  • z50 : Le rayon de transition est de 50 mm.

L’ensemble de la commande déplace le robot en positions articulaires vers un certain point intermédiaire entre le point de départ de la prise et le point d’approche de la dépose, avec une vitesse de 1000 mm/s et un rayon de transition de 50 mm.

L’ajout de points intermédiaires peut garantir un mouvement fluide du robot et éviter des collisions inutiles. Vous pouvez ajouter plusieurs points intermédiaires selon la situation réelle.

Déplacer le robot vers le point d’approche de la dépose

 
!move to approach waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;

  • RelTool(pickpoint,0,0,-100) : Spécifie la position cible vers laquelle le robot se déplace. Dans cet exemple, RelTool représente le mouvement relatif au repère de l’outil ; drop (le point de dépose) est le point de base dans le repère de l’outil, et 0,0,-100 représente 100 mm dans la direction Z négative par rapport à drop.

L’ensemble de la commande amène le robot à 100 mm au-dessus du point de dépose pour atteindre le point d’approche de la dépose.

L’ajout de points d’approche de la dépose peut empêcher le robot d’entrer en collision avec des objets (tels que des bacs) dans la scène lors du déplacement. Vous pouvez modifier le décalage négatif sur l’axe Z en fonction du scénario réel afin de garantir qu’aucune collision ne se produise pendant l’approche.

Se déplacer vers le point de dépose

 
!move to placing waypoint
MoveL drop,v300,fine,gripper1;

Le robot se déplace du point d’approche de la dépose vers le point de dépose.

Configurer des sorties numériques (DO) pour effectuer la dépose

 
!add object releasing logic here, such as "setdo DO_1, 0;"
Stop;

Après que le robot s’est déplacé vers le point de dépose, vous pouvez configurer une DO (par exemple setdo DO_1, 0;) pour contrôler le robot afin d’utiliser l’outil pour effectuer la dépose. Veuillez configurer les DO en fonction de la situation réelle.

Stop indique que l’exécution du programme est mise en pause. Si vous avez ajouté une instruction pour configurer une DO, vous pouvez supprimer l’instruction Stop ici.

Déplacer le robot vers le point de départ de la dépose

 
!move to departure waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;

Le robot se déplace à 100 mm au-dessus du point de dépose et atteint le point de départ de la dépose.

L’ajout de points de départ de la dépose peut empêcher le robot d’entrer en collision avec des objets (tels que des bacs) dans la scène lors du déplacement. Vous pouvez modifier le décalage négatif sur l’axe Z en fonction du scénario réel afin de garantir qu’aucune collision ne se produise pendant le départ.

Se déplacer vers la position de départ

 
!move back to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

Le robot se déplace du point de départ de la dépose vers la position de départ à nouveau.

Cette page est-elle utile ?

Veuillez nous indiquer comment améliorer :

Nous accordons de l’importance à votre vie privée

Nous utilisons des cookies pour vous offrir la meilleure expérience possible sur notre site web. En continuant à utiliser le site, vous reconnaissez accepter l’utilisation des cookies. Si vous refusez, un cookie unique sera utilisé pour garantir que vous ne soyez pas suivi ou reconnu lors de votre visite sur ce site.

  • Préférence
  • J’accepte
  • Je n’accepte pas