サンプルプログラム3：MM_S3_Vis_Path
プログラム概要
機能 |
ロボットがMech-Visionプロジェクトをトリガーして実行し、その後計画された経路を取得して、把持および配置を実行します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
|
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S3_Vis_Pathサンプルプログラムのコードと関連する説明です。
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get planned path ;
4: !Mech-Mind, 2023-12-25 ;
5: !-------------------------------- ;
6: ;
7: !set current uframe NO. to 0 ;
8: UFRAME_NUM=0 ;
9: !set current tool NO. to 1 ;
10: UTOOL_NUM=1 ;
11: !move to robot home position ;
12:J P[1] 100% FINE ;
13: !initialize communication ;
14: !parameters(initialization is ;
15: !required only once) ;
16: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
17: !move to image-capturing position ;
18:L P[2] 1000mm/sec FINE ;
19: !trigger NO.1 Mech-Vision project ;
20: CALL MM_START_VIS(1,0,2,10) ;
21: !get planned path from NO.1 ;
22: !Mech-Vision project; 2nd ;
23: !argument (1) means getting pose ;
24: !in JPs ;
25: CALL MM_GET_VISP(1,1,51,52,53) ;
26: !check whether planned path has ;
27: !been got from Mech-Vision ;
28: !successfully ;
29: IF R[53]<>1103,JMP LBL[99] ;
30: !save waypoints of the planned ;
31: !path to local variables one ;
32: !by one ;
33: CALL MM_GET_JPS(1,60,70,80) ;
34: CALL MM_GET_JPS(2,61,71,81) ;
35: CALL MM_GET_JPS(3,62,72,82) ;
36: !follow the planned path to pick ;
37: !move to approach waypoint ;
38: !of picking ;
39:J PR[60] 50% FINE ;
40: !move to picking waypoint ;
41:J PR[61] 10% FINE ;
42: !add object grasping logic here, ;
43: !such as "DO[1]=ON" ;
44: PAUSE ;
45: !move to departure waypoint ;
46: !of picking ;
47:J PR[62] 50% FINE ;
48: !move to intermediate waypoint ;
49: !of placing ;
50:J P[3] 50% CNT100 ;
51: !move to approach waypoint ;
52: !of placing ;
53:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
54: !move to placing waypoint ;
55:L P[4] 300mm/sec FINE ;
56: !add object releasing logic here, ;
57: !such as "DO[1]=OFF" ;
58: PAUSE ;
59: !move to departure waypoint ;
60: !of placing ;
61:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
62: !move back to robot home position ;
63:J P[1] 100% FINE ;
64: END ;
65: ;
66: LBL[99:vision error] ;
67: !add error handling logic here ;
68: !according to different ;
69: !error codes ;
70: !e.g.: status=1003 means no ;
71: !point cloud in ROI ;
72: !e.g.: status=1002 means no ;
73: !vision results ;
74: PAUSE ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は上記のプログラムのコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 | ||
|---|---|---|---|
座標系設定 |
上記の2つのコマンドは、現在選択されているユーザー座標系とツール座標系を設定することを意味します。 |
||
Home位置に移動 |
このコマンドは、ロボットが関節移動の方式で設定されたHome位置に移動することを意味します。
|
||
通信初期化 |
このコマンドは、ロボットが MM_INIT_SKT コマンドを使用して、通信対象（IPC）のIPアドレス、ポート番号、およびタイムアウト待機時間を指定し、ビジョンシステムとの接続を確立することを意味します。
|
||
撮影位置に移動 |
このコマンドは、ロボットが直線移動の方式で設定された撮影位置に移動することを意味し、移動速度は1000mm/秒です。
|
||
Mech-Visionプロジェクトをトリガー |
このコマンドは、ロボットがビジョンシステムをトリガーして番号1のMech-Visionプロジェクトを実行し、Mech-Visionプロジェクトがすべての経路点を返すことを期待することを意味します。 |
||
計画された経路を取得 |
このコマンドは、ロボットがMech-Visionプロジェクト1から返された計画経路を取得することを意味します。
上記のコードは、ステータスコードR[53]が1103の場合、ロボットがすべての計画された経路を正常に取得することを意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはLBL[99]にジャンプして実行を続けることを意味します。以下にLBL[99]のコードを示します。 ユーザーは、特定のエラーコードに応じて適切な処理を行うことが可能です。本サンプルでは、すべてのエラーコードに対して同一の処理を行い、PAUSEコマンドを使用してプログラムの実行を停止しています。 |
||
計画された経路を保存 |
「CALL MM_GET_JPS(1,60,70,80)」コマンドは、最初の経路点の関節角度、ラベル、およびロボットハンド番号をそれぞれ指定されたレジスタに保存することを意味します。
|
||
把持のアプローチ点に移動 |
ロボットが把持のアプローチ点（PR[60]が表す位置）に移動します。 |
||
把持点に移動 |
ロボットが把持点（PR[61]が表す位置）に移動します。 |
||
DO設定による把持 |
ロボットが把持点に到達した後、DOコマンド（例えば「DO[1]=ON」）を設定して、ロボットハンドを制御し、ワークを把持します。実際の状況に応じてDO設定を調整する必要があります。
|
||
把持の離れる点に移動 |
ロボットが把持の離れる点（PR[62]が表す位置）に移動します。 |
||
中間点に移動 |
このコマンドは、ロボットが関節移動の方式で、把持の離れる点と配置のアプローチ点の間の中間点に移動することを意味します。
|
||
配置のアプローチ点に移動 |
|
||
配置点に移動 |
ロボットが配置のアプローチ点から配置点に移動します。 |
||
DO設定による配置 |
ロボットが配置点に到達した後、DOコマンド（例えば「DO[1]=OFF」）を設定して、ロボットハンドを制御し、ワークを配置します。実際の状況に応じてDO設定を調整する必要があります。
|
||
配置の離れる点に移動 |
ロボットは配置点の上方の所定位置に移動し、これを配置の離れる点と呼びます。
|
||
Home位置に移動 |
ロボットが配置の離れる点からHome位置に戻ります。 |