サンプルプログラム18：MM_S18_Viz_GetUserData
プログラム概要
機能 |
ロボットは把持経路と共に、Mech-Visionプロジェクトから出力されたカスタムデータを取得します。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト（出力 ステップに カスタムポート に追加する必要があります）、Mech-Vizプロジェクト（ロボットハンド種類がデパレタイズ用吸盤である必要があります） |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S18_Viz_GetUserDataサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S15_Viz_GetDoListサンプルに比べて、太字部分のコードのみが追加されています。そのため、MM_S15_Viz_GetDoListサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S15_Viz_GetDoListサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Viz ;
3: !project, then get planned path ;
4: !and get custom data from ;
5: !Mech-Vision using command 210 ;
6: !Mech-Mind, 2023-12-25 ;
7: !-------------------------------- ;
8: ;
9: !set current uframe NO. to 0 ;
10: UFRAME_NUM=0 ;
11: !set current tool NO. to 1 ;
12: UTOOL_NUM=1 ;
13: !move to robot home position ;
14:J P[1] 100% FINE ;
15: !initialize communication ;
16: !parameters(initialization is ;
17: !required only once) ;
18: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
19: !move to image-capturing position ;
20:L P[2] 1000mm/sec FINE ;
21: !trigger Mech-Viz project ;
22: CALL MM_START_VIZ(2,10) ;
23: !get planned path ;
24: CALL MM_GET_PLNDT(0,3,51,52,53) ;
25: !check whether planned path has ;
26: !been got from Mech-Viz ;
27: !successfully ;
28: IF R[53]<>2100,JMP LBL[99] ;
29: !get gripper control signal list ;
30: CALL MM_GET_DL(0,0) ;
31: !save waypoints of the planned ;
32: !path to local variables one ;
33: !by one ;
34: CALL MM_GET_PLJOP(1,3,60,61,62,63,64,70) ;
35: CALL MM_GET_PLJOP(2,3,61,91,92,93,94,100) ;
36: CALL MM_GET_PLJOP(3,3,62,121,122,123,124,130) ;
37: !save received custom data of ;
38: !2nd point ;
39: R[10]=R[94] ;
40: R[11]=R[95] ;
41: R[12]=R[96] ;
42: !follow the planned path to pick ;
43: !move to approach waypoint ;
44: !of picking ;
45:J PR[60] 50% FINE ;
46: !move to picking waypoint ;
47:J PR[61] 10% FINE ;
48: !add object grasping logic here ;
49: PAUSE ;
50: !set gripper control signal ;
51: CALL MM_SET_DL(0) ;
52: !move to departure waypoint ;
53: !of picking ;
54:J PR[62] 50% FINE ;
55: !move to intermediate waypoint ;
56: !of placing ;
57:J P[3] 50% CNT100 ;
58: !move to approach waypoint ;
59: !of placing ;
60:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
61: !move to placing waypoint ;
62:L P[4] 300mm/sec FINE ;
63: !add object releasing logic here, ;
64: !such as "DO[1]=OFF" ;
65: PAUSE ;
66: !move to departure waypoint ;
67: !of placing ;
68:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
69: !move back to robot home position ;
70:J P[1] 100% FINE ;
71: END ;
72: ;
73: LBL[99:vision error] ;
74: !add error handling logic here ;
75: !according to different ;
76: !error codes ;
77: !e.g.: status=2038 means no ;
78: !point cloud in ROI ;
79: PAUSE ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は追加されたコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 | ||||
|---|---|---|---|---|---|
経路点のカスタムデータを保存 |
ロボットは MM_GET_PLNDT コマンドを使用して経路点の「ビジョン処理による移動」の計画結果とカスタムデータを取得し、その後、MM_GET_PLJOP コマンドを通じて経路点の「ビジョン処理による移動」の計画結果とカスタムデータをロボットメモリから指定されたレジスタに保存します。このサンプルでは、把持点（PR[61]）のカスタムデータがR[94]から格納されます。 上記のコードは、「ビジョン処理による移動」の経路点（把持点）の3つのカスタムデータR[94]、R[95]、R[96]をそれぞれR[10]、R[11]、R[12]に代入することを意味します。
|