샘플 프로그램 19: MM_S19_Vis_PlanAllVision

현재 최신 버전 (2.1.2)에 대한 매뉴얼을 보고 계십니다. 다른 버전에 액세스하려면 페이지 오른쪽 상단 모서리에 있는 '버전 전환' 버튼을 클릭하세요.

■ 현재 사용하고 있는 제품의 버전이 확실하지 않은 경우에는 언제든지 당사 기술 지원팀에 문의하시기 바랍니다.

프로그램 소개

기능 설명

로봇이 Mech-Vision 프로젝트 실행을 트리거한 후 루프를 통해 모든 계획된 경로를 획득하여 피킹 및 배치 작업을 수행합니다. 이 샘플에서는 카메라가 이미지를 한 번만 캡처하면 Mech-Vision가 모든 비전 결과에 대한 피킹 경로를 계획합니다. 일반적으로 멀티 피킹 시나리오에 적용합니다.

파일 경로

Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 통신 구성 요소/Robot_Interface/FANUC/sample/MM_S19_Vis_PlanAllVision 경로를 사용하여 파일을 찾을 수 있습니다.

필요한 프로젝트

Mech-Vision 프로젝트

이 프로젝트는 다음 구성을 미리 설정해야 함:경로 계획 도구의 작업 흐름 화면에서 전역 구성 스텝의 모든 비전 결과를 계획하기를 활성화해야 합니다.
sample19 1

사용 조건

  1. 표준 인터페이스 통신 구성이 완료됩니다.

  2. 자동 캘리브레이션이 완료됩니다.
이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오.

프로그램 설명

다음에는 MM_S19_Vis_PlanAllVision 샘플 프로그램의 코드와 관련 설명입니다.

