サンプルプログラム6：MM_S6_Viz_ErrorHandle

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project and get planned path, ;
   4:  !handle errors according to ;
   5:  !status codes (if no point cloud ;
   6:  !in ROI, retry several times ;
   7:  !before exit loop) ;
   8:  !Mech-Mind, 2023-12-25 ;
   9:  !-------------------------------- ;
  10:   ;
  11:  !set current uframe NO. to 0 ;
  12:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  13:  !set current tool NO. to 1 ;
  14:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  15:  !reset counter ;
  16:  ﾚｼﾞ[99]=0    ;
  17:  !move to robot home position ;
  18:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  19:  !initialize communication ;
  20:  !parameters(initialization is ;
  21:  !required only once) ;
  22:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
  23:  !move to image-capturing position ;
  24:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  25:  ﾗﾍﾞﾙ[1:vision] ;
  26:  !trigger Mech-Viz project ;
  27:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
  28:  !check whether viz project has ;
  29:  !been triggered successfully ;
  30:  ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  31:  !get planned path, 1st argument ;
  32:  !(1) means getting pose in JPs ;
  33:  ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
  34:  !check whether planned path has ;
  35:  !been got from Mech-Viz ;
  36:  !successfully ;
  37:  ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  38:  !save waypoints of the planned ;
  39:  !path to local variables one ;
  40:  !by one ;
  41:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
  42:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
  43:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
  44:  !follow the planned path to pick ;
  45:  !move to approach waypoint ;
  46:  !of picking ;
  47:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ    ;
  48:  !move to picking waypoint ;
  49:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ    ;
  50:  !add object grasping logic here, ;
  51:  !such as "DO[1]=ON" ;
  52:  ｲﾁｼﾞﾃｲｼ ;
  53:  !move to departure waypoint ;
  54:  !of picking ;
  55:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ    ;
  56:  !move to intermediate waypoint ;
  57:  !of placing ;
  58:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  59:  !move to approach waypoint ;
  60:  !of placing ;
  61:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  62:  !move to placing waypoint ;
  63:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ    ;
  64:  !add object releasing logic here, ;
  65:  !such as "DO[1]=OFF" ;
  66:  ｲﾁｼﾞﾃｲｼ ;
  67:  !move to departure waypoint ;
  68:  !of placing ;
  69:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  70:  !move back to robot home position ;
  71:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  72:  ｼｭｳﾘｮｳ ;
  73:   ;
  74:  ﾗﾍﾞﾙ[99:handling error] ;
  75:  !add error handling logic here ;
  76:  !according to different ;
  77:  !error codes ;
  78:  !e.g.: mm_status=2038 means no ;
  79:  !point cloud in ROI ;
  80:  !e.g.: mm_status=3099 means ;
  81:  !failed to open socket ;
  82:  ﾓｼ ﾚｼﾞ[53]=2038,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[2] ;
  83:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[999] ;
  84:   ;
  85:  ﾗﾍﾞﾙ[2] ;
  86:  !no point cloud in ROI, add ;
  87:  !handling logic here ;
  88:  !self-adding then check retry ;
  89:  !counter ;
  90:  ﾚｼﾞ[99]=ﾚｼﾞ[99]+1    ;
  91:  !jump back to vision retry label ;
  92:  !if the number of retry times is ;
  93:  !less than 3 ;
  94:  ﾓｼ ﾚｼﾞ[99]<3,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
  95:  !reset counter and exit loop if ;
  96:  !the number of retry times has ;
  97:  !reached 3 ;
  98:  ﾚｼﾞ[99]=0    ;
  99:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[999] ;
 100:   ;
 101:  ﾗﾍﾞﾙ[999:other error] ;
 102:  !add other error handling logic ;
 103:  !here ;
 104:  ｲﾁｼﾞﾃｲｼ ;