サンプルプログラム17：MM_S17_Vis_ParseLabel
プログラム概要
機能 |
ロボットはMech-Visionプロジェクトをトリガーして実行し、ビジョン結果を取得します。その後、ラベルを解析し、解析されたラベルに基づいて異なる処理ロジックを追加し、把持および配置を実行します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト（出力 ステップの labels ポートにデータがある必要があります） |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S17_Vis_ParseLabelサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S1_Vis_Basicサンプルに比べて、ラベル解析機能（太字部分のコード）のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get vision result, ;
4: !then parse the label info ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: UFRAME_NUM=0 ;
10: !set current tool NO. to 1 ;
11: UTOOL_NUM=1 ;
12: !move to robot home position ;
13:J P[1] 100% FINE ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
18: !move to image-capturing position ;
19:L P[2] 1000mm/sec FINE ;
20: !trigger NO.1 Mech-Vision project ;
21: CALL MM_START_VIS(1,0,2,10) ;
22: !get vision result from NO.1 ;
23: !Mech-Vision project ;
24: CALL MM_GET_VIS(1,51,53) ;
25: !check whether vision result has ;
26: !been got from Mech-Vision ;
27: !successfully ;
28: IF R[53]<>1100,JMP LBL[99] ;
29: !save first vision point data to ;
30: !local variables ;
31: CALL MM_GET_POS(1,60,70,80) ;
32: !parse label info received from ;
33: !Mech-Vision, eg. "R[70]=56" ;
34: !will decompose into 5 and 6 ;
35: R[30]=R[70] DIV 10 ;
36: R[31]=R[70] MOD 10 ;
37: !add handling logic according to ;
38: !decomposed label value ;
39: IF (R[30]=5) THEN ;
40: !add handling logic a ;
41: PAUSE ;
42: ELSE ;
43: !add handling logic b ;
44: PAUSE ;
45: ENDIF ;
46: !move to intermediate waypoint ;
47: !of picking ;
48:J P[3] 50% CNT100 ;
49: !move to approach waypoint ;
50: !of picking ;
51:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
52: !move to picking waypoint ;
53:L PR[60] 300mm/sec FINE ;
54: !add object grasping logic here, ;
55: !such as "DO[1]=ON" ;
56: PAUSE ;
57: !move to departure waypoint ;
58: !of picking ;
59:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
60: !move to intermediate waypoint ;
61: !of placing ;
62:J P[4] 50% CNT100 ;
63: !move to approach waypoint ;
64: !of placing ;
65:L P[5] 1000mm/sec FINE Tool_Offset,PR[2] ;
66: !move to placing waypoint ;
67:L P[5] 300mm/sec FINE ;
68: !add object releasing logic here, ;
69: !such as "DO[1]=OFF" ;
70: PAUSE ;
71: !move to departure waypoint ;
72: !of placing ;
73:L P[5] 1000mm/sec FINE Tool_Offset,PR[2] ;
74: !move back to robot home position ;
75:J P[1] 100% FINE ;
76: END ;
77: ;
78: LBL[99:vision error] ;
79: !add error handling logic here ;
80: !according to different ;
81: !error codes ;
82: !e.g.: status=1003 means no ;
83: !point cloud in ROI ;
84: !e.g.: status=1002 means no ;
85: !vision results ;
86: PAUSE ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は、ラベル解析機能のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
ラベルをR[30]およびR[31]に解析 |
MM_GET_POS コマンドを使用して、ビジョンポイントのツール位置姿勢、ラベル、ロボットハンド番号をそれぞれPR[60]、R[70]、R[80]に保存できます。このサンプルでは、R[70]の値が56であると仮定しています。「R[70] DIV 10」は56を10で割った商（つまり5）、「R[70] MOD 10」は56を10で割った余り（つまり6）を表します。このようにして、56を5と6に解析します。 |
解析されたラベル値に応じた処理ロジックの追加 |
上記のコードは、R[30]が5の場合は処理ロジックaを実行し、それ以外の場合は処理ロジックbを実行することを意味します。実際の適用シーンに応じて、異なるラベル値に対して異なる処理ロジックを追加することができます。 |