샘플 프로그램17: MM_S17_Vis_ParseLabel

현재 최신 버전 (2.1.2)에 대한 매뉴얼을 보고 계십니다. 다른 버전에 액세스하려면 페이지 오른쪽 상단 모서리에 있는 '버전 전환' 버튼을 클릭하세요.

■ 현재 사용하고 있는 제품의 버전이 확실하지 않은 경우에는 언제든지 당사 기술 지원팀에 문의하시기 바랍니다.

프로그램 소개

기능 설명

로봇은 Mech-Vision 프로젝트를 실행을 트리거하여 비전 결과를 획득하고, 레이블을 파싱한 후, 레이블에 따른 처리 방법을 채택하여 피킹 및 배치 작업을 수행합니다.

파일 경로

Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 통신 구성 요소/Robot_Interface/YASKAWA/sample/MM_S17_Vis_ParseLabel 경로를 사용하여 파일을 찾을 수 있습니다.

필요한 프로젝트

Mech-Vision 프로젝트 (출력 스텝의 labels포트에는 데이터가 존재해야 합니다).

사용 전제 조건

표준 인터페이스 통신 구성이 완료됩니다.
자동 캘리브레이션이 완료됩니다.

이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오.

프로그램 설명

다음에는 MM_S17_Vis_ParseLabel 샘플 프로그램의 코드와 관련 설명입니다.

MM_S1_Vis_Basic 샘플과 비하면, 이 샘플은 레이블을 파싱하는 기능만 추가되었습니다.(이 기능의 코드가 굵게 표시됨). 따라서, MM_S17_Vis_ParseLabel의 MM_S1_Vis_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S1_Vis_Basic 샘플 프로그램 설명을 참조하십시오).

NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project and get vision result,
'then parse the label info
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P070 P070
SUB P071 P071
'set 100mm to z of P070
SETE P070 (3) 100000
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_VISDATA ARGF"1;51;52"
'check whether vision result has
'been got from Mech-Vision
'successfully
IFTHENEXP I052<>1100
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: I052=1003 means no point
	'cloud in ROI
	'e.g.: I052=1002 means no
	'vision result
	 PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save first vision point data to
'local variables
CALL JOB:MM_GET_POSE ARGF"1;71;61;62"
'parse label info received from
'Mech-Vision, eg. "I061=56" will
'decompose into 5 and 6
SET I064 I061
SET I065 I061
'I064=5
DIV I064 10
SET I063 I064
MUL I063 10
'I065=6
SUB I065 I063
IFTHENEXP I064=5
	'add handling logic a
	 PAUSE
ELSE
	'add handling logic b
	 PAUSE
ENDIF
'move to intermediate waypoint of
'picking
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to picking waypoint
MOVL P071 V=50.0 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to intermediate waypoint of
'placing
MOVJ C00003 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00004 V=166.6 PL=0
'move to placing waypoint
MOVL C00005 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00006 V=166.6 PL=0
'move back to robot home position
MOVJ C00007 VJ=50.00
END

위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.

아래 표는 레이블을 분석하는 기능의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.

워크플로 코드와 설명

워크플로	코드와 설명
레이블을 파싱하기	MM_GET_POSE명령어는 특정 비전 포인트의 TCP 포즈와 레이블, 말단장치 번호가 각각 변수P071과 I61, I62에 저장될 수 있습니다. 이 샘플에서는 I061변수의 값이 56로 가정합니다. `SET I064 I061 SET I065 I061` 위 할당문을 실행한 후, I064와 I065의 변수 값은 56입니다. `'I064=5 DIV I064 10 SET I063 I064 MUL I063 10 'I065=6 SUB I065 I063` DIV I064 10: I064의 값을 10으로 나누고 몫을 I064에 할당하여, I064의 변수 값은 5가 됩니다. SET I063 I064: I064의 값을 I063에 할당하여, 그 결과 I063의 변수 값은 5가 됩니다. MUL I063 10: I063의 값을 10과 곱한 후(5 × 10), 그 결과를 I063에 할당하여, I063의 변수 값은 50이 됩니다. SUB I065 I063: I065의 값에서 I063의 값을 빼고(56 - 50), 그 결과를 I065에 할당하여 I065의 변수 값은 6이 됩니다. 위 코드는 I061을 I064와 I065로 파싱합니다(즉, 56은 5와 6으로 나누어집니다).
레이블 파싱 결과에 따라 처리 방법을 채택하기	`IFTHENEXP I064=5 'add handling logic a PAUSE ELSE 'add handling logic b PAUSE ENDIF` 위 코드는 I064가 5일 경우 논리 A가 실행되고, 그렇지 않으면 논리 B가 실행된다는 것을 나타냅니다. 처리 방법은 레이블 파싱 결과에 따라 달라집니다. 비즈니스 요구 사항에 따라 처리 방법을 선택할 수 있습니다.

레이블을 파싱하기

MM_GET_POSE명령어는 특정 비전 포인트의 TCP 포즈와 레이블, 말단장치 번호가 각각 변수P071과 I61, I62에 저장될 수 있습니다. 이 샘플에서는 I061변수의 값이 56로 가정합니다.

SET I064 I061
SET I065 I061

위 할당문을 실행한 후, I064와 I065의 변수 값은 56입니다.

'I064=5
DIV I064 10
SET I063 I064
MUL I063 10
'I065=6
SUB I065 I063

DIV I064 10: I064의 값을 10으로 나누고 몫을 I064에 할당하여, I064의 변수 값은 5가 됩니다.
SET I063 I064: I064의 값을 I063에 할당하여, 그 결과 I063의 변수 값은 5가 됩니다.
MUL I063 10: I063의 값을 10과 곱한 후(5 × 10), 그 결과를 I063에 할당하여, I063의 변수 값은 50이 됩니다.
SUB I065 I063: I065의 값에서 I063의 값을 빼고(56 - 50), 그 결과를 I065에 할당하여 I065의 변수 값은 6이 됩니다.

위 코드는 I061을 I064와 I065로 파싱합니다(즉, 56은 5와 6으로 나누어집니다).

레이블 파싱 결과에 따라 처리 방법을 채택하기

IFTHENEXP I064=5
	'add handling logic a
	 PAUSE
ELSE
	'add handling logic b
	 PAUSE
ENDIF

위 코드는 I064가 5일 경우 논리 A가 실행되고, 그렇지 않으면 논리 B가 실행된다는 것을 나타냅니다. 처리 방법은 레이블 파싱 결과에 따라 달라집니다. 비즈니스 요구 사항에 따라 처리 방법을 선택할 수 있습니다.

이 페이지가 도움이 되었습니까?

피드백 남기기

지원해 주셔서 감사합니다!

다음 방법을 통해 피드백을 보내주실 수 있습니다:

저희는 귀하의 개인정보를 소중히 다룹니다.

당사 웹사이트는 최상의 사용자 경험을 제공하기 위해 쿠키를 사용하고 있습니다. "모두 수락"을 클릭하시면 쿠키 사용에 동의하시는 것이며, "모두 거부"를 클릭하시면 이 웹사이트 방문 시 귀하의 정보가 추적되거나 기억되지 않도록 단일 쿠키만 사용됩니다.

모두 수락

모두 거부