Programme d’exemple 17 : MM_S17_Vis_ParseLabel
Introduction du programme
Description |
Le robot déclenche l’exécution du projet Mech-Vision pour obtenir le résultat de vision, analyse les étiquettes, puis adopte une méthode de traitement basée sur l’étiquette pour effectuer la prise et la dépose. |
||
Chemin du fichier |
Vous pouvez accéder au répertoire d’installation de Mech-Vision et Mech-Viz et trouver le fichier en utilisant le chemin
|
||
Projet |
Projet Mech-Vision (les données doivent être présentes dans le port étiquettes de la Sortie Étape) |
||
Prérequis |
|
| Ce programme d’exemple est fourni à titre de référence uniquement. Avant d’utiliser le programme, veuillez le modifier en fonction du scénario réel. |
Description du programme
Cette partie décrit le programme d’exemple MM_S17_Vis_ParseLabel.
| La seule différence entre le programme d’exemple MM_S17_Vis_ParseLabel et le programme d’exemple MM_S1_Vis_Basic est que MM_S17_Vis_ParseLabel peut analyser des étiquettes (le code de cette fonction est en gras). Ainsi, seule la fonction d’analyse des étiquettes est décrite dans la section suivante. Pour des informations sur les parties de MM_S17_Vis_ParseLabel qui sont identiques à celles de MM_S1_Vis_Basic, voir Programme d’exemple 1 : MM_S1_Vis_Basic. |
MODULE MM_S17_Vis_ParseLabel
!----------------------------------------------------------
! FUNCTION: trigger Mech-Vision project and get vision result,
! then parse the label info
! Mech-Mind, 2023-12-25
!----------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num label_1:=0;
LOCAL VAR num label_2:=0;
LOCAL VAR num toolid:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];
PROC Sample_17()
!set the acceleration parameters
AccSet 50, 50;
!set the velocity parameters
VelSet 50, 1000;
!move to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
!initialize communication parameters (initialization is required only once)
MM_Init_Socket "127.0.0.1",50000,300;
!move to image-capturing position
MoveL camera_capture,v1000,fine,gripper1;
!open socket connection
MM_Open_Socket;
!trigger NO.1 Mech-Vision project
MM_Start_Vis 1,0,2,snap_jps;
!get vision result from NO.1 Mech-Vision project
MM_Get_VisData 1,pose_num,status;
!check whether vision result has been got successfully
IF status<>1100 THEN
!add error handling logic here according to different error codes
!e.g.: status=1003 means no point cloud in ROI
!e.g.: status=1002 means no vision result
Stop;
ENDIF
!close socket connection
MM_Close_Socket;
!save first vision point data to local variables
MM_Get_Pose 1,pickpoint,label,toolid;
!parse label info received from Mech-Vision, eg. "label=56" will decompose into 5 and 6
label_1:=label DIV 10; !label_1=5
label_2:=label MOD 10; !label_2=6
!add handling logic according to decomposed label value
IF label_1=5 THEN
!add handling logic a
Stop;
ELSE
!add handling logic b
Stop;
ENDIF
!move to intermediate waypoint of picking
MoveJ pick_waypoint,v1000,z50,gripper1;
!move to approach waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
!move to picking waypoint
MoveL pickpoint,v300,fine,gripper1;
!add object grasping logic here, such as "setdo DO_1, 1;"
Stop;
!move to departure waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
!move to intermediate waypoint of placing
MoveJ drop_waypoint,v1000,z50,gripper1;
!move to approach waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
!move to placing waypoint
MoveL drop,v300,fine,gripper1;
!add object releasing logic here, such as "setdo DO_1, 0;"
Stop;
!move to departure waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
!move back to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULELe flux de travail correspondant au code du programme d’exemple ci-dessus est illustré dans la figure ci-dessous.
Le tableau ci-dessous décrit la fonction d’analyse des étiquettes. Vous pouvez cliquer sur l’hyperlien du nom de la commande pour en voir la description détaillée.
| Fonction | Code et description |
|---|---|
Analyser les étiquettes en label_1 et label_2 |
La commande MM_Get_Pose enregistre le TCP, l’étiquette et l’ID d’outil du point de vision dans les variables pickpoint, label et toolid respectivement. Dans cet exemple, la variable label est définie à 56 ; label DIV 10 représente le quotient de la valeur de label divisée par 10 (c’est-à-dire 5), et label MOD 10 représente le reste de la valeur de label divisée par 10 (c’est-à-dire 6). De cette façon, l’étiquette est analysée en label_1 et label_2 (c’est-à-dire 56 en 5 et 6). |
Adopter une méthode de traitement basée sur le résultat d’analyse de l’étiquette |
Le code ci-dessus indique que si label_1 vaut 5, la logique a sera exécutée ; sinon, la logique b sera exécutée. La méthode de traitement varie selon le résultat d’analyse de l’étiquette. Vous pouvez adopter une méthode de traitement en fonction de vos besoins métier. |