샘플 프로그램12: MM_S12_Viz_ForLoop
프로그램 소개
기능 설명 |
로봇이 Mech-Viz 프로젝트 실행을 트리거한 후, 경로 계획 결과를 획득하고 루프를 통해 계획된 경로를 저장하여 피킹 및 배치 작업을 수행합니다. |
파일 경로 |
Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 |
필요한 프로젝트 |
Mech-Vision와 Mech-Viz 프로젝트 |
사용 전제 조건 |
|
| 이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
다음에는 MM_S12_Viz_ForLoop 샘플 프로그램의 코드와 관련 설명입니다.
| MM_S2_Viz_Basic은 웨이포인트를 하나씩으로 저장하는 반면, MM_S12_Viz_ForLoop은 루프를 통해 웨이포인트를 저장합니다(이 기능의 코드는 굵게 표시됨). 따라서, MM_S12_Viz_ForLoop의 MM_S2_Viz_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S2_Viz_Basic샘플 프로그램 설명을 참조하십시오). |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project and get planned path, ;
4: !get poses using for-loop ;
5: !structure ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: UFRAME_NUM=0 ;
11: !set current tool NO. to 1 ;
12: UTOOL_NUM=1 ;
13: !move to robot home position ;
14:J P[1] 100% FINE ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
19: !move to image-capturing position ;
20:L P[2] 1000mm/sec FINE ;
21: !trigger Mech-Viz project ;
22: CALL MM_START_VIZ(2,10) ;
23: !get planned path, 1st argument ;
24: !(1) means getting pose in JPs ;
25: CALL MM_GET_VIZ(1,51,52,53) ;
26: !check whether planned path has ;
27: !been got from Mech-Viz ;
28: !successfully ;
29: IF R[53]<>2100,JMP LBL[99] ;
30: !save waypoints of the planned ;
31: !path to local variables using ;
32: !for-loop structure ;
33: FOR R[100]=1 TO R[51] ;
34: R[101]=59+R[100] ;
35: R[102]=69+R[100] ;
36: R[103]=79+R[100] ;
37: CALL MM_GET_JPS(R[100],R[101],R[102],R[103]) ;
38: ENDFOR ;
39: !follow the planned path to pick, ;
40: !in this example waypoint 2 ;
41: !(PR[61]) is picking waypoint ;
42: !move to approach waypoint ;
43: !of picking ;
44:J PR[60] 50% FINE ;
45: !move to picking waypoint ;
46:J PR[61] 10% FINE ;
47: !add object grasping logic here, ;
48: !such as "DO[1]=ON" ;
49: PAUSE ;
50: !move to departure waypoint ;
51: !of picking ;
52:J PR[62] 50% FINE ;
53: !move to intermediate waypoint ;
54: !of placing ;
55:J P[3] 50% CNT100 ;
56: !move to approach waypoint ;
57: !of placing ;
58:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
59: !move to placing waypoint ;
60:L P[4] 300mm/sec FINE ;
61: !add object releasing logic here, ;
62: !such as "DO[1]=OFF" ;
63: PAUSE ;
64: !move to departure waypoint ;
65: !of placing ;
66:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
67: !move back to robot home position ;
68:J P[1] 100% FINE ;
69: END ;
70: ;
71: LBL[99:vision error] ;
72: !add error handling logic here ;
73: !according to different ;
74: !error codes ;
75: !e.g.: status=2038 means no ;
76: !point cloud in ROI ;
77: PAUSE ;위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.
아래 표는 루프를 통해 웨이포인트를 저장하는 기능의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.
| 워크플로 | 코드와 설명 |
|---|---|
루프를 통해 계획 경로를 저장하기 |
분 샘플이 계획한 경로 중 웨이포인트는 3개로 가정하면 위 순환은 MM_S2_Viz_Basic 샘플 중 아래와 같이 3개의 명령어와 동일합니다. |