MM_S3_Vis_Path 샘플과 비하면, 이 샘플은 루프를 통해 모든 계획된 경로를 획득하여 피킹 및 배치 작업을 수행하는 기능만 수정되었습니다.(이 부분의 코드는 굵게 표시됨) 따라서, MM_S19_Vis_PlanAllVision의 MM_S3_Vis_Path과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S3_Vis_Path샘플 프로그램 설명을 참조하십시오). 
   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project, plan all vision results ;
   4:  !and get all planned paths ;
   5:  !Mech-Mind, 2023-12-25 ;
   6:  !-------------------------------- ;
   7:   ;
   8:  !set current uframe NO. to 0 ;
   9:  UFRAME_NUM=0 ;
  10:  !set current tool NO. to 1 ;
  11:  UTOOL_NUM=1 ;
  12:  !move to robot home position ;
  13:J P[1] 100% FINE    ;
  14:  !initialize communication ;
  15:  !parameters(initialization is ;
  16:  !required only once) ;
  17:  CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  18:  LBL[1:recap] ;
  19:  !move to image-capturing position ;
  20:L P[2] 1000mm/sec FINE    ;
  21:  !trigger NO.1 Mech-Vision project ;
  22:  CALL MM_START_VIS(1,0,2,10) ;
  23:  !get planned path from NO.1 ;
  24:  !Mech-Vision project; 2nd ;
  25:  !argument (1) means getting pose ;
  26:  !in JPs ;
  27:  CALL MM_GET_VISP(1,1,51,52,53) ;
  28:  !check whether planned path has ;
  29:  !been got from Mech-Vision ;
  30:  !successfully ;
  31:  IF R[53]<>1103,JMP LBL[99] ;
  32:  !save all waypoint data to local ;
  33:  !variables using for-loop, a ;
  34:  !maximum of 50 points are support ;
  35:  !supported ;
  36:  FOR R[10]=1 TO R[51] ;
  37:  R[11]=59+R[10]    ;
  38:  R[12]=69+R[10]    ;
  39:  R[13]=99+R[10]    ;
  40:  CALL MM_GET_JPS(R[10],R[11],R[12],R[13]) ;
  41:  ENDFOR ;
  42:  !parse pick cycle count, here ;
  43:  !suppose 5 points per planned ;
  44:  !path ;
  45:  R[30]=R[51] DIV 5    ;
  46:  R[29]=R[51] MOD 5    ;
  47:  !check if parsed data is valid; ;
  48:  !if not, retry to get planned ;
  49:  !path or add some error handling ;
  50:  !logic ;
  51:  IF R[30]<1) OR (R[29]<>0 THEN ;
  52:  PAUSE ;
  53:  JMP LBL[1] ;
  54:  ENDIF ;
  55:  !repeatedly run pick-and-place ;
  56:  !cycle using for-loop ;
  57:  FOR R[10]=1 TO R[30] ;
  58:  R[20]=R[10]-1    ;
  59:  R[21]=R[20]*5    ;
  60:  R[31]=60+R[21]    ;
  61:  R[32]=61+R[21]    ;
  62:  R[33]=62+R[21]    ;
  63:  R[34]=63+R[21]    ;
  64:  R[35]=64+R[21]    ;
  65:  !follow the planned path to pick ;
  66:J PR[R[31]] 50% CNT100    ;
  67:J PR[R[32]] 50% FINE    ;
  68:J PR[R[33]] 10% FINE    ;
  69:  !add object grasping logic here, ;
  70:  !such as "DO[1]=ON" ;
  71:  PAUSE ;
  72:J PR[R[34]] 50% FINE    ;
  73:J PR[R[35]] 50% CNT100    ;
  74:  !move to intermediate waypoint ;
  75:  !of placing ;
  76:J P[3] 50% CNT100    ;
  77:  !move to approach waypoint ;
  78:  !of placing ;
  79:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  80:  !move to placing waypoint ;
  81:L P[4] 300mm/sec FINE    ;
  82:  !add object releasing logic here, ;
  83:  !such as "DO[1]=OFF" ;
  84:  PAUSE ;
  85:  !move to departure waypoint ;
  86:  !of placing ;
  87:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  88:  !move to intermediate waypoint ;
  89:  !of placing ;
  90:J P[3] 50% CNT100    ;
  91:  ENDFOR ;
  92:  !finish pick-and-place cycle, and ;
  93:  !jump back to camera capturing ;
  94:  JMP LBL[1] ;
  95:  END ;
  96:   ;
  97:  LBL[99:vision error] ;
  98:  !add error handling logic here ;
  99:  !according to different ;
 100:  !error codes ;
 101:  !e.g.: status=1003 means no ;
 102:  !point cloud in ROI ;
 103:  !e.g.: status=1002 means no ;
 104:  !vision results ;
 105:  PAUSE ;

위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.

sample19

아래 표는 새롭게 추가된 기능의 설명입니다. 명령어 이름의 링크를 클릭하면 해당 명령의 상세 설명을 확인할 수 있습니다.

워크플로 코드와 설명

루프를 통해 계획 경로를 저장하기

 
  32:  !save all waypoint data to local ;
  33:  !variables using for-loop, a ;
  34:  !maximum of 50 points are support ;
  35:  !supported ;
  36:  FOR R[10]=1 TO R[51] ;
  37:  R[11]=59+R[10]    ;
  38:  R[12]=69+R[10]    ;
  39:  R[13]=99+R[10]    ;
  40:  CALL MM_GET_JPS(R[10],R[11],R[12],R[13]) ;
  41:  ENDFOR ;

  • 36번째 줄: FOR는 아래 코드가 반복 실행되는 루프 프로그램임을 나타냅니다. R[10]는 반복 횟수를 제어하며, 1부터 시작하여 매 반복마다 1씩 증가하고, R[51]보다 커지면 루프가 종료됩니다. R[51]은 MM_GET_VISP 명령어의 세 번째 파라미터에 해단하는 데이터 레지스터로, 비전 시스템이 반환한 웨이포인트 개수를 저장합니다. 따라서 R[10]는 해당 웨이포인트가 계획 경로에 번호를 나타낼 수 있습니다.

  • 37~39번째 줄: R[11], R[12], R[13]은 긱각 해당 웨이포인트의 관절 각도, 레이블, 말단장치 번호가 사용한 레지스터의 번호를 의미합니다.

  • 40번째 줄: MM_GET_JPS 명령어는 특정 웨이포인트의 관절 각도, 레이블, 말단장치 번호를 각각 지정된 레지스터에 저장합니다. 따가서 전체 명령어는 번호가 R[10]인 웨이포인트의 관절 각도, 레이블, 말단장치 번호를 순서대로 R[11], R[12], R[13]이 표현하는 레지스터로 저장합니다.

R[30] 및 R[29]를 계산하기

 
  42:  !parse pick cycle count, here ;
  43:  !suppose 5 points per planned ;
  44:  !path ;
  45:  R[30]=R[51] DIV 5    ;
  46:  R[29]=R[51] MOD 5    ;

이 샘플에서는 매번 계획된 피킹 경로에 5개의 경로 웨이포인트가 포함된다고 가정합니다. "R[51] DIV 5"는 R[51]을 5로 나눈 몫을 의미하며, "R[51] MOD 5"는 R[51]을 5로 나눈 나머지를 의미합니다. R[30]은 계획된 피킹의 총 횟수를 의미합니다. R[29] 값이 0이 아닌 경우, 특정 계획된 피킹 웨이포인트 개수가 5개 미만임을 의미하며, 이는 경로 계획에 이상이 발생했음을 나타내므로 다시 계획을 수행해야 합니다.

경로 계획 오류가 발생했는지 확인하기

 
  47:  !check if parsed data is valid; ;
  48:  !if not, retry to get planned ;
  49:  !path or add some error handling ;
  50:  !logic ;
  51:  IF ((R[30]<1) OR (R[29]<>0)) THEN ;
  52:  PAUSE ;
  53:  JMP LBL[1] ;
  54:  ENDIF ;

피킹 횟수 R[30]가 1보다 작은 경우 또는 R[29] 값이 0이 아닌 경우, 경로 계획 중 오류가 발생했음을 의미하며 사용자는 여기에서 코드 처리를 추가해야 합니다. 예를 들어 Mech-Vision 프로젝트를 다시 트리거하여 계획 경로를 획득하는 코드를 추가합니다.

루프를 통해 피킹 및 배치 작업을 실행하기

 
  55:  !repeatedly run pick-and-place ;
  56:  !cycle using for-loop ;
  57:  FOR R[10]=1 TO R[30] ;
  58:  R[20]=R[10]-1    ;
  59:  R[21]=R[20]*5    ;
  60:  R[31]=60+R[21]    ;
  61:  R[32]=61+R[21]    ;
  62:  R[33]=62+R[21]    ;
  63:  R[34]=63+R[21]    ;
  64:  R[35]=64+R[21]    ;
  65:  !follow the planned path to pick ;
  66:J PR[R[31]] 50% CNT100    ;
  67:J PR[R[32]] 50% FINE    ;
  68:J PR[R[33]] 10% FINE    ;
  69:  !add object grasping logic here, ;
  70:  !such as "DO[1]=ON" ;
  71:  PAUSE ;
  72:J PR[R[34]] 50% FINE    ;
  73:J PR[R[35]] 50% CNT100    ;
  74:  !move to intermediate waypoint ;
  75:  !of placing ;
  76:J P[3] 50% CNT100    ;
  77:  !move to approach waypoint ;
  78:  !of placing ;
  79:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  80:  !move to placing waypoint ;
  81:L P[4] 300mm/sec FINE    ;
  82:  !add object releasing logic here, ;
  83:  !such as "DO[1]=OFF" ;
  84:  PAUSE ;
  85:  !move to departure waypoint ;
  86:  !of placing ;
  87:L P[4] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  88:  !move to intermediate waypoint ;
  89:  !of placing ;
  90:J P[3] 50% CNT100    ;
  91:  ENDFOR ;

위의 코드는 FOR 루프 내에서 로봇이 매번 계획된 5개의 웨이포인트로 이동하여 피킹 작업을 수행한 후, 이어서 배치 작업을 실행하는 것을 나타냅니다. R[10]은 순환 횟수를 제어하는 변수로, 1부터 시작하여 매 순환마다 1씩 증가하며, 피킹 횟수 R[30]보다 커지면 루프가 종료됩니다. R[10]이 1 증가할 때마다 R[21]은 5 증가합니다. 또한, 60 + R[21] \~ 64 + R[21] (즉, R[31] ~ R[35])는 매번 계획된 5개의 웨이포인트이 저장될 5개의 레지스터 번호를 나타냅니다.

이 페이지가 도움이 되었습니까?

다음 방법을 통해 피드백을 보내주실 수 있습니다:

저희는 귀하의 개인정보를 소중히 다룹니다.

당사 웹사이트는 최상의 사용자 경험을 제공하기 위해 쿠키를 사용하고 있습니다. "모두 수락"을 클릭하시면 쿠키 사용에 동의하시는 것이며, "모두 거부"를 클릭하시면 이 웹사이트 방문 시 귀하의 정보가 추적되거나 기억되지 않도록 단일 쿠키만 사용됩니다.

  • Preference
  • 모두 수락
  • 모두 거부