サンプルプログラム5：MM_S5_Viz_SetBranch
プログラム概要
機能 |
ロボットはMech-Vizプロジェクトをトリガーして実行し、Mech-Vizの分岐出口を設定します。その後、計画された経路を取得し、把持および配置を実行します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S5_Viz_SetBranchサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S2_Viz_Basicサンプルに比べて、Mech-Vizの分岐出口設定機能（太字部分のコード）のみが追加されています。そのため、MM_S2_Viz_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S2_Viz_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project then set branch and get ;
4: !planned path ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
10: !set current tool NO. to 1 ;
11: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
12: !move to robot home position ;
13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
18: !move to image-capturing position ;
19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
20: !trigger Mech-Viz project ;
21: ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
22: !check whether viz project has ;
23: !been triggered successfully ;
24: ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
25: !set branch ;
26: ﾖﾋﾞﾀﾞｼ MM_SET_BCH(1,1,53) ;
27: !check whether viz branch has ;
28: !been set successfully ;
29: ﾓｼ (ﾚｼﾞ[53]<>2105),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
30: !get planned path, 1st argument ;
31: !(1) means getting pose in JPs ;
32: ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
33: !check whether planned path has ;
34: !been got from Mech-Viz ;
35: !successfully ;
36: ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
37: !save waypoints of the planned ;
38: !path to local variables one ;
39: !by one ;
40: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
41: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
42: ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
43: !follow the planned path to pick ;
44: !move to approach waypoint ;
45: !of picking ;
46:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ ;
47: !move to picking waypoint ;
48:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ ;
49: !add object grasping logic here, ;
50: !such as "DO[1]=ON" ;
51: ｲﾁｼﾞﾃｲｼ ;
52: !move to departure waypoint ;
53: !of picking ;
54:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ ;
55: !move to intermediate waypoint ;
56: !of placing ;
57:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
58: !move to approach waypoint ;
59: !of placing ;
60:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
61: !move to placing waypoint ;
62:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ ;
63: !add object releasing logic here, ;
64: !such as "DO[1]=OFF" ;
65: ｲﾁｼﾞﾃｲｼ ;
66: !move to departure waypoint ;
67: !of placing ;
68:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
69: !move back to robot home position ;
70:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
71: ｼｭｳﾘｮｳ ;
72: ;
73: ﾗﾍﾞﾙ[99:handling error] ;
74: !add error handling logic here ;
75: !according to different ;
76: !error codes ;
77: !e.g.: mm_status=2038 means no ;
78: !point cloud in ROI ;
79: !e.g.: mm_status=3099 means ;
80: !failed to open socket ;
81: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表はMech-Viz分岐出口設定のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
Mech-Vizの分岐ステップの出口を設定 |
このコマンドは、Mech-Vizプロジェクトが番号1の「メッセージによって異なる分岐を実行」ステップで出口0から実行を続けることを意味します。 
上記のコードは、ステータスコードﾚｼﾞ[53]が2105の場合、ロボットはMech-Vizのメッセージ分岐出口を正常に設定することを意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはﾗﾍﾞﾙ[99]にジャンプして実行を続けることを意味します。以下にﾗﾍﾞﾙ[99]のコードを示します。 |