샘플 프로그램15: MM_S15_Viz_GetDoList
프로그램 소개
기능 설명 |
로봇은 피킹 경로와 DO 신호를 획득한 후 피킹 웨이 포인트로 이동하고 DO 신호를 설정하여 피킹 작업을 완료합니다. 이 샘플 예시는 일반적으로 디팔레타이징 시나리오에 사용되며, 로봇의 말단장치는 멀티 파티션 빨판입니다. |
파일 경로 |
Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 |
필요한 프로젝트 |
Mech-Vision와 Mech-Viz 프로젝트(말단장치 유형은 디팔레타이징 진공 그리퍼입니다) |
사용 전제 조건 |
|
| 이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
아래는 MM_S15_Viz_GetDoList 샘플 프로그램 코드와 관련 설명입니다.
| MM_S2_Viz_Basic 샘플과 비교하면 이 샘플은 아래와 같이 굵게 표시된 코드 부분만 수정되었습니다. 따라서 MM_S15_Viz_GetDoList의 MM_S2_Viz_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S2_Viz_Basic 샘플 프로그램 설명을 참조하십시오). |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project, then get planned path ;
4: !and gripper control signal using ;
5: !command 210 ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: UFRAME_NUM=0 ;
11: !set current tool NO. to 1 ;
12: UTOOL_NUM=1 ;
13: !move to robot home position ;
14:J P[1] 100% FINE ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: CALL MM_INIT_SKT('8','127.0.0.1',30000,5) ;
19: !move to image-capturing position ;
20:L P[2] 1000mm/sec FINE ;
21: !trigger Mech-Viz project ;
22: CALL MM_START_VIZ(2,10,53) ;
23: !check whether viz project has ;
24: !been triggered successfully ;
25: IF (R[53]<>2103),JMP LBL[99] ;
26: !get planned path ;
27: CALL MM_GET_PLNDT(0,3,51,52,53) ;
28: !check whether planned path has ;
29: !been got from Mech-Viz ;
30: !successfully ;
31: IF R[53]<>2100,JMP LBL[99] ;
32: !get gripper control signal list ;
33: CALL MM_GET_DL(0,0,53) ;
34: !check whether viz DoList has ;
35: !been gotten successfully ;
36: IF (R[53]<>2102),JMP LBL[99] ;
37: !save waypoints of the planned ;
38: !path to local variables one ;
39: !by one ;
40: CALL MM_GET_PLJOP(1,3,60,61,62,63,64,70) ;
41: CALL MM_GET_PLJOP(2,3,61,91,92,93,94,100) ;
42: CALL MM_GET_PLJOP(3,3,62,121,122,123,124,130) ;
43: !follow the planned path to pick ;
44: !move to approach waypoint ;
45: !of picking ;
46:J PR[60] 50% FINE ;
47: !move to picking waypoint ;
48:J PR[61] 10% FINE ;
49: !add object grasping logic here ;
50: PAUSE ;
51: !set gripper control signal ;
52: CALL MM_SET_DL(0) ;
53: !move to departure waypoint ;
54: !of picking ;
55:J PR[62] 50% FINE ;
56: !move to intermediate waypoint ;
57: !of placing ;
58:J P[3] 50% CNT100 ;
59: !move to approach waypoint ;
60: !of placing ;
61:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
62: !move to placing waypoint ;
63:L P[4] 300mm/sec FINE ;
64: !add object releasing logic here, ;
65: !such as "DO[1]=OFF" ;
66: PAUSE ;
67: !move to departure waypoint ;
68: !of placing ;
69:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
70: !move back to robot home position ;
71:J P[1] 100% FINE ;
72: END ;
73: ;
74: LBL[99:vision error] ;
75: !add error handling logic here ;
76: !according to different ;
77: !error codes ;
78: !e.g.: status=2038 means no ;
79: !point cloud in ROI ;
80: !e.g.: mm_status=3099 means ;
81: !failed to open socket ;
82: PAUSE ;위 샘플 프로그램 코드에 해당하는 작업 흐름은 아래 그림에 표시되어 있습니다.
아래 표는 굵게 표시된 코드의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.
| 작업 흐름 | 코드와 설명 | ||
|---|---|---|---|
계획 경로를 획득하기 |
|
||
진공 그리퍼의 DO 신호를 가져오기 |
|
||
계획 경로를 저장하기 |
따라서 "CALL MM_GET_PLJOP(1,3,60,61,62,63,64,70)"는 첫 번째 웨이 포인트의 포즈, 이동 유형, 말단장치 번호, 속도, 비전 이동 계획 결과 및 사용자 정의 데이터를 지정된 레지스터에 저장하는 명령어입니다.
|
||
피킹 웨이 포인트로 이동하고 피킹하기 |
따라서 위 문장은 로봇이 피킹 웨이 포인트(PR[61])로 이동한 후 MM_SET_DL 명령어를 통해 진공 그리퍼의 DO 신호를 설정하여 피킹 작업을 완료함을 나타냅니다. |