Exemple de programme 1 : MM_S1_Vis_Basic

Vous consultez actuellement la documentation pour la dernière version (2.1.2). Pour accéder à une autre version, cliquez sur le bouton "Changer de version" situé dans le coin supérieur droit de la page.

■ Si vous n’êtes pas sûr de la version du produit que vous utilisez, veuillez contacter le support technique Mech-Mind pour obtenir de l’aide.

Présentation du programme

Description

Le robot déclenche l’exécution du projet Mech-Vision, puis obtient le résultat de vision pour saisir et déposer l’objet.

Chemin du fichier

Vous pouvez accéder au répertoire d’installation de Mech-Vision et Mech-Viz et trouver le fichier en utilisant le chemin Communication Component/Robot_Interface/ABB/sample/MM_S1_Vis_Basic.

Pour RobotWare6, l’extension du fichier est .mod. Pour RobotWare7, veuillez modifier l’extension du fichier de .mod en .modx.

Projet

Projet Mech-Vision

Prérequis

Vous avez configuré la communication de l’interface standard.
L’étalonnage automatique est terminé.

Ce programme d’exemple est fourni uniquement à titre de référence. Avant d’utiliser le programme, veuillez le modifier en fonction du scénario réel.

Description du programme

Cette partie décrit le programme d’exemple MM_S1_Vis_Basic.

MODULE MM_S1_Vis_Basic
!--------------------------------------------------------------
! FUNCTION: trigger Mech-Vision project and get vision result
! Mech-Mind, 2023-12-25
!-------------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num toolid:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

PROC Sample_1()
    !set the acceleration parameters
    AccSet 50, 50;
    !set the velocity parameters
    VelSet 50, 1000;
    !move to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
    !initialize communication parameters (initialization is required only once)
    MM_Init_Socket "127.0.0.1",50000,300;
    !move to image-capturing position
    MoveL camera_capture,v1000,fine,gripper1;
    !open socket connection
    MM_Open_Socket;
    !trigger NO.1 Mech-Vision project
    MM_Start_Vis 1,0,2,snap_jps;
    !get vision result from NO.1 Mech-Vision project
    MM_Get_VisData 1,pose_num,status;
    !check whether vision result has been got from Mech-Vision successfully
    IF status<>1100 THEN
        !add error handling logic here according to different error codess
        !e.g.: status=1003 means no point cloud in ROI
        !e.g.: status=1002 means no vision result
        Stop;
    ENDIF
    !close socket connection
    MM_Close_Socket;
    !save first vision point data to local variables
    MM_Get_Pose 1,pickpoint,label,toolid;
    !move to intermediate waypoint of picking
    MoveJ pick_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to picking waypoint
    MoveL pickpoint,v300,fine,gripper1;
    !add object grasping logic here, such as "setdo DO_1, 1;"
    Stop;
    !move to departure waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to intermediate waypoint of placing
    MoveJ drop_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move to placing waypoint
    MoveL drop,v300,fine,gripper1;
    !add object releasing logic here, such as "setdo DO_1, 0;"
    Stop;
    !move to departure waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move back to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULE

Le flux de travail correspondant au code de programme d’exemple ci-dessous est illustré dans la figure ci-dessous.

Le tableau ci-dessous explique le programme ci-dessus. Vous pouvez cliquer sur l’hyperlien du nom de commande pour en consulter la description détaillée.

Fonctionnalité Code et description

Définir des variables

!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num toolid:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

Définissez des variables locales. Les variables locales ci-dessus ne sont valides que dans ce programme.

Apprenez la position de départ (variable home), la pose d’entrée du projet Mech-Vision (variable snap_jps), la position de capture d’image (variable camera_capture), le point intermédiaire de saisie (variable pick_waypoint), le point intermédiaire de dépose (variable drop_waypoint) et le point de dépose (variable drop), et configurez à l’avance les données de l’outil (variable gripper1).

