サンプルプログラム9：MM_S9_Viz_RunInAdvance
プログラム概要
機能 |
ロボットは把持時にMech-Vizプロジェクトをトリガーし、その後、分岐設定により配置時にカメラ撮影をトリガーします。これにより、次の経路を事前に計画し、サイクルタイムを短縮します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-VisionとMech-Vizプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S9_Viz_RunInAdvanceサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S5_Viz_SetBranchサンプルに比べて、次の経路を事前に計画する機能（太字部分のコード）のみが追加されています。そのため、MM_S5_Viz_SetBranchサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S5_Viz_SetBranchサンプルの説明 をご参照ください）。 |
NOP
'--------------------------------
'FUNCTION: trigger Mech-Viz
'project then set branch and get
'planned path, trigger Mech-Viz
'project and set branch in
'advance during pick&place
'process
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger Mech-Viz project
CALL JOB:MM_START_VIZ ARGF"2;30"
'set branch exit port
CALL JOB:MM_SET_BRANCH ARGF"1;1"
*LOOP
'get planned path, 1st argument
'(1) means getting pose in JPs
CALL JOB:MM_GET_VIZDATA ARGF"1;51;52;53"
'check whether planned path has
'been got from Mech-Viz
'successfully
IFTHENEXP I053<>2100
'add error handling logic here
'according to different error
'codes
'e.g.: I053=2038 means no
'point cloud in ROI
PAUSE
ENDIF
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'trigger Mech-Viz project but not
'to trigger camera capturing
CALL JOB:MM_START_VIZ ARGF"2;30"
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'set branch exit port and trigger
'camera capturing when robot
'moves out of camera’s field
'of view
CALL JOB:MM_SET_BRANCH ARGF"1;1"
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
JUMP *LOOP
*ENDLOOP
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
END上記のサンプルプログラムの処理流れは、下図の通りです。
以下は、次の経路を事前に計画するコードとその説明です。
| 処理流れ | コートと説明 | ||||||
|---|---|---|---|---|---|---|---|
ループで次の経路を事前に計画（把持→次の把持経路を計画→配置） |
上記のコードは、プログラムが「*LOOP」と「JUMP *LOOP」の間のコードを繰り返し実行することを意味します。 上記のコードは、ロボットが MM_GET_VIZDATA コマンドを使用してMech-Vizが計画された経路を取得することを意味します。 上記のコードは、ロボットが MM_GET_JPS コマンドを使用して計画された経路を指定された変数に保存することを意味します。このサンプルでは、P071、P072、P073がそれぞれ把持のアプローチ点、把持点、把持の離れる点であると仮定しています。 上記のコードは、ロボットが把持のアプローチ点、把持点、把持の離れる点の順に移動し、DOコマンド（例えばDOUT OT#(1) ON）を設定することでロボットハンドを制御し、把持を実行することを意味します。 上記のコードは、ロボットが MM_START_VIZ コマンドを使用してMech-Vizプロジェクトを再度トリガーします。この時点で、ロボットは計画された把持経路を取得し、把持点に移動しているため、配置が完了するのを待つことなく、事前にMech-Vizプロジェクトをトリガーして次の経路を計画することができます。
上記のコードは、ロボットが把持の離れる点（P073）、中間点（C00002）、配置のアプローチ点（C00003）の順に移動することを意味します。
上記のコードは、ロボットが MM_SET_BRANCH コマンドを使用して「メッセージによって異なる分岐を実行」ステップの出口を設定することを意味します。この分岐出口では、「ビジョン処理による認識」ステップが実行され、Mech-Vizはビジョン認識の結果に基づいて次の把持経路を事前に計画します。 上記のコードは、ロボットが配置点（C00004）に移動して配置を行い（例えばDOUT OT#(1) OFF）、その後、配置の離れる点（C00005）、Home位置（C00006）の順に移動することを意味します。
ループコード内でプログラムのエラーロジックを記述する場合、「JUMP *ENDLOOP」コマンドを使用して、通信を終了するコード部分にジャンプできます。 |