サンプルプログラム4：MM_S4_Vis_ChangeModel
プログラム概要
機能 |
ロボットはMech-Visionのパラメータレシピを切り替え、その後Mech-Visionプロジェクトをトリガーして実行します。ビジョン結果を取得し、その結果に基づいて把持および配置を実行します。 |
||
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
||
必要なプロジェクト |
Mech-Visionプロジェクト
|
||
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S4_Vis_ChangeModelサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S1_Vis_Basicサンプルに比べて、Mech-Visionのパラメータレシピを切り替える機能（太字部分のコード）のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project after switching recipe ;
4: !and get vision result ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: UFRAME_NUM=0 ;
10: !set current tool NO. to 1 ;
11: UTOOL_NUM=1 ;
12: !move to robot home position ;
13:J P[1] 100% FINE ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
18: !move to image-capturing position ;
19:L P[2] 1000mm/sec FINE ;
20: !switch recipe of NO.1 ;
21: !Mech-Vision project, ;
22: !"MM_SET_MOD(Proj_num,Model_num)" ;
23: CALL MM_SET_MOD(1,1) ;
24: !trigger NO.1 Mech-Vision project ;
25: CALL MM_START_VIS(1,0,2,10) ;
26: !get vision result from NO.1 ;
27: !Mech-Vision project ;
28: CALL MM_GET_VIS(1,51,53) ;
29: !check whether vision result has ;
30: !been got from Mech-Vision ;
31: !successfully ;
32: IF R[53]<>1100,JMP LBL[99] ;
33: !save first vision point data to ;
34: !local variables ;
35: CALL MM_GET_POS(1,60,70,80) ;
36: !move to intermediate waypoint ;
37: !of picking ;
38:J P[3] 50% CNT100 ;
39: !move to approach waypoint ;
40: !of picking ;
41:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
42: !move to picking waypoint ;
43:L PR[60] 300mm/sec FINE ;
44: !add object grasping logic here, ;
45: !such as "DO[1]=ON" ;
46: PAUSE ;
47: !move to departure waypoint ;
48: !of picking ;
49:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
50: !move to intermediate waypoint ;
51: !of placing ;
52:J P[4] 50% CNT100 ;
53: !move to approach waypoint ;
54: !of placing ;
55:L P[5] 1000mm/sec FINE Tool_Offset,PR[2] ;
56: !move to placing waypoint ;
57:L P[5] 300mm/sec FINE ;
58: !add object releasing logic here, ;
59: !such as "DO[1]=OFF" ;
60: PAUSE ;
61: !move to departure waypoint ;
62: !of placing ;
63:L P[5] 1000mm/sec FINE Tool_Offset,PR[2] ;
64: !move back to robot home position ;
65:J P[1] 100% FINE ;
66: END ;
67: ;
68: LBL[99:vision error] ;
69: !add error handling logic here ;
70: !according to different ;
71: !error codes ;
72: !e.g.: status=1003 means no ;
73: !point cloud in ROI ;
74: !e.g.: status=1002 means no ;
75: !vision results ;
76: PAUSE ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表はMech-Visionのパラメータレシピを切り替えるコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 |
|---|---|
Mech-Visionのパラメータレシピを切り替る |
このコマンドは、Mech-Visionプロジェクト1のパラメータレシピを番号1のレシピに切り替えることを意味します。 |