サンプルプログラム17：MM_S17_Vis_ParseLabel
プログラム概要
機能 |
ロボットはMech-Visionプロジェクトをトリガーして実行し、ビジョン結果を取得します。その後、ラベルを解析し、解析されたラベルに基づいて異なる処理ロジックを追加し、把持および配置を実行します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト（出力 ステップの labels ポートにデータがある必要があります） |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S17_Vis_ParseLabelサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S1_Vis_Basicサンプルに比べて、ラベル解析機能（太字部分のコード）のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get vision result, ;
4: !then parse the label info ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
10: !set current tool NO. to 1 ;
11: ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
12: !move to robot home position ;
13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
18: !move to image-capturing position ;
19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ ;
20: !trigger NO.1 Mech-Vision project ;
21: ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10,53) ;
22: !check whether vision project has ;
23: !been triggered successfully ;
24: ﾓｼ (ﾚｼﾞ[53]<>1102),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
25: !get vision result from NO.1 ;
26: !Mech-Vision project ;
27: ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
28: !check whether vision result has ;
29: !been got from Mech-Vision ;
30: !successfully ;
31: ﾓｼ (ﾚｼﾞ[53]<>1100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
32: !save first vision point data to ;
33: !local variables ;
34: ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
35: !parse label info received from ;
36: !Mech-Vision, eg. "R[70]=56" ;
37: !will decompose into 5 and 6 ;
38: ﾚｼﾞ[30]=ﾚｼﾞ[70] DIV 10 ;
39: ﾚｼﾞ[31]=ﾚｼﾞ[70] MOD 10 ;
40: !add handling logic according to ;
41: !decomposed label value ;
42: IF (ﾚｼﾞ[30]=5) THEN ;
43: !add handling logic a ;
44: ｲﾁｼﾞﾃｲｼ ;
45: ELSE ;
46: !add handling logic b ;
47: ｲﾁｼﾞﾃｲｼ ;
48: ENDIF ;
49: !move to intermediate waypoint ;
50: !of picking ;
51:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100 ;
52: !move to approach waypoint ;
53: !of picking ;
54:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
55: !move to picking waypoint ;
56:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ ;
57: !add object grasping logic here, ;
58: !such as "DO[1]=ON" ;
59: ｲﾁｼﾞﾃｲｼ ;
60: !move to departure waypoint ;
61: !of picking ;
62:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1] ;
63: !move to intermediate waypoint ;
64: !of placing ;
65:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100 ;
66: !move to approach waypoint ;
67: !of placing ;
68:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
69: !move to placing waypoint ;
70:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ ;
71: !add object releasing logic here, ;
72: !such as "DO[1]=OFF" ;
73: ｲﾁｼﾞﾃｲｼ ;
74: !move to departure waypoint ;
75: !of placing ;
76:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2] ;
77: !move back to robot home position ;
78:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ ;
79: ｼｭｳﾘｮｳ ;
80: ;
81: ﾗﾍﾞﾙ[99:handling error] ;
82: !add error handling logic here ;
83: !according to different ;
84: !error codes ;
85: !e.g.: mm_status=1003 means no ;
86: !point cloud in ROI ;
87: !e.g.: mm_status=1002 means no ;
88: !vision results ;
89: !e.g.: mm_status=3099 means ;
90: !failed to open socket ;
91: ｲﾁｼﾞﾃｲｼ ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は、ラベル解析機能のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
ラベルをﾚｼﾞ[30]およびﾚｼﾞ[31]に解析 |
MM_GET_POS コマンドを使用して、ビジョンポイントのツール位置姿勢、ラベル、ロボットハンド番号をそれぞれｲﾁﾚｼﾞ[60]、ﾚｼﾞ[70]、ﾚｼﾞ[80]に保存できます。このサンプルでは、ﾚｼﾞ[70]の値が56であると仮定しています。「ﾚｼﾞ[70] DIV 10」は56を10で割った商（つまり5）、「ﾚｼﾞ[70] MOD 10」は56を10で割った余り（つまり6）を表します。このようにして、56を5と6に解析します。 |
解析されたラベル値に応じた処理ロジックの追加 |
上記のコードは、ﾚｼﾞ[30]が5の場合は処理ロジックaを実行し、それ以外の場合は処理ロジックbを実行することを意味します。実際の適用シーンに応じて、異なるラベル値に対して異なる処理ロジックを追加することができます。 |