サンプルプログラム9：MM_S9_Viz_RunInAdvance
プログラム概要
機能 |
ロボットは把持時にMech-Vizプロジェクトをトリガーし、その後、分岐設定により配置時にカメラ撮影をトリガーします。これにより、次の経路を事前に計画し、サイクルタイムを短縮します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S9_Viz_RunInAdvanceサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S5_Viz_SetBranchサンプルに比べて、次の経路を事前に計画する機能（太字部分のコード）のみが追加されています。そのため、MM_S5_Viz_SetBranchサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S5_Viz_SetBranchサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project then set branch and get ;
4: !planned path, trigger Mech-Viz ;
5: !project and set branch in ;
6: !advance during pick&place proces ;
7: !process ;
8: !Mech-Mind, 2023-12-25 ;
9: !-------------------------------- ;
10: ;
11: !set current uframe NO. to 0 ;
12: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
13: !set current tool NO. to 1 ;
14: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
15: !move to robot home position ;
16:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
17: !initialize communication ;
18: !parameters(initialization is ;
19: !required only once) ;
20: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
21: !move to image-capturing position ;
22:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
23: !trigger Mech-Viz project ;
24: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
25: !check whether viz project has ;
26: !been triggered successfully ;
27: ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
28: !set branch ;
29: ﾖﾋﾞﾀﾞｼ MM_SET_BCH(1,1,53) ;
30: !check whether viz branch has ;
31: !been set successfully ;
32: ﾓｼ (ﾚｼﾞ[53]<>2105),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
33: ﾗﾍﾞﾙ[1:LOOP] ;
34: !get planned path, 1st argument ;
35: !(1) means getting pose in JPs ;
36: ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
37: !check whether planned path has ;
38: !been got from Mech-Viz ;
39: !successfully ;
40: ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
41: !save waypoints of the planned ;
42: !path to local variables one ;
43: !by one ;
44: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
45: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
46: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
47: !follow the planned path to pick ;
48: !move to approach waypoint ;
49: !of picking ;
50:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
51: !move to picking waypoint ;
52:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
53: !add object grasping logic here, ;
54: !such as "DO[1]=ON" ;
55: ｲﾁｼﾞﾃｲｼ ;
56: !trigger Mech-Viz project but not ;
57: !to trigger camera capturing ;
58: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
59: !check whether viz project has ;
60: !been triggered successfully ;
61: ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
62: !move to departure waypoint ;
63: !of picking ;
64:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
65: !move to intermediate waypoint ;
66: !of placing ;
67:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
68: !move to approach waypoint ;
69: !of placing ;
70:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
71: !set branch exit port and trigger ;
72: !camera capturing when robot ;
73: !moves out of camera’s field of ;
74: !view ;
75: ﾖﾋﾞﾀﾞｼ MM_SET_BCH(1,1,53) ;
76: !check whether viz branch has ;
77: !been set successfully ;
78: ﾓｼ (ﾚｼﾞ[53]<>2105),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
79: !move to placing waypoint ;
80:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
81: !add object releasing logic here, ;
82: !such as "DO[1]=OFF" ;
83: ｲﾁｼﾞﾃｲｼ ;
84: !move to departure waypoint ;
85: !of placing ;
86:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
87: !move back to robot home position ;
88:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
89: ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
90: ｼｭｳﾘｮｳ ;
91: ;
92: ﾗﾍﾞﾙ[99:handling error] ;
93: !add error handling logic here ;
94: !according to different ;
95: !error codes ;
96: !e.g.: mm_status=2038 means no ;
97: !point cloud in ROI ;
98: !e.g.: mm_status=3099 means ;
99: !failed to open socket ;
100: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
以下は、次の経路を事前に計画するコードとその説明です。
| 処理流れ | コートと説明 | ||
|---|---|---|---|
ループで次の経路を事前に計画（把持→次の把持経路を計画→配置） |
上記のコードは、プログラムがﾗﾍﾞﾙ[1]で示すコードを繰り返し実行することを意味します。 上記のコードは、ロボットが MM_GET_VIZ コマンドを使用してMech-Vizが計画された経路を取得することを意味します。 上記のコードは、ロボットが MM_GET_JPS コマンドを使用して計画された経路を指定されたレジスタに保存することを意味します。このサンプルでは、ｲﾁﾚｼﾞ[60]、ｲﾁﾚｼﾞ[61]、ｲﾁﾚｼﾞ[62]がそれぞれ把持のアプローチ点、把持点、把持の離れる点であると仮定しています。 上記のコードは、ロボットが把持のアプローチ点、把持点、把持の離れる点の順に移動し、DOコマンド（例えばDO[1]=ON）を設定することでロボットハンドを制御し、把持を実行することを意味します。
上記のコードは、ロボットが MM_START_VIZ コマンドを使用してMech-Vizプロジェクトを再度トリガーします。この時点で、ロボットは今回計画された把持経路を取得し、把持点に移動しているため、配置が完了するのを待つことなく、事前にMech-Vizプロジェクトをトリガーして次の経路を計画することができます。
上記のコードは、ロボットが把持の離れる点（ｲﾁﾚｼﾞ[62]）、中間点（ｲﾁ[3]）、配置のアプローチ点（ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]）の順に移動することを意味します。 上記のコードは、ロボットが MM_SET_BCH コマンドを使用して「メッセージによって異なる分岐を実行」ステップの出口を設定することを意味します。この分岐出口では、「ビジョン処理による認識」ステップが実行され、Mech-Vizはビジョン認識の結果に基づいて次の把持経路を事前に計画します。 上記のコードは、ロボットが配置点（ｲﾁ[4]）に移動して配置を行い（例えばDO[1]=OFF）、その後、配置の離れる点（ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]）、Home位置の順に移動することを意味します。 |