サンプルプログラム13：MM_S13_Vis_MoveInAdvance
プログラム概要
機能 |
Mech-Visionプロジェクトをトリガーした後、ロボットがカメラ撮影が完了した時点で移動でき、Mech-Visionプロジェクトの実行が終了するのを待機する必要はありません。このサンプルは、カメラがEIH方式で取り付けられている場合に適しています。 |
ファイル場所 |
Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある |
必要なプロジェクト |
Mech-Visionプロジェクト（EIHカメラ取り付け方式） |
使用前提 |
|
| このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。 |
プログラム説明
以下はMM_S13_Vis_MoveInAdvanceサンプルプログラムのコードと関連する説明です。
| このサンプルは、MM_S1_Vis_Basicサンプルに比べて、「撮影完了後に移動できる」機能（太字部分のコード）のみが追加されています。そのため、MM_S1_Vis_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S1_Vis_Basicサンプルの説明 をご参照ください）。 |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !then move to wait position and ;
4: !get vision pose in EIH setup ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: UFRAME_NUM=0 ;
10: !set current tool NO. to 1 ;
11: UTOOL_NUM=1 ;
12: !move to robot home position ;
13:J P[1] 100% FINE ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
18: !move to image-capturing position ;
19:L P[2] 1000mm/sec FINE ;
20: !trigger NO.1 Mech-Vision project ;
21: CALL MM_START_VIS(1,0,1,10) ;
22: !move to wait position for ;
23: !picking ;
24:J P[3] 50% CNT100 ;
25: !get vision result from NO.1 ;
26: !Mech-Vision project ;
27: CALL MM_GET_VIS(1,51,53) ;
28: !check whether vision result has ;
29: !been got from Mech-Vision ;
30: !successfully ;
31: IF R[53]<>1100,JMP LBL[99] ;
32: !save first vision point data to ;
33: !local variables ;
34: CALL MM_GET_POS(1,60,70,80) ;
35: !move to intermediate waypoint ;
36: !of picking ;
37:J P[4] 50% CNT100 ;
38: !move to approach waypoint ;
39: !of picking ;
40:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
41: !move to picking waypoint ;
42:L PR[60] 300mm/sec FINE ;
43: !add object grasping logic here, ;
44: !such as "DO[1]=ON" ;
45: PAUSE ;
46: !move to departure waypoint ;
47: !of picking ;
48:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
49: !move to intermediate waypoint ;
50: !of placing ;
51:J P[5] 50% CNT100 ;
52: !move to approach waypoint ;
53: !of placing ;
54:L P[6] 1000mm/sec FINE Tool_Offset,PR[2] ;
55: !move to placing waypoint ;
56:L P[6] 300mm/sec FINE ;
57: !add object releasing logic here, ;
58: !such as "DO[1]=OFF" ;
59: PAUSE ;
60: !move to departure waypoint ;
61: !of placing ;
62:L P[6] 1000mm/sec FINE Tool_Offset,PR[2] ;
63: !move back to robot home position ;
64:J P[1] 100% FINE ;
65: END ;
66: ;
67: LBL[99:vision error] ;
68: !add error handling logic here ;
69: !according to different ;
70: !error codes ;
71: !e.g.: status=1003 means no ;
72: !point cloud in ROI ;
73: !e.g.: status=1002 means no ;
74: !vision results ;
75: PAUSE ;上記のサンプルプログラムの処理流れは、下図の通りです。
下表は、「撮影完了後に移動できる」機能のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。
| 処理流れ | コートと説明 | ||||
|---|---|---|---|---|---|
ロボットが撮影完了後に移動できる |
EIHシーンでは、Mech-Visionプロジェクトの実行が終了するのを待たずに、カメラの撮影完了後にロボットが移動できるようにするために、Mech-Visionソフトウェア内で を選択し、撮影完了後、「1102：トリガー成功」を返す にチェックを入れます。これにより、ロボットはMech-Visionプロジェクトをトリガーし、「1102：トリガー成功」を受信した後、移動を開始できるようになり、サイクルタイムを短縮できます。 下図ような設定を行わない場合、Mech-Visionプロジェクトが正常に実行されると、ビジョンシステムは直ちに「1102」ステータスコードをロボットに返します。このとき、ロボットは撮影が完了したかどうか判断できないため、移動することはできません。したがって、ロボットはMech-Visionプロジェクトが終了するのを待つ必要があります。
上記のコードは、撮影後にロボットが把持の待機点（P[3]、ティーチング法でこの点を事前に設定する必要があります）に移動できることを意味します。これにより、Mech-Visionプロジェクトの実行とロボットの移動を並行して行うことができ、サイクルタイムを短縮することができます。
|