サンプルプログラム4：MM_S4_Vis_ChangeModel
プログラム概要
機能 |
ロボットはMech-Visionのパラメータレシピを切り替え、その後Mech-Visionプロジェクトをトリガーして実行します。ビジョン結果を取得し、その結果に基づいて把持および配置を実行します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-Visionプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S4_Vis_ChangeModelサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S1_Vis_Basicサンプルに比べて、Mech-Visionのパラメータレシピを切り替える機能（太字部分のコード）のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project after switching recipe ;
4: !and get vision result ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
10: !set current tool NO. to 1 ;
11: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
12: !move to robot home position ;
13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
18: !move to image-capturing position ;
19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
20: !switch recipe of NO.1 ;
21: !Mech-Vision project, ;
22: !"MM_SET_MOD(Proj_num,Model_num, ;
23: !mm_status,socket_status)" ;
24: ﾖﾋﾞﾀﾞｼ MM_SET_MOD(1,1,53) ;
25: !check whether vision recipe has ;
26: !been switched successfully ;
27: ﾓｼ (ﾚｼﾞ[53]<>1107),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
28: !trigger NO.1 Mech-Vision project ;
29: ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10,53) ;
30: !check whether vision project has ;
31: !been triggered successfully ;
32: ﾓｼ (ﾚｼﾞ[53]<>1102),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
33: !get vision result from NO.1 ;
34: !Mech-Vision project ;
35: ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
36: !check whether vision result has ;
37: !been got from Mech-Vision ;
38: !successfully ;
39: ﾓｼ (ﾚｼﾞ[53]<>1100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
40: !save first vision point data to ;
41: !local variables ;
42: ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
43: !move to intermediate waypoint ;
44: !of picking ;
45:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
46: !move to approach waypoint ;
47: !of picking ;
48:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
49: !move to picking waypoint ;
50:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ ;
51: !add object grasping logic here, ;
52: !such as "DO[1]=ON" ;
53: ｲﾁｼﾞﾃｲｼ ;
54: !move to departure waypoint ;
55: !of picking ;
56:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
57: !move to intermediate waypoint ;
58: !of placing ;
59:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100 ;
60: !move to approach waypoint ;
61: !of placing ;
62:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
63: !move to placing waypoint ;
64:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ ;
65: !add object releasing logic here, ;
66: !such as "DO[1]=OFF" ;
67: ｲﾁｼﾞﾃｲｼ ;
68: !move to departure waypoint ;
69: !of placing ;
70:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
71: !move back to robot home position ;
72:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
73: ｼｭｳﾘｮｳ ;
74: ;
75: ﾗﾍﾞﾙ[99:handling error] ;
76: !add error handling logic here ;
77: !according to different ;
78: !error codes ;
79: !e.g.: mm_status=1003 means no ;
80: !point cloud in ROI ;
81: !e.g.: mm_status=1002 means no ;
82: !vision results ;
83: !e.g.: mm_status=3099 means ;
84: !failed to open socket ;
85: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表はMech-Visionのパラメータレシピを切り替えるコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
Mech-Visionのパラメータレシピを切り替る |
このコマンドは、Mech-Visionプロジェクト1のパラメータレシピを番号1のレシピに切り替えることを意味します。
上記のコードは、ステータスコードﾚｼﾞ[53]が1107の場合、ロボットはMech-Visionパラメータレシピを正常に切り替えること意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはﾗﾍﾞﾙ[99]にジャンプして実行を続けることを意味します。以下にﾗﾍﾞﾙ[99]のコードを示します。 ユーザーは、特定のエラーコードに応じて適切な処理を行うことが可能です。本サンプルでは、すべてのエラーコードに対して同一の処理を行い、PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドを使用してプログラムの実行を停止しています。 |