MM_S22_Vis_As_Uframe
プログラム概要
機能 |
ロボットがMech-Visionプロジェクトを実行してビジョン結果を取得し、その結果を座標系として用いて、把持および配置動作のフローを実行します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S22_Vis_As_Uframeサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S3_Vis_Pathサンプルに比べて、すべての計画された経路をループで取得し、把持および配置を行う機能（太字部分のコード）のみが追加されています。そのため、MM_S3_Vis_Pathサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S3_Vis_Pathサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get vision result ;
4: !as the uframe 7 ;
5: !Mech-Mind, 2026-1-23 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
10: !set current tool NO. to 1 ;
11: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
12: !move to robot home position ;
13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
18: !move to image-capturing position ;
19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
20: !trigger NO.1 Mech-Vision project ;
21: ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10,53) ;
22: !check whether vision project has ;
23: !been triggered successfully ;
24: ﾓｼ (ﾚｼﾞ[53]<>1102),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
25: !get vision result from NO.1 ;
26: !Mech-Vision project ;
27: ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
28: !check whether vision result has ;
29: !been got from Mech-Vision ;
30: !successfully ;
31: ﾓｼ (ﾚｼﾞ[53]<>1100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
32: !save first vision point data to ;
33: !local variables ;
34: ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
35: !move to intermediate waypoint ;
36: !of picking ;
37:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
38: ;
39: !set the uframe for camera ;
40: ﾕｰｻﾞｻﾞﾋｮｳ[7:UFrame7]=ｲﾁﾚｼﾞ[60] ;
41: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=7 ;
42: ;
43: !move to approach waypoint ;
44: !of picking ;
45:ﾁｮｸｾﾝ ｲﾁ[6] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
46: !move to picking waypoint ;
47:ﾁｮｸｾﾝ ｲﾁ[6] 300mm/sec ｲﾁｷﾞﾒ ;
48: !add object grasping logic here, ;
49: !such as "DO[1]=ON" ;
50: ｲﾁｼﾞﾃｲｼ ;
51: !move to departure waypoint ;
52: !of picking ;
53:ﾁｮｸｾﾝ ｲﾁ[6] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
54: ;
55: !change the uframe ;
56: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
57: ;
58: !move to intermediate waypoint ;
59: !of placing ;
60:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100 ;
61: !move to approach waypoint ;
62: !of placing ;
63:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
64: !move to placing waypoint ;
65:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ ;
66: !add object releasing logic here, ;
67: !such as "DO[1]=OFF" ;
68: ｲﾁｼﾞﾃｲｼ ;
69: !move to departure waypoint ;
70: !of placing ;
71:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
72: !move back to robot home position ;
73:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
74: ｼｭｳﾘｮｳ ;
75: ;
76: ﾗﾍﾞﾙ[99:handling error] ;
77: !add error handling logic here ;
78: !according to different ;
79: !error codes ;
80: !e.g.: mm_status=1003 means no ;
81: !point cloud in ROI ;
82: !e.g.: mm_status=1002 means no ;
83: !vision results ;
84: !e.g.: mm_status=3099 means ;
85: !failed to open socket ;
86: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は追加されたコードとその説明です。コマンド名のリンクをクリックすることで、その詳細を確認できます。
| 処理流れ | コートと説明 |
|---|---|
ビジョン座標系を設定 |
|
把持と配置を実行 |
上記のコードでは、ロボットはまずビジョン認識結果に基づくユーザー座標系に切り替えて把持動作を実行し、その後デフォルト座標系に戻して配置動作を実行します。最後に原点へ戻り、プログラムを終了します。ﾕｰｻﾞｻﾞﾋｮｳ[7:UFrame7]=ｲﾁﾚｼﾞ[60] は、ビジョン認識で取得した位置姿勢データをユーザー座標系 7 に代入します。ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=7 はこのビジョン座標系を有効にし、以降の把持動作をビジョン認識されたワーク位置に基づいて実行できるようにします。把持完了後、ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 によりロボットのベース座標系へ戻します。これにより、配置動作は事前に設定された基準位置に基づいて実行されます。ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] および ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] は、それぞれ把持動作および配置動作で使用するツールオフセットパラメータです。ロボット先端がワークに接近またはワークから退避する際の安全なオフセット量を制御し、干渉や衝突を防ぎます。 |