샘플 프로그램 19: MM_S19_Vis_PlanAllVision
프로그램 소개
기능 설명 |
로봇이 Mech-Vision 프로젝트 실행을 트리거한 후 루프를 통해 모든 계획된 경로를 획득하여 피킹 및 배치 작업을 수행합니다. 이 샘플에서는 카메라가 이미지를 한 번만 캡처하면 Mech-Vision가 모든 비전 결과에 대한 피킹 경로를 계획합니다. 일반적으로 멀티 피킹 시나리오에 적용합니다. |
파일 경로 |
Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 |
필요한 프로젝트 |
|
사용 전제 조건 |
|
이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
다음에는 MM_S19_Vis_PlanAllVision 샘플 프로그램의 코드와 관련 설명입니다.
MM_S3_Vis_Path 샘플과 비하면, 이 샘플은 루프를 통해 모든 계획된 경로를 획득하여 피킹 및 배치 작업을 수행하는 기능만 수정되었습니다.(이 부분의 코드는 굵게 표시됨) 따라서, MM_S19_Vis_PlanAllVision의 MM_S3_Vis_Path과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S3_Vis_Path샘플 프로그램 설명을 참조하십시오). |
DEF MM_S19_Vis_PlanAllVision ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Vision project, plan all
; vision results and get all planned paths
; Mech-Mind, 2023-12-25
;---------------------------------------------------
;set current tool no. to 1
BAS(#TOOL,1)
;set current base no. to 0
BAS(#BASE,0)
;move to robot home position
PTP HOME Vel=100 % DEFAULT
;initialize communication parameters (initialization is required only once)
MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
RECAP:
;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
;trigger Mech-Viz project
MM_Start_Vis(1,0,2,init_jps)
;get planned path from NO.1 Mech-Vision project; 2nd argument (1) means getting pose in JPs
MM_Get_Vispath(1,1,pos_num,vis_pos_num,status)
;check whether planned path has been got from Mech-Vision successfully
IF status<> 1103 THEN
;add error handling logic here according to different error codes
;e.g.: status=1003 means no point cloud in ROI
;e.g.: status=1002 means no vision results
halt
ENDIF
;save waypoints of the planned path to local variables one by one
FOR count=1 TO pos_num
MM_Get_Jps(count,pick_point[count],label[count],toolid[count])
ENDFOR
;parse pick cycle count, here suppose 5 points per planned path
pick_cnt = pos_num / 5
residual = pos_num - pick_cnt*5
;check if parsed data is valid; if not, retry to get planned path or add some error handling logic
IF (pick_cnt<1) OR (residual<>0) THEN
halt
GOTO RECAP
ENDIF
;repeatedly run pick-and-place cycle using for-loop
FOR i=1 TO pick_cnt
count=(i-1)*5
Xpick_point1=pick_point[1+count]
Xpick_point2=pick_point[2+count]
Xpick_point3=pick_point[3+count]
Xpick_point4=pick_point[4+count]
Xpick_point5=pick_point[5+count]
;follow the planned path to pick
;move to approach waypoint of picking
PTP pick_point1 CONT Vel=50 % PDAT1 Tool[1] Base[0]
PTP pick_point2 Vel=50 % PDAT2 Tool[1] Base[0]
PTP pick_point3 Vel=10 % PDAT3 Tool[1] Base[0]
;add object grasping logic here, such as "$OUT[1]=TRUE"
halt
PTP pick_point4 Vel=50 % PDAT5 Tool[1] Base[0]
PTP pick_point5 CONT Vel=50 % PDAT6 Tool[1] Base[0]
;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT4 Tool[1] Base[0]
;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT2 Tool[1] Base[0]
;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT3 Tool[1] Base[0]
;add object releasing logic here, such as "$OUT[1]=FALSE"
halt
;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT2 Tool[1] Base[0]
;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT4 Tool[1] Base[0]
ENDFOR
;finish pick and-place cycle, and jump back to camera capturing
GOTO RECAP
END
위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.

아래 표는 새롭게 추가된 기능의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.
워크플로 | 코드와 설명 |
---|---|
루프를 통해 계획 경로를 저장하기 |
|
pick_cnt 및 residual를 계산하기 |
본 샘플에서는 매번 계획된 피킹 경로에 5개의 웨이포인트가 포함된다고 가정합니다. "pos_num / 5"는 pos_num을 5로 나눈 몫을 의미합니다. "pos_num - pick_cnt*5"는 pos_num을 5로 나눈 나머지를 의미합니다. pick_cnt는 계획된 총 피킹 횟수를 나타냅니다. residual 값이 0이 아닌 경우, 특정 계획된 피킹 웨이포인트 개수가 5개 미만임을 의미하며, 이는 경로 계획에 이상이 발생했음을 나타내므로 다시 계획을 수행해야 합니다. |
경로 계획 오류가 발생했는지 확인하기 |
피킹 횟수 pick_cnt가 1보다 작은 경우 또는 residual 값이 0이 아닌 경우, 경로 계획 중 오류가 발생했음을 의미하며 사용자는 여기에서 코드 처리를 추가해야 합니다. 예를 들어 Mech-Vision 프로젝트를 다시 트리거하여 계획 경로를 획득하는 코드를 추가합니다. |
루프를 통해 피킹 및 배치 작업을 실행하기 |
위의 코드는 FOR 루프 내에서 로봇이 매번 계획된 5개의 웨이포인트로 이동하여 피킹 작업을 수행한 후, 이어서 배치 작업을 실행하는 것을 나타냅니다. i는 순환 횟수를 제어하는 변수로, 1부터 시작하여 매 순환마다 1씩 증가하며, 피킹 횟수 pick_cnt보다 커지면 루프가 종료됩니다. i가 1 증가할 때마다 count가 5 증가하며, 이를 통해 [1+count] ~ [5+count]는 매번 계획된 5개의 웨이포인트가 전체 계획 경로에서 차지하는 번호를 나타냅니다. |