サンプルプログラム14：MM_S14_Vis_GetUserData
プログラム概要
機能 |
ロボットはビジョン結果と共に、Mech-Visionプロジェクトから出力されたカスタムデータを取得します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト（出力 ステップに カスタムポート を追加する必要があります） |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S14_Vis_GetUserDataサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S1_Vis_Basicサンプルに比べて、太字部分のコードのみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get vision result ;
4: !and custom data using ;
5: !command 110 ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
11: !set current tool NO. to 1 ;
12: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
13: !move to robot home position ;
14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
19: !move to image-capturing position ;
20:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
21: !trigger NO.1 Mech-Vision project ;
22: ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10,53) ;
23: !check whether vision project has ;
24: !been triggered successfully ;
25: ﾓｼ (ﾚｼﾞ[53]<>1102),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
26: !get vision result from NO.1 ;
27: !Mech-Vision project ;
28: ﾖﾋﾞﾀﾞｼ MM_GET_DY_DT(1,51,53) ;
29: !check whether vision result has ;
30: !been got from Mech-Vision ;
31: !successfully ;
32: ﾓｼ (ﾚｼﾞ[53]<>1100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
33: !save first vision point data to ;
34: !local variables ;
35: ﾖﾋﾞﾀﾞｼ MM_GET_DYPOS(1,60,70,90) ;
36: !save received custom data ;
37: ﾚｼﾞ[10]=ﾚｼﾞ[90] ;
38: ﾚｼﾞ[11]=ﾚｼﾞ[91] ;
39: ﾚｼﾞ[12]=ﾚｼﾞ[92] ;
40: !move to intermediate waypoint ;
41: !of picking ;
42:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
43: !move to approach waypoint ;
44: !of picking ;
45:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
46: !move to picking waypoint ;
47:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ ;
48: !add object grasping logic here, ;
49: !such as "DO[1]=ON" ;
50: ｲﾁｼﾞﾃｲｼ ;
51: !move to departure waypoint ;
52: !of picking ;
53:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
54: !move to intermediate waypoint ;
55: !of placing ;
56:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100 ;
57: !move to approach waypoint ;
58: !of placing ;
59:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
60: !move to placing waypoint ;
61:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ ;
62: !add object releasing logic here, ;
63: !such as "DO[1]=OFF" ;
64: ｲﾁｼﾞﾃｲｼ ;
65: !move to departure waypoint ;
66: !of placing ;
67:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
68: !move back to robot home position ;
69:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
70: ｼｭｳﾘｮｳ ;
71: ;
72: ﾗﾍﾞﾙ[99:handling error] ;
73: !add error handling logic here ;
74: !according to different ;
75: !error codes ;
76: !e.g.: mm_status=1003 means no ;
77: !point cloud in ROI ;
78: !e.g.: mm_status=1002 means no ;
79: !vision results ;
80: !e.g.: mm_status=3099 means ;
81: !failed to open socket ;
82: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は太字部分のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 | ||||
|---|---|---|---|---|---|
ビジョン結果（カスタムデータを含む）を取得 |
このコマンドは、ロボットがMech-Visionプロジェクト1から返されたビジョン結果（カスタムデータを含む）を取得することを意味します。
|
||||
ビジョン結果（カスタムデータを含む）を保存 |
このコマンドは、最初のビジョンポイントのツール位置姿勢、ラベル、およびカスタムデータをそれぞれ指定されたレジスタに保存することを意味します。 上記のコードは、ビジョンポイント（把持点）の3つのカスタムデータﾚｼﾞ[90]、ﾚｼﾞ[91]、ﾚｼﾞ[92]をそれぞれﾚｼﾞ[10]、ﾚｼﾞ[11]、ﾚｼﾞ[12]に代入することを意味します。
|