サンプルプログラム18：MM_S18_Viz_GetUserData
プログラム概要
機能 |
ロボットは把持経路と共に、Mech-Visionプロジェクトから出力されたカスタムデータを取得します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト（出力 ステップに カスタムポート に追加する必要があります）、Mech-Vizプロジェクト（ロボットハンド種類がデパレタイズ用吸盤である必要があります） |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S18_Viz_GetUserDataサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S15_Viz_GetDoListサンプルに比べて、太字部分のコードのみが追加されています。そのため、MM_S15_Viz_GetDoListサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S15_Viz_GetDoListサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project, then get planned path ;
4: !and get custom data from ;
5: !Mech-Vision using command 210 ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
11: !set current tool NO. to 1 ;
12: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
13: !move to robot home position ;
14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
19: !move to image-capturing position ;
20:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
21: !trigger Mech-Viz project ;
22: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
23: !check whether viz project has ;
24: !been triggered successfully ;
25: ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
26: !get planned path ;
27: ﾖﾋﾞﾀﾞｼ MM_GET_PLNDT(0,3,51,52,53) ;
28: !check whether planned path has ;
29: !been got from Mech-Viz ;
30: !successfully ;
31: ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
32: !get gripper control signal list ;
33: ﾖﾋﾞﾀﾞｼ MM_GET_DL(0,0,53) ;
34: !check whether viz DoList has ;
35: !been gotten successfully ;
36: ﾓｼ (ﾚｼﾞ[53]<>2102),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
37: !save waypoints of the planned ;
38: !path to local variables one ;
39: !by one ;
40: ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(1,3,60,61,62,63,64,70) ;
41: ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(2,3,61,91,92,93,94,100) ;
42: ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(3,3,62,121,122,123,124,130) ;
43: !save received custom data of ;
44: !2nd point ;
45: ﾚｼﾞ[10]=ﾚｼﾞ[94] ;
46: ﾚｼﾞ[11]=ﾚｼﾞ[95] ;
47: ﾚｼﾞ[12]=ﾚｼﾞ[96] ;
48: !follow the planned path to pick ;
49: !move to approach waypoint ;
50: !of picking ;
51:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
52: !move to picking waypoint ;
53:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
54: !add object grasping logic here ;
55: ｲﾁｼﾞﾃｲｼ ;
56: !set gripper control signal ;
57: ﾖﾋﾞﾀﾞｼ MM_SET_DL(0) ;
58: !move to departure waypoint ;
59: !of picking ;
60:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
61: !move to intermediate waypoint ;
62: !of placing ;
63:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
64: !move to approach waypoint ;
65: !of placing ;
66:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
67: !move to placing waypoint ;
68:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
69: !add object releasing logic here, ;
70: !such as "DO[1]=OFF" ;
71: ｲﾁｼﾞﾃｲｼ ;
72: !move to departure waypoint ;
73: !of placing ;
74:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
75: !move back to robot home position ;
76:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
77: ｼｭｳﾘｮｳ ;
78: ;
79: ﾗﾍﾞﾙ[99:handling error] ;
80: !add error handling logic here ;
81: !according to different ;
82: !error codes ;
83: !e.g.: mm_status=2038 means no ;
84: !point cloud in ROI ;
85: !e.g.: mm_status=3099 means ;
86: !failed to open socket ;
87: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は追加されたコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 | ||||
|---|---|---|---|---|---|
経路点のカスタムデータを保存 |
ロボットは MM_GET_PLNDT コマンドを使用して経路点の「ビジョン処理による移動」の計画結果とカスタムデータを取得し、その後、MM_GET_PLJOP コマンドを通じて経路点の「ビジョン処理による移動」の計画結果とカスタムデータをロボットメモリから指定されたレジスタに保存します。このサンプルでは、把持点（ｲﾁﾚｼﾞ[61]）のカスタムデータがﾚｼﾞ[94]から格納されます。 上記のコードは、「ビジョン処理による移動」の経路点（把持点）の3つのカスタムデータﾚｼﾞ[94]、ﾚｼﾞ[95]、ﾚｼﾞ[96]をそれぞれﾚｼﾞ[10]、ﾚｼﾞ[11]、ﾚｼﾞ[12]に代入することを意味します。
|