サンプルプログラム20：MM_S20_Viz_PlanAllVision

現在ご覧いただいているのは2.1.0 バージョンの内容です。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ 最新版をご利用される場合は、弊社ホームページよりダウンロードが可能です。ダウンロードにはパスワードが必要となりますので、サポート窓口までお問い合わせください。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットはMech-Vizプロジェクトをトリガーして実行し、その後ループですべての計画された経路を取得し、把持および配置を実行します。このサンプルでは、カメラで1回撮影することで、Mech-Vizがすべてのビジョン結果に基づいた把持経路を計画します。通常は「1回の撮影で複数回の把持を行う」シーンで使用されます。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/FANUC/sample/MM_S20_Viz_PlanAllVision。

必要なプロジェクト

Mech-VisionとMech-Vizプロジェクト

ビジョン処理による移動 ステップの ビジョン処理の結果を再使用 パラメータにチェックが入っている必要があります。
sample20 1

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。
このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S20_Viz_PlanAllVisionサンプルプログラムのコードと関連する説明です。

このサンプルは、MM_S2_Viz_Basicサンプルに比べて、すべての計画された経路をループで取得し、把持および配置を行う機能（太字部分のコード）のみが追加されています。そのため、MM_S2_Viz_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S2_Viz_Basicサンプルの説明 をご参照ください）。 
   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project, plan all vision results ;
   4:  !and get all planned results ;
   5:  !using command 210 ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  11:  !set current tool NO. to 1 ;
  12:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  13:  !move to robot home position ;
  14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  19:  ﾗﾍﾞﾙ[1:recap] ;
  20:  !move to image-capturing position ;
  21:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  22:  !trigger Mech-Viz project ;
  23:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10) ;
  24:  !get planned path ;
  25:  ﾖﾋﾞﾀﾞｼ MM_GET_PLNDT(0,3,51,52,53) ;
  26:  !check whether planned path has ;
  27:  !been got from Mech-Viz ;
  28:  !successfully ;
  29:  ﾓｼ ﾚｼﾞ[53]<>2100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  30:  !save all waypoint data to local ;
  31:  !variables using for-loop, a ;
  32:  !maximum of 50 points are support ;
  33:  !supported ;
  34:  FOR ﾚｼﾞ[10]=1 TO ﾚｼﾞ[51] ;
  35:  ﾚｼﾞ[11]=59+ﾚｼﾞ[10]    ;
  36:  ﾚｼﾞ[12]=ﾚｼﾞ[10]*30    ;
  37:  ﾚｼﾞ[13]=31+ﾚｼﾞ[12]    ;
  38:  ﾚｼﾞ[14]=32+ﾚｼﾞ[12]    ;
  39:  ﾚｼﾞ[15]=33+ﾚｼﾞ[12]    ;
  40:  ﾚｼﾞ[16]=34+ﾚｼﾞ[12]    ;
  41:  ﾚｼﾞ[17]=40+ﾚｼﾞ[12]    ;
  42:  ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(ﾚｼﾞ[10],3,ﾚｼﾞ[11],ﾚｼﾞ[13],ﾚｼﾞ[14],ﾚｼﾞ[15],ﾚｼﾞ[16],ﾚｼﾞ[17]) ;
  43:  ENDFOR ;
  44:  !parse pick cycle count, here ;
  45:  !suppose 3 points per planned ;
  46:  !path ;
  47:  ﾚｼﾞ[30]=ﾚｼﾞ[51] DIV 3    ;
  48:  ﾚｼﾞ[31]=ﾚｼﾞ[51] MOD 3    ;
  49:  !check if parsed data is valid; ;
  50:  !if not, retry to get planned ;
  51:  !path or add some error handling ;
  52:  !logic ;
  53:  IF ﾚｼﾞ[30]<1) ﾏﾀﾊ (ﾚｼﾞ[31]<>0 THEN ;
  54:  ｲﾁｼﾞﾃｲｼ ;
  55:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
  56:  ENDIF ;
  57:  !repeatedly run pick-and-place ;
  58:  !cycle using for-loop ;
  59:  FOR ﾚｼﾞ[10]=1 TO ﾚｼﾞ[30] ;
  60:  ﾚｼﾞ[20]=ﾚｼﾞ[10]-1    ;
  61:  ﾚｼﾞ[21]=ﾚｼﾞ[20]*3    ;
  62:  ﾚｼﾞ[31]=60+ﾚｼﾞ[21]    ;
  63:  ﾚｼﾞ[32]=61+ﾚｼﾞ[21]    ;
  64:  ﾚｼﾞ[33]=62+ﾚｼﾞ[21]    ;
  65:  !move to intermediate waypoint ;
  66:  !of picking ;
  67:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  68:  !follow the planned path to pick ;
  69:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[ﾚｼﾞ[31]] 50% ｲﾁｷﾞﾒ    ;
  70:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[ﾚｼﾞ[32]] 10% ｲﾁｷﾞﾒ    ;
  71:  !add object grasping logic here ;
  72:  ｲﾁｼﾞﾃｲｼ ;
  73:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[ﾚｼﾞ[33]] 50% ｲﾁｷﾞﾒ    ;
  74:  !move to intermediate waypoint ;
  75:  !of placing ;
  76:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  77:  !move to approach waypoint ;
  78:  !of placing ;
  79:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  80:  !move to placing waypoint ;
  81:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;
  82:  !add object releasing logic here, ;
  83:  !such as "DO[1]=OFF" ;
  84:  ｲﾁｼﾞﾃｲｼ ;
  85:  !move to departure waypoint ;
  86:  !of placing ;
  87:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  88:  !move to intermediate waypoint ;
  89:  !of placing ;
  90:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  91:  ENDFOR ;
  92:  !finish pick-and-place cycle, and ;
  93:  !jump back to camera capturing ;
  94:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
  95:  ｼｭｳﾘｮｳ ;
  96:   ;
  97:  ﾗﾍﾞﾙ[99:vision error] ;
  98:  !add error handling logic here ;
  99:  !according to different ;
 100:  !error codes ;
 101:  !e.g.: status=2038 means no ;
 102:  !point cloud in ROI ;
 103:  ｲﾁｼﾞﾃｲｼ ;

上記のサンプルプログラムの処理流れは、下図の通りです。

sample20

下表は追加されたコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。

処理流れ コートと説明

計画された経路を取得

 
  24:  !get planned path ;
  25:  ﾖﾋﾞﾀﾞｼ MM_GET_PLNDT(0,3,51,52,53) ;

  • MM_GET_PLNDT：計画された経路を取得するためのコマンド。このコマンドを使用して取得した「ビジョン処理による移動」の経路点は、位置姿勢に加えて、「ビジョン処理による移動」の計画結果やカスタムデータ（ある場合）も含まれます。一方、MM_GET_VIZ コマンドを使用して取得した「ビジョン処理による移動」の経路点には、「ビジョン処理による移動」の計画結果やカスタムデータは含まれていません。

  • 0：Mech-Vizから計画された経路を取得します。

  • 3：期待される返されるデータ形式。「位置姿勢（関節角度形式）、移動方式、ロボットハンド番号、速度、Mech-Vizの「ビジョン処理による移動」の計画結果、カスタムデータ項目1、…、カスタムデータ項目N」といった形式でデータを返します。

  • 51：ﾚｼﾞ[51]の番号。このレジスタはビジョンシステムから返された経路点の数を保存します。

  • 52：ﾚｼﾞ[52]の番号。このレジスタは、「ビジョン処理による移動」の経路点（把持点）が経路全体における位置番号を保存します。

  • 53：ﾚｼﾞ[53]の番号。このレジスタはコマンド実行のステータスコードを保存します。

ループで計画された経路を保存

 
  30:  !save all waypoint data to local ;
  31:  !variables using for-loop, a ;
  32:  !maximum of 50 points are support ;
  33:  !supported ;
  34:  FOR ﾚｼﾞ[10]=1 TO ﾚｼﾞ[51] ;
  35:  ﾚｼﾞ[11]=59+ﾚｼﾞ[10]    ;
  36:  ﾚｼﾞ[12]=ﾚｼﾞ[10]*30    ;
  37:  ﾚｼﾞ[13]=31+ﾚｼﾞ[12]    ;
  38:  ﾚｼﾞ[14]=32+ﾚｼﾞ[12]    ;
  39:  ﾚｼﾞ[15]=33+ﾚｼﾞ[12]    ;
  40:  ﾚｼﾞ[16]=34+ﾚｼﾞ[12]    ;
  41:  ﾚｼﾞ[17]=40+ﾚｼﾞ[12]    ;
  42:  ﾖﾋﾞﾀﾞｼ MM_GET_PLJOP(ﾚｼﾞ[10],3,ﾚｼﾞ[11],ﾚｼﾞ[13],ﾚｼﾞ[14],ﾚｼﾞ[15],ﾚｼﾞ[16],ﾚｼﾞ[17]) ;
  43:  ENDFOR ;

  • 34行目：FORは以下のループプログラム部分を示します。ﾚｼﾞ[10]はループの回数を制御します（ﾚｼﾞ[10]は1から始まり、毎回ループ後に1増加し、ﾚｼﾞ[51]より大きくなるとループが終了します）。ﾚｼﾞ[51]は MM_GET_PLNDT コマンドにおける3番目のパラメータが表す数値レジスタで、このレジスタはビジョンシステムが返す経路点の数を保存します。したがって、ﾚｼﾞ[10]は計画された経路における現在の経路点の番号を示します。

  • 35行目～41行目：ﾚｼﾞ[11]、ﾚｼﾞ[12]、ﾚｼﾞ[13]、ﾚｼﾞ[14]、ﾚｼﾞ[15]、ﾚｼﾞ[16]、ﾚｼﾞ[17]は、それぞれ現在の経路点に対応する関節角度、移動方式、ロボットハンド番号、速度、「ビジョン処理による移動」の計画結果、およびカスタムデータで使用されるレジスタ番号を示します。

  • 42行目：MM_GET_PLJOP コマンドを使用して、経路点の関節角度、移動方式、ロボットハンド番号、速度、「ビジョン処理による移動」の計画結果、およびカスタムデータをそれぞれ指定されたレジスタに保存できます。したがって、このコマンドは、ﾚｼﾞ[10]番号の経路点の関節角度、移動方式、ロボットハンド番号、速度、「ビジョン処理による移動」の計画結果、およびカスタムデータをそれぞれﾚｼﾞ[11]、ﾚｼﾞ[12]、ﾚｼﾞ[13]、ﾚｼﾞ[14]、ﾚｼﾞ[15]、ﾚｼﾞ[16]およびﾚｼﾞ[17]が表すレジスタに保存することを意味します。

ﾚｼﾞ[30]とﾚｼﾞ[31]を計算

 
  44:  !parse pick cycle count, here ;
  45:  !suppose 3 points per planned ;
  46:  !path ;
  47:  ﾚｼﾞ[30]=ﾚｼﾞ[51] DIV 3    ;
  48:  ﾚｼﾞ[31]=ﾚｼﾞ[51] MOD 3    ;

このサンプルでは、各計画された把持経路が3つの経路点を含むことを仮定としています。「ﾚｼﾞ[51] DIV 3」はﾚｼﾞ[51]を3で割った商、「ﾚｼﾞ[51] MOD 3」はﾚｼﾞ[51]を3で割った余りを表します。ﾚｼﾞ[30]は計画された把持回数の合計を示します。ﾚｼﾞ[31]が0でない場合、ある経路計画において把持経路点の数が3未満であることを意味し、経路計画に異常が発生したため再計画が必要です。

経路計画が異常かどうかを判断

 
  49:  !check if parsed data is valid; ;
  50:  !if not, retry to get planned ;
  51:  !path or add some error handling ;
  52:  !logic ;
  53:  IF ((ﾚｼﾞ[30]<1) ﾏﾀﾊ (ﾚｼﾞ[31]<>0)) THEN ;
  54:  ｲﾁｼﾞﾃｲｼ ;
  55:  ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[1] ;
  56:  ENDIF ;

把持回数ﾚｼﾞ[30]が1未満である場合、またはﾚｼﾞ[31]が0でない場合、経路計画に異常が発生していることを示します。この場合、処理ロジックを追加する必要があります。例えば、Mech-Vizプロジェクトを再度トリガーして実行し、計画された経路を再取得するなどの対応が必要です。

ループで把持および配置を実行

 
  57:  !repeatedly run pick-and-place ;
  58:  !cycle using for-loop ;
  59:  FOR ﾚｼﾞ[10]=1 TO ﾚｼﾞ[30] ;
  60:  ﾚｼﾞ[20]=ﾚｼﾞ[10]-1    ;
  61:  ﾚｼﾞ[21]=ﾚｼﾞ[20]*3    ;
  62:  ﾚｼﾞ[31]=60+ﾚｼﾞ[21]    ;
  63:  ﾚｼﾞ[32]=61+ﾚｼﾞ[21]    ;
  64:  ﾚｼﾞ[33]=62+ﾚｼﾞ[21]    ;
  65:  !move to intermediate waypoint ;
  66:  !of picking ;
  67:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  68:  !follow the planned path to pick ;
  69:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[ﾚｼﾞ[31]] 50% ｲﾁｷﾞﾒ    ;
  70:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[ﾚｼﾞ[32]] 10% ｲﾁｷﾞﾒ    ;
  71:  !add object grasping logic here ;
  72:  ｲﾁｼﾞﾃｲｼ ;
  73:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[ﾚｼﾞ[33]] 50% ｲﾁｷﾞﾒ    ;
  74:  !move to intermediate waypoint ;
  75:  !of placing ;
  76:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  77:  !move to approach waypoint ;
  78:  !of placing ;
  79:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  80:  !move to placing waypoint ;
  81:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;
  82:  !add object releasing logic here, ;
  83:  !such as "DO[1]=OFF" ;
  84:  ｲﾁｼﾞﾃｲｼ ;
  85:  !move to departure waypoint ;
  86:  !of placing ;
  87:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;   ;
  88:  !move to intermediate waypoint ;
  89:  !of placing ;
  90:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  91:  ENDFOR ;

上記のコードは、FORループ内でロボットが各計画された経路における3つの経路点に移動し、把持を完了した後に配置を続けて実行することを意味します。ﾚｼﾞ[10]はループ回数を制御するために使用されます。ﾚｼﾞ[10]は1から始まり、各ループ後に1ずつ増加します。ﾚｼﾞ[10]が把持回数ﾚｼﾞ[30]を超えるとループは終了します。ﾚｼﾞ[10]が1増加するごとに、ﾚｼﾞ[21]も3ずつ増加します。「60+ﾚｼﾞ[21]～62+ﾚｼﾞ[21]」（ﾚｼﾞ[31]からﾚｼﾞ[33]）は、各経路計画における3つの経路点が格納される3つのレジスタ番号を示します。

この情報は役に立ちましたか？

ご意見・ご要望がございましたら、以下よりお寄せください：

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

  • Preference
  • 同意する
  • 拒否する