サンプルプログラム9:MM_S9_Viz_RunInAdvance

現在ご覧いただいているのは2.1.0 バージョンの内容です。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ 最新版をご利用される場合は、弊社ホームページよりダウンロードが可能です。ダウンロードにはパスワードが必要となりますので、サポート窓口までお問い合わせください。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットは把持時にMech-Vizプロジェクトをトリガーし、その後、分岐設定により配置時にカメラ撮影をトリガーします。これにより、次の経路を事前に計画し、サイクルタイムを短縮します。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/KUKA/sample/MM_S9_Viz_RunInAdvance

必要なプロジェクト

Mech-VisionとMech-Vizプロジェクト

Mech-Vizプロジェクトでは、事前に メッセージによる異なる分岐を設定 ステップを設定する必要があります。

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。

このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S9_Viz_RunInAdvanceサンプルプログラムのコードと関連する説明です。

このサンプルは、MM_S5_Viz_SetBranchサンプルに比べて、次の経路を事前に計画する機能(太字部分のコード)のみが追加されています。そのため、MM_S5_Viz_SetBranchサンプルと同じ部分のコードについては、以下で再度説明することはありません(詳細は MM_S5_Viz_SetBranchサンプルの説明 をご参照ください)。
DEF  MM_S9_Viz_RunInAdvance ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Viz project then set
; branch and get planned path, trigger Mech-Viz
; project and set branch in advance during
; pick&place process
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger Mech-Viz project
   MM_Start_Viz(2,init_jps)
   ;set branch exit port
   MM_Set_Branch(1,1)
LOOP
   ;get planned path, 1st argument (1) means getting pose in JPs
   MM_Get_VizData(1,pos_num,vis_pos_num,status)
   ;check whether planned path has been got from Mech-Viz successfully
   IF status<> 2100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=2038 means no point cloud in ROI
      halt
   ENDIF
   ;save waypoints of the planned path to local variables one by one
   MM_Get_Jps(1,Xpick_point1,label[1],toolid[1])
   MM_Get_Jps(2,Xpick_point2,label[2],toolid[2])
   MM_Get_Jps(3,Xpick_point3,label[3],toolid[3])
   ;follow the planned path to pick
   ;move to approach waypoint of picking
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here, such as "$OUT[1]=TRUE"
   halt
   ;trigger Mech-Viz project but not to trigger camera capturing
   MM_Start_Viz(2,init_jps)
   ;move to departure waypoint of picking
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;set branch exit port and trigger camera capturing when robot moves out of camera’s field of view
   MM_Set_Branch(1,1)
   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT
ENDLOOP
END

上記のサンプルプログラムの処理流れは、下図の通りです。

sample9

以下は、次の経路を事前に計画するコードとその説明です。

処理流れ コートと説明

ループで次の経路を事前に計画(把持→次の把持経路を計画→配置)

LOOP
    ...
ENDLOOP

上記のコードは、プログラムが「LOOP」と「ENDLOOP」の間のコードを繰り返し実行することを意味します。

;get planned path, 1st argument (1) means getting pose in JPs
MM_Get_VizData(1,pos_num,vis_pos_num,status)

上記のコードは、ロボットが MM_Get_VizData コマンドを使用してMech-Vizで計画された経路を取得することを意味します。

;save waypoints of the planned path to local variables one by one
MM_Get_Jps(1,Xpick_point1,label[1],toolid[1])
MM_Get_Jps(2,Xpick_point2,label[2],toolid[2])
MM_Get_Jps(3,Xpick_point3,label[3],toolid[3])

上記のコードは、ロボットが MM_Get_Jps コマンドを使用して計画された経路を指定された変数に保存することを意味します。このサンプルでは、Xpick_point1、Xpick_point2、Xpick_point3がそれぞれ把持のアプローチ点、把持点、把持の離れる点を表すと仮定しています。

   ;follow the planned path to pick
   ;move to approach waypoint of picking
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here, such as "$OUT[1]=TRUE"
   halt

上記のコードは、ロボットが把持のアプローチ点、把持点、把持の離れる点の順に移動し、DOコマンド(例えば$OUT[1]=TRUE)を設定することでロボットハンドを制御し、把持を実行することを意味します。

;trigger Mech-Viz project but not to trigger camera capturing
MM_Start_Viz(2,init_jps)
  • MM_Start_Viz:Mech-Vizプロジェクトの実行をトリガーするためのコマンド。

  • 2:変数snap_jpsが表す関節角度データをMech-Vizプロジェクトに送信します。

  • init_jps:ユーザーによりカスタマイズされた関節角度。事前に設定する必要があります。この関節角度データはMech-Vizプロジェクトに送信され、次の計画の開始点として使用されます。これにより、ロボットが撮影領域の外にいるときにMech-Vizプロジェクトがトリガーされ、次の経路計画を事前に行うことができます。

上記のコードは、ロボットが MM_Start_Viz コマンドを使用してMech-Vizプロジェクトを再度トリガーします。この時点で、ロボットは今回計画された把持経路を取得し、把持点に移動しているため、配置が完了するのを待つことなく、事前にMech-Vizプロジェクトをトリガーして次の経路を計画することができます。

Mech-Vizプロジェクトが実行されると、「メッセージによって異なる分岐を実行」ステップを実行した際、MM_Set_Branch コマンドによってその分岐出口が設定されるのを待機します。また、「ビジョン処理による認識」ステップ(カメラ撮影を実行)は、「メッセージによって異なる分岐を実行」ステップのいずれかの分岐に設定されているため、この時点ではカメラは撮影を実行していません。
   ;move to departure waypoint of picking
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]

上記のコードは、ロボットが把持の離れる点(pick_point3)、中間点(drop_waypoint)、配置のアプローチ点(drop_app)の順に移動することを意味します。

;set branch exit port and trigger camera capturing when robot moves out of camera's field of view
MM_Set_Branch(1,1)

上記のコードは、ロボットが MM_Set_Branch コマンドを使用して「メッセージによって異なる分岐を実行」ステップの出口を設定することを意味します。この分岐出口では、「ビジョン処理による認識」ステップが実行され、Mech-Vizはビジョン認識の結果に基づいて次の把持経路を事前に計画します。

   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT

上記のコードは、ロボットが配置点(drop)に移動して配置を行い(例:$OUT[1]=FALSE)、その後、配置の離れる点(drop_app)、Home位置の順に移動することを意味します。

この情報は役に立ちましたか?

ご意見・ご要望がございましたら、以下よりお寄せください:

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。