サンプルプログラム14：MM_S14_Vis_GetUserData

現在ご覧いただいているのは未リリースのバージョンです（V2.1.0）。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ ご利用中のバージョンが分からない場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットはビジョン結果と共に、Mech-Visionプロジェクトから出力されたカスタムデータを取得します。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/FANUC/sample/MM_S14_Vis_GetUserData。

必要なプロジェクト

Mech-Visionプロジェクト（出力ステップに カスタムポート を追加する必要があります）

使用前提

標準インターフェース通信設定が完了しました。
自動キャリブレーションが完了しました。

このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S14_Vis_GetUserDataサンプルプログラムのコードと関連する説明です。

このサンプルは、MM_S1_Vis_Basicサンプルに比べて、太字部分のコードのみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明をご参照ください）。

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project and get vision result ;
   4:  !and custom data using ;
   5:  !command 110 ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  UFRAME_NUM=0 ;
  11:  !set current tool NO. to 1 ;
  12:  UTOOL_NUM=1 ;
  13:  !move to robot home position ;
  14:J P[1] 100% FINE    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  19:  !move to image-capturing position ;
  20:L P[2] 1000mm/sec FINE    ;
  21:  !trigger NO.1 Mech-Vision project ;
  22:  CALL MM_START_VIS(1,0,2,10) ;
  23:  !get vision result from NO.1 ;
  24:  !Mech-Vision project ;
  25:  CALL MM_GET_DY_DT(1,51,53) ;
  26:  !check whether vision result has ;
  27:  !been got from Mech-Vision ;
  28:  !successfully ;
  29:  IF R[53]<>1100,JMP LBL[99] ;
  30:  !save first vision point data to ;
  31:  !local variables ;
  32:  CALL MM_GET_DYPOS(1,60,70,90) ;
  33:  !save received custom data ;
  34:  R[10]=R[90]    ;
  35:  R[11]=R[91]    ;
  36:  R[12]=R[92]    ;
  37:  !move to intermediate waypoint ;
  38:  !of picking ;
  39:J P[3] 50% CNT100    ;
  40:  !move to approach waypoint ;
  41:  !of picking ;
  42:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1]    ;
  43:  !move to picking waypoint ;
  44:L PR[60] 300mm/sec FINE    ;
  45:  !add object grasping logic here, ;
  46:  !such as "DO[1]=ON" ;
  47:  PAUSE ;
  48:  !move to departure waypoint ;
  49:  !of picking ;
  50:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1]    ;
  51:  !move to intermediate waypoint ;
  52:  !of placing ;
  53:J P[4] 50% CNT100    ;
  54:  !move to approach waypoint ;
  55:  !of placing ;
  56:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  57:  !move to placing waypoint ;
  58:L P[5] 300mm/sec FINE    ;
  59:  !add object releasing logic here, ;
  60:  !such as "DO[1]=OFF" ;
  61:  PAUSE ;
  62:  !move to departure waypoint ;
  63:  !of placing ;
  64:L P[5] 1000mm/sec FINE Tool_Offset,PR[2]    ;
  65:  !move back to robot home position ;
  66:J P[1] 100% FINE    ;
  67:  END ;
  68:   ;
  69:  LBL[99:vision error] ;
  70:  !add error handling logic here ;
  71:  !according to different ;
  72:  !error codes ;
  73:  !e.g.: status=1003 means no ;
  74:  !point cloud in ROI ;
  75:  !e.g.: status=1002 means no ;
  76:  !vision results ;
  77:  PAUSE ;

上記のサンプルプログラムの処理流れは、下図の通りです。

下表は太字部分のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。

処理流れコートと説明

ビジョン結果（カスタムデータを含む）を取得

  23:  !get vision result from NO.1 ;
  24:  !Mech-Vision project ;
  25:  CALL MM_GET_DY_DT(1,51,53) ;

Mech-Visionプロジェクトにおいて、カスタムデータとは、Mech-Visionの「出力」ステップのカスタムポートから出力されるデータを指します。

MM_GET_DY_DT：ビジョン結果を取得するためのコマンド。このコマンドを使用して取得されたビジョンポイントは、位置姿勢とラベルに加えて、カスタムデータも含まれます。一方、MM_GET_VIS コマンドを使用して取得されたビジョンポイントには、カスタムデータは含まれません。
1：Mech-Visionプロジェクト番号。
51：数値レジスタR[51]の番号。このレジスタはビジョンシステムから返されたビジョンポイントの数を保存します。
53：数値レジスタR[53]の番号。このレジスタはコマンド実行のステータスコードを保存します。

このコマンドは、ロボットがMech-Visionプロジェクト1から返されたビジョン結果（カスタムデータを含む）を取得することを意味します。

返されたビジョン結果はロボットのメモリに保存されるため、この時点ではユーザーがビジョン結果に含まれるカスタムデータを直接取得することはできません。その後の「ビジョン結果を保存」コマンドを実行することで、カスタムデータを取得することができます。

ビジョン結果（カスタムデータを含む）を保存

  30:  !save first vision point data to ;
  31:  !local variables ;
  32:  CALL MM_GET_DYPOS(1,60,70,90) ;

MM_GET_DYPOS：ビジョン結果を保存するためのコマンド。このコマンドは、位置姿勢とラベルに加えて、カスタムデータも保存します。一方、MM_GET_POS コマンドは位置姿勢、ラベル、ロボットハンド番号のみを保存し、カスタムデータは保存できません。さらに、MM_GET_DYPOSコマンドは、ビジョンポイントのカスタムデータをロボットのメモリから指定されたレジスタに保存できます。
1：最初のビジョンポイントを保存します。
60：位置レジスタPR[60]の番号。このレジスタは最初のビジョンポイント（把持点）のツール位置姿勢を保存します。
70：数値レジスタR[70]の番号。このレジスタは最初のビジョンポイントに対応するラベルを保存します。
90：番号が90から始まる数値レジスタ。このレジスタは、最初のビジョンポイントに対応するカスタムデータを数値レジスタR[90]から順番に保存します。

このコマンドは、最初のビジョンポイントのツール位置姿勢、ラベル、およびカスタムデータをそれぞれ指定されたレジスタに保存することを意味します。

  33:  !save received custom data ;
  34:  R[10]=R[90]    ;
  35:  R[11]=R[91]    ;
  36:  R[12]=R[92]    ;

上記のコードは、ビジョンポイント（把持点）の3つのカスタムデータR[90]、R[91]、R[92]をそれぞれR[10]、R[11]、R[12]に代入することを意味します。

R[10]、R[11]、R[12]の意味はユーザーが設定できます。例えば、これらの3つの値は、ロボットが把持点に移動する際のXYZ各軸におけるオフセットを表すことができます。

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

同意する

拒否する