Pour plus d’informations sur la manière d’enseigner un point de passage, consultez la section Teach Calibration Start Point dans le document d’étalonnage.

Définir l’accélération et la vitesse

!set the acceleration parameters
AccSet 50, 50;
!set the velocity parameters
VelSet 50, 1000;

AccSet 50, 50: Limite l’accélération à 50 % de la valeur normale et le taux d’accélération à 50 % de la valeur normale.
VelSet 50, 1000: Définit la vitesse à 50 % de la vitesse programmée et la vitesse TCP maximale à 1000 mm/s.

Se déplacer vers la position de départ

!move to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

MoveAbsJ: La commande de mouvement en position absolue du robot ABB, indiquant que chaque axe articulé du robot se déplace indépendamment vers une position spécifiée.
home: Spécifie la position cible vers laquelle le robot se déplace, c’est-à-dire la position de départ enseignée. La position de départ est généralement une position sûre où le robot est éloigné des objets et des équipements environnants.
\NoEOffs: Spécifie que le mouvement n’est pas affecté par des axes externes.
v3000: Spécifie que la vitesse du robot est de 3000 mm/s.
fine: Déplace le robot jusqu’à la position spécifiée.
gripper1: Spécifie l’ID de l’outil utilisé par le robot lors du déplacement.

La commande entière indique que le robot se déplace vers la position de départ enseignée, sans l’influence d’axes externes, à une vitesse de 3000 mm/s.

Initialiser les paramètres de communication

!initialize communication parameters (initialization is required only once)
MM_Init_Socket "127.0.0.1",50000,300;

Le robot envoie la commande MM_Init_Socket pour définir l’adresse IP, le numéro de port et le délai d’expiration de l’objet de communication (l’IPC) à 127.0.0.1, 50000 et 300 secondes.

Veuillez modifier l’adresse IP et le numéro de port de l’IPC en fonction de la situation réelle. L’adresse IP et le numéro de port doivent être cohérents avec ceux définis dans le système de vision.

Se déplacer vers la position de capture d’image

!move to image-capturing position
MoveL camera_capture,v1000,fine,gripper1;

MoveL: La commande de mouvement linéaire du robot ABB. Cette commande spécifie le déplacement du robot le long d’une trajectoire linéaire vers une position donnée.
camera_capture: Spécifie la position cible vers laquelle le robot se déplace, c’est-à-dire la position de capture d’image enseignée. La position de capture d’image correspond à la position du robot où la caméra montée sur le robot capture des images. À cette position, le bras du robot ne doit pas obstruer le champ de vision de la caméra.

La commande entière indique que le robot se déplace avec précision, en mouvement linéaire, vers la position de capture d’image enseignée, à une vitesse de 1000 mm/s.

Établir la communication

!open socket connection
MM_Open_Socket;

La communication TCP entre le robot et le système de vision est établie via la commande MM_Open_Socket.

Déclencher l’exécution du projet Mech-Vision

!trigger NO.1 Mech-Vision project
MM_Start_Vis 1,0,2,snap_jps;

MM_Start_Vis: La commande pour déclencher l’exécution du projet Mech-Vision.
1: L’ID du projet Mech-Vision.
0: Le projet Mech-Vision doit renvoyer tous les points de vision.
2: Indique que la pose de la bride du robot doit être fournie en entrée au projet Mech-Vision.
snap_jps: Positions articulaires personnalisées. Les positions articulaires dans ce programme d’exemple n’ont aucune utilité pratique mais doivent être définies.

L’ensemble de l’instruction indique que le robot déclenche le système de vision pour exécuter le projet Mech-Vision avec un ID de 1 et attend que le projet Mech-Vision renvoie tous les points de vision.

Obtenir le résultat de vision

!get vision result from NO.1 Mech-Vision project
MM_Get_VisData 1,pose_num,status;

MM_Get_VisData: La commande pour obtenir le résultat de vision.
1: L’ID du projet Mech-Vision.
pose_num: La variable qui stocke le nombre de points de vision reçus.
status: La variable qui stocke le code d’état d’exécution de la commande.

