サンプルプログラム11：MM_S11_Viz_Timer

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project and get planned path, ;
   4:  !add a timer to record cycle time ;
   5:  !Mech-Mind, 2023-12-25 ;
   6:  !-------------------------------- ;
   7:   ;
   8:  !set current uframe NO. to 0 ;
   9:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  10:  !set current tool NO. to 1 ;
  11:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  12:  !move to robot home position ;
  13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  14:  !initialize communication ;
  15:  !parameters(initialization is ;
  16:  !required only once) ;
  17:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
  18:  ﾗﾍﾞﾙ[1:LOOP] ;
  19:  !reset timer to 0 ;
  20:  ﾀｲﾏ[1]=ﾘｾｯﾄ ;
  21:  !start timer ;
  22:  ﾀｲﾏ[1]=ｽﾀｰﾄ ;
  23:  !move to image-capturing position ;
  24:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  25:  !trigger Mech-Viz project ;
  26:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
  27:  !check whether viz project has ;
  28:  !been triggered successfully ;
  29:  ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  30:  !get planned path, 1st argument ;
  31:  !(1) means getting pose in JPs ;
  32:  ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
  33:  !check whether planned path has ;
  34:  !been got from Mech-Viz ;
  35:  !successfully ;
  36:  ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  37:  !save waypoints of the planned ;
  38:  !path to local variables one ;
  39:  !by one ;
  40:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
  41:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
  42:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
  43:  !follow the planned path to pick ;
  44:  !move to approach waypoint ;
  45:  !of picking ;
  46:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ    ;
  47:  !move to picking waypoint ;
  48:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ    ;
  49:  !add object grasping logic here, ;
  50:  !such as "DO[1]=ON" ;
  51:  ｲﾁｼﾞﾃｲｼ ;
  52:  !move to departure waypoint ;
  53:  !of picking ;
  54:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ    ;
  55:  !move to intermediate waypoint ;
  56:  !of placing ;
  57:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  58:  !move to approach waypoint ;
  59:  !of placing ;
  60:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  61:  !move to placing waypoint ;
  62:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ    ;
  63:  !add object releasing logic here, ;
  64:  !such as "DO[1]=OFF" ;
  65:  ｲﾁｼﾞﾃｲｼ ;
  66:  !move to departure waypoint ;
  67:  !of placing ;
  68:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  69:  !move back to robot home position ;
  70:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  71:  !stop timer ;
  72:  ﾀｲﾏ[1]=ｽﾄｯﾌﾟ ;
  73:  !save timer value to register ;
  74:  ﾚｼﾞ[99]=ﾀｲﾏ[1]    ;
  75:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
  76:  ｼｭｳﾘｮｳ ;
  77:   ;
  78:  ﾗﾍﾞﾙ[99:handling error] ;
  79:  !add error handling logic here ;
  80:  !according to different ;
  81:  !error codes ;
  82:  !e.g.: mm_status=2038 means no ;
  83:  !point cloud in ROI ;
  84:  !e.g.: mm_status=3099 means ;
  85:  !failed to open socket ;
  86:  ｲﾁｼﾞﾃｲｼ ;