샘플 프로그램10：MM_S10_Viz_Subtask
프로그램 소개
기능 설명 |
이 샘플은 두 개의 프로그램으로 구성되어 있습니다. 그 중, 서브 프로그램(백그라운드 프로그램)은 Mech-Viz프로젝트 실행을 트리거하고 계획된 경로를 가져오는 역할을 합니다. 메인 프로그램(포어그라운드 프로그램)은 계획된 경로에 따라 로봇을 이동시키며, 로봇이 피킹 영역에 떠날 때 서브 프로그램을 실행하여 다음 라운드 경로를 미리 계획하여 사이클 타임을 단축합니다.
|
||
파일 경로 |
서브 프로그램: Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 메인 프로그램: Mech-Vision 및 Mech-Viz의 설치 디렉토리로 이동하여 |
||
필요한 프로젝트 |
Mech-Vision와 Mech-Viz 프로젝트 |
||
사용 전제 조건 |
|
|
이 샘플 프로그램은 참고용으로 제공됩니다. 사용자는 실제 상황에 맞춰 이 내용을 바탕으로 수정해야 하며, 해당 프로그램을 그대로 사용하지 않도록 하십시오. |
프로그램 설명
아래는 서브 프로그램의 코드와 관련된 설명입니다.
| 서브 프로그램에서 Mech-Viz 프로젝트 실행을 트리거하고 계획 경로의 코드를 획득합니다. MM_S2_Viz_Basic 샘플과 비슷합니다. 따라서, MM_S10_Viz_Subtask의 MM_S2_Viz_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S2_Viz_Basic샘플 프로그램 설명을 참조하십시오). |
1: !-------------------------------- ;
2: !FUNCTION: run Mech-Viz project ;
3: !and get planned path in subtask ;
4: !(run together with ;
5: !MM_S10_Viz_Subtask) ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: F[11]=(ON) ;
10: !trigger Mech-Viz project ;
11: CALL MM_START_VIZ(2,10) ;
12: !get planned path, 1st argument ;
13: !(1) means getting pose in JPs ;
14: CALL MM_GET_VIZ(1,51,52,53) ;
15: !check whether planned path has ;
16: !been got from Mech-Viz ;
17: !successfully ;
18: IF (R[53]=2100) THEN ;
19: !save waypoints of the planned ;
20: !path to local variables one ;
21: !by one ;
22: CALL MM_GET_JPS(1,60,70,80) ;
23: CALL MM_GET_JPS(2,61,71,81) ;
24: CALL MM_GET_JPS(3,62,72,82) ;
25: ENDIF ;
26: F[11]=(OFF) ;위의 코드는 서브 프로그램이 실행할 때 다음의 워크플로를 수행합니다.
-
F[11]이 ON으로 설정합니다.
-
Mech-Viz 프로젝트 실행을 트리거합니다.
-
계획 경로를 획득합니다.
-
계획 경로를 저장합니다.
-
F[11]이 OFF으로 설정합니다.
F[11] 값에 따라 서브 프로그램이 실행이 완료되는지 확인할 수 있습니다.
아래는 메인 프로그램의 코드와 관련된 설명입니다.
| 메인 프로그램에서 계획된 경로에 따라 피킹 및 배치의 코드를 실행합니다. MM_S2_Viz_Basic 샘플과 비슷합니다. 따라서, MM_S10_Viz_Subtask의 MM_S2_Viz_Basic과 일치하는 부분은 다시 설명하지 않습니다. (일치하는 부분에 대한 정보는 MM_S2_Viz_Basic샘플 프로그램 설명을 참조하십시오). |
1: !-------------------------------- ;
2: !FUNCTION: run Mech-Viz project ;
3: !and get planned path in subtask ;
4: !(run together with ;
5: !MM_S10_Sub) ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: UFRAME_NUM=0 ;
11: !set current tool NO. to 1 ;
12: UTOOL_NUM=1 ;
13: !initialize communication ;
14: !parameters(initialization is ;
15: !required only once) ;
16: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
17: !move to robot home position ;
18:J P[1] 100% FINE ;
19: RUN MM_S10_SUB ;
20: LBL[1:LOOP] ;
21: !move to wait position for ;
22: !picking ;
23:L P[2] 1000mm/sec FINE ;
24: !wait until subtask program ;
25: !finished ;
26: WAIT (F[11]=OFF) ;
27: !check whether planned path has ;
28: !been got from Mech-Viz ;
29: !successfully ;
30: IF R[53]<>2100,JMP LBL[99] ;
31: !follow the planned path to pick ;
32: !move to approach waypoint ;
33: !of picking ;
34:J PR[60] 50% FINE ;
35: !move to picking waypoint ;
36:J PR[61] 10% FINE ;
37: !add object grasping logic here, ;
38: !such as "DO[1]=ON" ;
39: PAUSE ;
40: !move to departure waypoint ;
41: !of picking ;
42:J PR[62] 50% FINE ;
43: !move to intermediate waypoint ;
44: !of placing, and trigger Mech-Viz ;
45: !project and get planned path in ;
46: !advance ;
47:J P[3] 50% CNT100 DB 10.0mm,CALL MM_S10_SUB ;
48: !move to approach waypoint ;
49: !of placing ;
50:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
51: !move to placing waypoint ;
52:L P[4] 300mm/sec FINE ;
53: !add object releasing logic here, ;
54: !such as "DO[1]=OFF" ;
55: PAUSE ;
56: !move to departure waypoint ;
57: !of placing ;
58:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
59: !move back to robot home position ;
60:J P[1] 100% FINE ;
61: JMP LBL[1] ;
62: END ;
63: ;
64: LBL[99:vision error] ;
65: !add error handling logic here ;
66: !according to different ;
67: !error codes ;
68: !e.g.: status=2038 means no ;
69: !point cloud in ROI ;
70: PAUSE ;위 샘플 프로그램 코드에 해당하는 워크플로는 아래 그림에 표시되어 있습니다.
아래 표는 메인 프로그램 주요 코드의 설명입니다.
| 워크플로 | 코드와 설명 | ||
|---|---|---|---|
Mech-Viz 프로젝트 실행를 트리거하여 경로 계획을 획득하기 |
위의 코드는 메인 프로그램은 MM_S10_SUB 서브 프로그램을 호출하여 Mech-Viz 프로젝트 실행를 트리거하여 경로 계획을 획득합니다.
|
||
루프(피킹→다음 경로 계획을 트리거하기→배치)를 통해 다음 경로를 미리 계획하기 |
위의 코드는 메인 프로그램은 LBL[1] 위치의 코드를 순환하게 수행합니다. 위 코드는 로봇이 한 피킹 사전 대기 웨이포인트로 이동한 후, 서브 프로그램이 실행이 완료될 때까지(즉, F[11]이 ON이 OFF로 전환됨) 대기하여 계획 경로를 획득하고 저장하는 것을 확인합니다. 위 코드는 로봇이 계획된 경로에 따라 피킹 접근 웨이포인트(PR[60])로 이동한 후 피킹 웨이포인트(PR[61])로 이동하여 피킹(예를 들어 DO[1]=ON)하고, 피킹 출발 웨이포인트(PR[62])로 이동하는 것을 나타낸다. 위 전체 명령어는 "우선 거리 실행" 명령어를 의미하며, 구체적인 설명은 다음과 같습니다.
위의 코드는 로봇이 P[3] 중심으로 구형 범위에 도달할 때 MM_S10_SUB 서브 프로그램을 호출합니다. 즉, Mech-Viz 프로젝트 실행를 다시 트리거하여 경로 계획을 획득합니다. 여기는 로봇이 이미 피킹 영역을 벗어나 있으므로, 배치 완성을 기다릴 필요 없고, 미리 다음 피킹 경로를 계획할 수 있습니다.
위 코드는 로봇이 먼저 순서대로 배치 접근 웨이포인트(Tool_Offset,PR[2]), 배치 웨이포인트(P[4])로 이동한 후, 배치 작업(예: DO[1]=OFF)을 수행하고, 그 후 배치 출발 웨이포인트(Tool_Offset,PR[2]과 Home 포인트로 순차적으로 이동하는 것을 나타냅니다. |