L’ensemble de l’instruction indique que le robot obtient le résultat de vision du projet Mech-Vision avec un ID de 1.

Le résultat de vision renvoyé est enregistré dans la mémoire du robot et ne peut pas être obtenu directement. Pour accéder au résultat de vision, vous devez l’enregistrer à l’étape suivante.

!check whether vision result has been got from Mech-Vision successfully
IF status<>1100 THEN
    !add error handling logic here according to different error codess
    !e.g.: status=1003 means no point cloud in ROI
    !e.g.: status=1002 means no vision result
    Stop;
ENDIF

Lorsque le code d’état est 1100, le robot a obtenu avec succès tous les résultats de vision. Sinon, une erreur s’est produite dans le système de vision. Vous pouvez effectuer l’opération correspondante en fonction du code d’erreur spécifique.

Fermer la communication

!close socket connection
MM_Close_Socket;

La communication TCP entre le robot et le système de vision est fermée via la commande MM_Close_Socket.

Stocker le résultat de vision

!save first vision point data to local variables
MM_Get_Pose 1,pickpoint,label,toolid;

MM_Get_Pose: La commande pour stocker le résultat de vision.
1: Le premier point de vision est enregistré.
pickpoint: La variable qui stocke le TCP du premier point de vision, qui est le TCP du point de saisie.
label: La variable qui stocke l’étiquette correspondant au premier point de vision.
toolid: La variable qui stocke l’ID d’outil correspondant au premier point de vision.

L’ensemble de l’instruction enregistre le TCP, l’étiquette et l’ID d’outil du premier point de vision dans les variables spécifiées.

Se déplacer vers le point intermédiaire

!move to intermediate waypoint of picking
MoveJ pick_waypoint,v1000,z50,gripper1;

MoveJ: La commande de mouvement en positions articulaires du robot ABB, indiquant que le robot se déplace le long d’un arc vers une position spécifiée.
pick_waypoint: Spécifie la position cible vers laquelle le robot se déplace, c’est-à-dire le point intermédiaire.
z50: Le rayon de transition est de 50 mm.

La commande entière déplace le robot en positions articulaires vers un point intermédiaire entre la position de capture d’image et le point d’approche de saisie, à une vitesse de 1000 mm/s et avec un rayon de transition de 50 mm.

L’ajout de points intermédiaires peut assurer un mouvement fluide du robot et éviter des collisions inutiles. Vous pouvez ajouter plusieurs points intermédiaires selon la situation réelle.

Se déplacer vers le point d’approche de saisie

!move to approach waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;

MoveL: La commande de mouvement du robot ABB. Cette commande spécifie le déplacement du robot le long d’une trajectoire linéaire.
RelTool(pickpoint,0,0,-100): Spécifie la position cible du robot, où RelTool représente le mouvement relatif au repère de l’outil, pickpoint est le point de base dans le repère de l’outil, et 0,0,-100 représente 100 mm selon la direction Z négative de pickpoint (c’est-à-dire que le robot se déplace à 100 mm au-dessus du point de saisie pour atteindre le point d’approche de saisie).

La commande entière indique que le robot se déplace linéairement à 100 mm au-dessus du point de saisie, à une vitesse de 1000 mm/s.

L’ajout de points d’approche de saisie peut empêcher le robot d’entrer en collision avec des objets (tels que des bacs) dans la scène lors des déplacements. Vous pouvez modifier le décalage négatif de l’axe Z en fonction du scénario réel afin de garantir qu’aucune collision ne se produit pendant l’approche.

Se déplacer vers le point de saisie

!move to picking waypoint
MoveL pickpoint,v300,fine,gripper1;

Le robot se déplace en mouvement linéaire du point d’approche de saisie vers le point de saisie.

Définir des commandes DO pour effectuer la saisie

