サンプルプログラム13:MM_S13_Vis_MoveInAdvance

現在ご覧いただいているのは2.1.0 バージョンの内容です。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ 最新版をご利用される場合は、弊社ホームページよりダウンロードが可能です。ダウンロードにはパスワードが必要となりますので、サポート窓口までお問い合わせください。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

Mech-Visionプロジェクトをトリガーした後、ロボットがカメラ撮影が完了した時点で移動でき、Mech-Visionプロジェクトの実行が終了するのを待機する必要はありません。このサンプルは、カメラがEIH方式で取り付けられている場合に適しています。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/KUKA/sample/MM_S13_Vis_MoveInAdvance

必要なプロジェクト

Mech-Visionプロジェクト(EIHカメラ取り付け方式)

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。

このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S13_Vis_MoveInAdvanceサンプルプログラムのコードと関連する説明です。

このサンプルは、MM_S1_Vis_Basicサンプルに比べて、「撮影完了後に移動できる」機能(太字部分のコード)のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません(詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください)。
DEF  MM_S13_Vis_MoveInAdvance ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Vision project then move
; to wait position and get vision pose in EIH setup
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger NO.1 Mech-Vision project
   MM_Start_Vis(1,0,1,init_jps)
   ;move to wait position for picking
LIN pick_wait_point CONT Vel=1 m/s CPDAT6 Tool[1] Base[0]
   ;get vision result from NO.1 Mech-Vision project
   MM_Get_VisData(1,pos_num,status)
   ;check whether vision result has been got from Mech-Vision successfully
   IF status<> 1100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=1003 means no point cloud in ROI
      ;e.g.: status=1002 means no vision result
      halt
   ENDIF
   ;save first vision point data to local variables
   MM_Get_Pose(1,Xpick_point,label,toolid)
   ;calculate pick approach point based on pick point
   tool_offset={X 0,Y 0,Z -100,A 0,B 0,C 0}
   Xpick_app=Xpick_point:tool_offset
   ;move to intermediate waypoint of picking
PTP pick_waypoint CONT Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to approach waypoint of picking
LIN pick_app Vel=1 m/s CPDAT2 Tool[1] Base[0]
   ;move to picking waypoint
LIN pick_point Vel=0.3 m/s CPDAT3 Tool[1] Base[0]
   ;add object grasping logic here, such as "$OUT[1]=TRUE"
   halt
   ;move to departure waypoint of picking
LIN pick_app Vel=1 m/s CPDAT2 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT4 Tool[1] Base[0]
   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT5 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT4 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT
END

上記のサンプルプログラムの処理流れは、下図の通りです。

sample13

下表は、「撮影完了後に移動できる」機能のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細を確認できます。

処理流れ コートと説明

ロボットが撮影完了後に移動できる

;trigger NO.1 Mech-Vision project
MM_Start_Vis(1,0,1,init_jps)
  • MM_Start_Vis:Mech-Visionプロジェクトの実行をトリガーするためのコマンド。

  • 1:Mech-Visionプロジェクト番号。

  • 0:Mech-Visionプロジェクトがすべてのビジョンポイントを返すことを期待します。

  • 1:ロボットの現在の関節角度とフランジ位置姿勢をMech-Visionプロジェクトに送信します。カメラの取り付け方式がEIHの場合、ここは通常1に設定されます。

  • snap_jps:ユーザーによりカスタマイズされた関節角度。本プログラムでは、関節角度は使用されませんが、設定する必要があります。

EIHシーンでは、Mech-Visionプロジェクトの実行が終了するのを待たずに、カメラの撮影完了後にロボットが移動できるようにするために、Mech-Visionソフトウェア内で ロボット通信設定  次へ  詳細設定 を選択し、撮影完了後、「1102:トリガー成功」を返す にチェックを入れます。これにより、ロボットはMech-Visionプロジェクトをトリガーし、「1102:トリガー成功」を受信した後、移動を開始できるようになり、サイクルタイムを短縮できます。

下図のように設定していない場合、Mech-Visionプロジェクトが正常に実行されると、ビジョンシステムは直ちに「1102」ステータスコードをロボットに返します。このとき、ロボットは撮影が完了したかどうか判断できないため、移動することはできません。したがって、ロボットはMech-Visionプロジェクトが終了するのを待つ必要があります。

ビジョンシステムから返された「1102」ステータスコードは、MM_Start_Visコマンド内部で処理されます。下図のような設定を完了した場合、MM_Start_Visコマンドの実行が完了した後、ロボットは移動を開始できます。
configure communication
   ;move to wait position for picking
LIN pick_wait_point CONT Vel=1 m/s CPDAT6 Tool[1] Base[0]

上記のコードは、ロボットが撮影後に把持の待機点に移動できることを意味します。これにより、Mech-Visionプロジェクトの実行とロボットの移動を並行して行うことができ、サイクルタイムを短縮することができます。

MM_S1_Vis_Basic サンプルとの違いにご注意ください。MM_S1_Vis_Basicサンプルでは、ロボットはMech-Visionプロジェクトの実行が終了した後に移動できますが、本サンプルではロボットはカメラの撮影が完了した後にすぐに移動できるようになっています。

この情報は役に立ちましたか?

ご意見・ご要望がございましたら、以下よりお寄せください:

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。