サンプルプログラム12：MM_S12_Viz_ForLoop
プログラム概要
機能 |
ロボットがMech-Vizプロジェクトをトリガーして実行し、計画された経路を取得します。その後、ループで計画された経路を保存し、把持および配置を実行します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S12_Viz_ForLoopサンプルプログラムのコードと関連する説明です。
| MM_S2_Viz_Basicは計画された経路点を一つずつ保存しますが、このサンプル（太字部分のコード）はループを使用して計画された経路点を保存します。そのため、MM_S2_Viz_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S2_Viz_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project and get planned path, ;
4: !get poses using for-loop ;
5: !structure ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
11: !set current tool NO. to 1 ;
12: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
13: !move to robot home position ;
14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
19: !move to image-capturing position ;
20:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
21: !trigger Mech-Viz project ;
22: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
23: !check whether viz project has ;
24: !been triggered successfully ;
25: ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
26: !get planned path, 1st argument ;
27: !(1) means getting pose in JPs ;
28: ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
29: !check whether planned path has ;
30: !been got from Mech-Viz ;
31: !successfully ;
32: ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
33: !save waypoints of the planned ;
34: !path to local variables using ;
35: !for-loop structure ;
36: FOR ﾚｼﾞ[100]=1 TO ﾚｼﾞ[51] ;
37: ﾚｼﾞ[101]=59+ﾚｼﾞ[100] ;
38: ﾚｼﾞ[102]=69+ﾚｼﾞ[100] ;
39: ﾚｼﾞ[103]=79+ﾚｼﾞ[100] ;
40: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(ﾚｼﾞ[100],ﾚｼﾞ[101],ﾚｼﾞ[102],ﾚｼﾞ[103]) ;
41: ENDFOR ;
42: !follow the planned path to pick, ;
43: !in this example waypoint 2 ;
44: !(PR[61]) is picking waypoint ;
45: !move to approach waypoint ;
46: !of picking ;
47:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
48: !move to picking waypoint ;
49:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
50: !add object grasping logic here, ;
51: !such as "DO[1]=ON" ;
52: ｲﾁｼﾞﾃｲｼ ;
53: !move to departure waypoint ;
54: !of picking ;
55:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
56: !move to intermediate waypoint ;
57: !of placing ;
58:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
59: !move to approach waypoint ;
60: !of placing ;
61:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
62: !move to placing waypoint ;
63:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
64: !add object releasing logic here, ;
65: !such as "DO[1]=OFF" ;
66: ｲﾁｼﾞﾃｲｼ ;
67: !move to departure waypoint ;
68: !of placing ;
69:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
70: !move back to robot home position ;
71:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
72: ｼｭｳﾘｮｳ ;
73: ;
74: ﾗﾍﾞﾙ[99:handling error] ;
75: !add error handling logic here ;
76: !according to different ;
77: !error codes ;
78: !e.g.: mm_status=2038 means no ;
79: !point cloud in ROI ;
80: !e.g.: mm_status=3099 means ;
81: !failed to open socket ;
82: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は、ループで計画された経路を保存するコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
ループで計画された経路を保存 |
このサンプルで計画された経路に3つの経路点があると仮定すると、上記のループは MM_S2_Viz_Basic サンプルで次の3つのコマンドに相当します。 |