!add object grasping logic here, such as "setdo DO_1, 1;"
Stop;

Après que le robot s’est déplacé vers le point de saisie, vous pouvez définir une commande DO (par exemple setdo DO_1, 1;) pour contrôler l’utilisation de l’outil par le robot afin d’effectuer la saisie. Veuillez définir les commandes DO en fonction de la situation réelle.

Stop indique que l’exécution du programme est en pause. Si vous avez ajouté une instruction pour définir une commande DO, vous pouvez supprimer l’instruction Stop ici.

Se déplacer vers le point de départ de saisie

!move to departure waypoint of picking
MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;

Le robot se déplace à 100 mm au-dessus du point de saisie et atteint le point de départ de saisie.

L’ajout de points de départ de saisie peut empêcher le robot d’entrer en collision avec des objets (tels que des bacs) dans la scène lors des déplacements. Vous pouvez modifier le décalage négatif de l’axe Z en fonction du scénario réel afin de garantir qu’aucune collision ne se produit pendant le départ.

Se déplacer vers le point intermédiaire

!move to intermediate waypoint of placing
MoveJ drop_waypoint,v1000,z50,gripper1;

Le robot se déplace vers un point intermédiaire entre le point de départ de saisie et le point d’approche de dépose.

L’ajout de points intermédiaires peut assurer un mouvement fluide du robot et éviter des collisions inutiles. Vous pouvez ajouter plusieurs points intermédiaires selon la situation réelle.

Déplacer le robot vers le point d’approche de dépose

!move to approach waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;

Le robot se déplace à 100 mm au-dessus du point de dépose et atteint le point d’approche de dépose.

L’ajout de points d’approche de dépose peut empêcher le robot d’entrer en collision avec des objets (tels que des bacs) dans la scène lors des déplacements. Vous pouvez modifier le décalage négatif de l’axe Z en fonction du scénario réel afin de garantir qu’aucune collision ne se produit pendant l’approche.

Se déplacer vers le point de dépose

!move to placing waypoint
MoveL drop,v300,fine,gripper1;

Le robot se déplace du point d’approche de dépose vers le point de dépose.

Définir des commandes DO pour effectuer la dépose

!add object releasing logic here, such as "setdo DO_1, 0;"
Stop;

Après que le robot s’est déplacé vers le point de dépose, vous pouvez définir une commande DO (par exemple setdo DO_1, 0;) pour contrôler l’utilisation de l’outil par le robot afin d’effectuer la dépose. Veuillez définir les commandes DO en fonction de la situation réelle.

Stop indique que l’exécution du programme est en pause. Si vous avez ajouté une instruction pour définir une commande DO, vous pouvez supprimer l’instruction Stop ici.

Déplacer le robot vers le point de départ de dépose

!move to departure waypoint of placing
MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;

Le robot se déplace à 100 mm au-dessus du point de dépose et atteint le point de départ de dépose.

L’ajout de points de départ de dépose peut empêcher le robot d’entrer en collision avec des objets (tels que des bacs) dans la scène lors des déplacements. Vous pouvez modifier le décalage négatif de l’axe Z en fonction du scénario réel afin de garantir qu’aucune collision ne se produit pendant le départ.

Se déplacer vers la position de départ

!move back to robot home position
MoveAbsJ home\NoEOffs,v3000,fine,gripper1;

Le robot se déplace à nouveau du point de départ de dépose vers la position de départ.

Cette page est-elle utile ?

Laisser un commentaire

Merci pour votre soutien !

Veuillez nous indiquer comment améliorer :

Nous accordons de l’importance à votre vie privée

Nous utilisons des cookies pour vous offrir la meilleure expérience possible sur notre site web. En continuant à utiliser le site, vous reconnaissez accepter l’utilisation des cookies. Si vous refusez, un cookie unique sera utilisé pour garantir que vous ne soyez pas suivi ou reconnu lors de votre visite sur ce site.

J’accepte

Je n’accepte pas