サンプルプログラム2：MM_S2_Viz_Basic

現在ご覧いただいているのは最新版の内容です（V2.2.0）。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ ご利用中のバージョンが分からない場合や、サポートが必要な場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットがMech-Vizプロジェクトをトリガーして実行し、その後計画された経路を取得して、把持および配置を実行します。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/FANUC/sample/MM_S2_Viz_Basic。

必要なプロジェクト

Mech-VisionとMech-Vizプロジェクト

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。
このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S2_Viz_Basicサンプルプログラムのコードと関連する説明です。

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Viz ;
   3:  !project and get planned path ;
   4:  !Mech-Mind, 2023-12-25 ;
   5:  !-------------------------------- ;
   6:   ;
   7:  !set current uframe NO. to 0 ;
   8:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
   9:  !set current tool NO. to 1 ;
  10:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  11:  !move to robot home position ;
  12:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  13:  !initialize communication ;
  14:  !parameters(initialization is ;
  15:  !required only once) ;
  16:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;
  17:  !move to image-capturing position ;
  18:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  19:  !trigger Mech-Viz project ;
  20:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;
  21:  !check whether viz project has ;
  22:  !been triggered successfully ;
  23:  ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  24:  !get planned path, 1st argument ;
  25:  !(1) means getting pose in JPs ;
  26:  ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;
  27:  !check whether planned path has ;
  28:  !been got from Mech-Viz ;
  29:  !successfully ;
  30:  ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  31:  !save waypoints of the planned ;
  32:  !path to local variables one ;
  33:  !by one ;
  34:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
  35:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
  36:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;
  37:  !follow the planned path to pick ;
  38:  !move to approach waypoint ;
  39:  !of picking ;
  40:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ    ;
  41:  !move to picking waypoint ;
  42:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ    ;
  43:  !add object grasping logic here, ;
  44:  !such as "DO[1]=ON" ;
  45:  ｲﾁｼﾞﾃｲｼ ;
  46:  !move to departure waypoint ;
  47:  !of picking ;
  48:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ    ;
  49:  !move to intermediate waypoint ;
  50:  !of placing ;
  51:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  52:  !move to approach waypoint ;
  53:  !of placing ;
  54:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  55:  !move to placing waypoint ;
  56:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ    ;
  57:  !add object releasing logic here, ;
  58:  !such as "DO[1]=OFF" ;
  59:  ｲﾁｼﾞﾃｲｼ ;
  60:  !move to departure waypoint ;
  61:  !of placing ;
  62:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  63:  !move back to robot home position ;
  64:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  65:  ｼｭｳﾘｮｳ ;
  66:   ;
  67:  ﾗﾍﾞﾙ[99:handling error] ;
  68:  !add error handling logic here ;
  69:  !according to different ;
  70:  !error codes ;
  71:  !e.g.: mm_status=2038 means no ;
  72:  !point cloud in ROI ;
  73:  !e.g.: mm_status=3099 means ;
  74:  !failed to open socket ;
  75:  ｲﾁｼﾞﾃｲｼ ;

上記のサンプルプログラムの処理流れは、下図の通りです。

sample2

下表は上記のプログラムのコードとその説明です。コマンド名のリンクをクリックすることで、その詳細な説明を確認できます。

処理流れ コートと説明

座標系設定

 
   7:  !set current uframe NO. to 0 ;
   8:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
   9:  !set current tool NO. to 1 ;
  10:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;

  • ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0：現在選択されているユーザー座標系番号を0（ワールド座標系）に設定します。

  • ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1：現在選択されているツール座標系番号を1に設定します（ユーザーは事前に1番ツール座標系を設定する必要があります）。

上記の2つのコマンドは、現在選択されているユーザー座標系とツール座標系を設定することを意味します。

Home位置に移動

 
  11:  !move to robot home position ;
  12:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;

  • ｶｸｼﾞｸ：ロボットの関節移動コマンドで、ロボットが円弧型の経路に沿って指定された位置に移動することを意味します。

  • ｲﾁ[1]：ロボットが移動する目標位置を指定します。この場合、ティーチング法で設定されたHome位置を指します。通常、この位置はロボットがワークや周辺機器から安全な位置に離れている場所です。

  • 100%：最大移動速度に対する相対的な移動速度の割合を示します。

  • ｲﾁｷﾞﾒ：ロボットが目標位置に到達した際に、少し停止してから次の目標位置に移動することを意味します。

このコマンドは、ロボットが関節移動の方式で設定されたHome位置に移動することを意味します。

初期位置（ｲﾁ[1]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

通信初期化

 
  13:  !initialize communication ;
  14:  !parameters(initialization is ;
  15:  !required only once) ;
  16:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','192.168.1.20',30000,5) ;

  • MM_INIT_SKT：通信を初期化するためのコマンド。

  • '8'：ロボットのポート番号。

  • '192.168.1.20'：IPCのIPアドレス。

  • 30000：IPCのポート番号。

  • 5：通信のタイムアウト待機時間（5分間）。

このコマンドは、ロボットが MM_INIT_SKT コマンドを使用して、通信対象（IPC）のIPアドレス、ポート番号、およびタイムアウト待機時間を指定し、ビジョンシステムとの接続を確立することを意味します。

実際の状況に基づいてIPCのIPアドレスやポート番号を変更し、ビジョンシステムで設定されたパラメータと一致するようにする必要があります。

撮影位置に移動

 
  17:  !move to image-capturing position ;
  18:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;

  • ﾁｮｸｾﾝ：ロボットの直線移動コマンドで、ロボットが指定された位置まで直線的に移動することを意味します。

  • ｲﾁ[2]：ロボットが移動する目標位置を指定します。この場合、ティーチング法で設定された画像撮影位置を指します。撮影位置とは、カメラが画像を撮影したときにロボットがいる位置を指します。この位置では、ロボットアームがカメラ視野を遮らないようにする必要があります。

このコマンドは、ロボットが直線移動の方式で設定された撮影位置に移動することを意味し、移動速度は1000mm/秒です。

撮影位置（ｲﾁ[2]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

Mech-Vizプロジェクトをトリガー

 
  19:  !trigger Mech-Viz project ;
  20:  ﾖﾋﾞﾀﾞｼ MM_START_VIZ(2,10,53) ;

  • MM_START_VIZ：Mech-Vizプロジェクトの実行をトリガーするためのコマンド。

  • 2：ｲﾁﾚｼﾞ[10]で示される関節角度データをMech-Vizプロジェクトに送信します。

  • 10：ｲﾁﾚｼﾞ[10]の番号。このレジスタはカスタマイズされた関節角度データを保存します。関節角度は、事前にティーチング法で設定する必要があります。把持経路を計画する際に、Mech-Vizプロジェクトの仮想ロボットはこの関節角度から最初の経路点に移動します。

このコマンドは、ロボットがビジョンシステムをトリガーしてMech-Vizプロジェクトを実行し、Mech-VizがMech-Visionから出力されたビジョン結果に基づいて把持経路を計画することを意味します。

  21:  !check whether viz project has ;
  22:  !been triggered successfully ;
  23:  ﾓｼ (ﾚｼﾞ[53]<>2103),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;

  • 「ﾓｼ A,ｼﾞｬﾝﾌﾟ B」：条件Aが成立した場合、プログラムはBにジャンプして実行を続けます。

  • <>：等しくないことを意味します。

上記のコードは、ステータスコードﾚｼﾞ[53]が2103の場合、ロボットがすべてのビジョン結果を正常に取得することを意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはﾗﾍﾞﾙ[99]にジャンプして実行を続けることを意味します。

計画された経路を取得

 
  24:  !get planned path, 1st argument ;
  25:  !(1) means getting pose in JPs ;
  26:  ﾖﾋﾞﾀﾞｼ MM_GET_VIZ(1,51,52,53) ;

  • MM_GET_VIZ：Mech-Vizが計画された経路を取得するためのコマンド。

  • 1：取得した経路点の位置姿勢を関節角度の形式として指定します。

  • 51：ﾚｼﾞ[51]の番号。このレジスタはビジョンシステムから返された経路点の数を保存します。

  • 52：ﾚｼﾞ[52]の番号。このレジスタは、「ビジョン処理による移動」の経路点（把持点）が経路全体における位置番号を保存します。

  • 53：ﾚｼﾞ[53]の番号。このレジスタはコマンド実行のステータスコードを保存します。

このコマンドは、ロボットがMech-Vizプロジェクトから返された計画経路を取得することを意味します。

返された計画経路はロボットのメモリに保存されるため、この時点ではユーザーが計画経路を直接取得することはできません。その後の「計画された経路を保存」コマンドを実行することで、経路を取得することができます。 
  27:  !check whether planned path has ;
  28:  !been got from Mech-Viz ;
  29:  !successfully ;
  30:  ﾓｼ (ﾚｼﾞ[53]<>2100),ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;

  • 「ﾓｼ A,ｼﾞｬﾝﾌﾟ B」：条件Aが成立した場合、プログラムはBにジャンプして実行を続けます。

  • <>：等しくないことを意味します。

上記のコードは、ステータスコードﾚｼﾞ[53]が2100の場合、ロボットがすべての計画された経路を正常に取得することを意味し、それ以外の場合はビジョンシステムに異常が発生し、プログラムはﾗﾍﾞﾙ[99]にジャンプして実行を続けることを意味します。以下にﾗﾍﾞﾙ[99]のコードを示します。

  67:  ﾗﾍﾞﾙ[99:handling error] ;
  68:  !add error handling logic here ;
  69:  !according to different ;
  70:  !error codes ;
  71:  !e.g.: mm_status=2038 means no ;
  72:  !point cloud in ROI ;
  73:  !e.g.: mm_status=3099 means ;
  74:  !failed to open socket ;
  75:  ｲﾁｼﾞﾃｲｼ ;

ユーザーは、特定のエラーコードに応じて適切な処理を行うことが可能です。本サンプルでは、すべてのエラーコードに対して同一の処理を行い、PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドを使用してプログラムの実行を停止しています。

計画された経路を保存

 
  31:  !save waypoints of the planned ;
  32:  !path to local variables one ;
  33:  !by one ;
  34:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80) ;
  35:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(2,61,71,81) ;
  36:  ﾖﾋﾞﾀﾞｼ MM_GET_JPS(3,62,72,82) ;

  • MM_GET_JPS：計画された経路を保存するためのコマンド。

  • 1：最初の経路点を保存します。

  • 60：ｲﾁﾚｼﾞ[60]の番号。このレジスタは最初の経路点の関節角度を保存します。

  • 70：ﾚｼﾞ[70]の番号。このレジスタは最初の経路点に対応するラベルを保存します。

  • 80：ﾚｼﾞ[80]の番号。このレジスタは最初の経路点に対応するロボットハンド番号を保存します。

「ﾖﾋﾞﾀﾞｼ MM_GET_JPS(1,60,70,80)」コマンドは、最初の経路点の関節角度、ラベル、およびロボットハンド番号をそれぞれ指定されたレジスタに保存することを意味します。

このサンプルでは、Mech-Vizで計画された経路に3つの経路点が含まれていると仮定しています。最初の経路点は「把持のアプローチ点（ｲﾁﾚｼﾞ[60]）」、2番目の経路点は「把持点（ｲﾁﾚｼﾞ[61]）」、3番目の経路点は「把持の離れる点（ｲﾁﾚｼﾞ[62]）」です。Mech-Vizプロジェクトで作成されたワークフローに応じて、プログラムを適切に変更し、経路を保存する必要があります。

把持のアプローチ点に移動

 
  37:  !follow the planned path to pick ;
  38:  !move to approach waypoint ;
  39:  !of picking ;
  40:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[60] 50% ｲﾁｷﾞﾒ    ;

ロボットが把持のアプローチ点（ｲﾁﾚｼﾞ[60]が表す位置）に移動します。

把持点に移動

 
  41:  !move to picking waypoint ;
  42:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[61] 10% ｲﾁｷﾞﾒ    ;

ロボットが把持点（ｲﾁﾚｼﾞ[61]が表す位置）に移動します。

DO設定による把持

 
  43:  !add object grasping logic here, ;
  44:  !such as "DO[1]=ON" ;
  45:  ｲﾁｼﾞﾃｲｼ ;

ロボットが把持点に到達した後、DOコマンド（例えば「DO[1]=ON」）を設定して、ロボットハンドを制御し、ワークを把持します。実際の状況に応じてDO設定を調整する必要があります。

PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドはプログラムの実行を停止します。DO設定コマンドが設定されている場合、このPAUSEコマンドは削除できます。

把持の離れる点に移動

 
  46:  !move to departure waypoint ;
  47:  !of picking ;
  48:ｶｸｼﾞｸ ｲﾁﾚｼﾞ[62] 50% ｲﾁｷﾞﾒ    ;

ロボットが把持の離れる点（ｲﾁﾚｼﾞ[62]が表す位置）に移動します。

中間点に移動

 
  49:  !move to intermediate waypoint ;
  50:  !of placing ;
  51:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;

  • ｲﾁ[3]：ロボットが移動する目標位置を指定します。この場合、中間点を指します。

  • ﾅﾒﾗｶ：ロボットは目標位置に近づきますが、その位置で停止するのではなく、次の位置に向かって移動を続けます。その後の数字は、ロボットが目標位置にどれだけ近づくかを示し、数値が大きいほど目標位置から遠くなります。

このコマンドは、ロボットが関節移動の方式で、把持の離れる点と配置のアプローチ点の間の中間点に移動することを意味します。

  • 中間点を追加することで、ロボットの移動がスムーズになり、不要な衝突を避けることができます。実際の状況に応じて複数の中間点を追加することが可能です。

  • 中間点（ｲﾁ[3]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

配置のアプローチ点に移動

 
  52:  !move to approach waypoint ;
  53:  !of placing ;
  54:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;

  • ｲﾁ[4]：ロボットが移動する目標位置を指定します。この場合、配置点を指します。配置点（ｲﾁ[4]）を事前にティーチングする必要があります。ティーチング方法については、FANUCの公式マニュアルをご参照ください。

  • ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]：ロボットは配置点（ｲﾁ[4]）を基準に、指定されたｲﾁﾚｼﾞ[2]に従ってオフセットを適用します。ここでは、ｲﾁﾚｼﾞ[2]のZ軸の値のみを設定する必要があります。例えば、Z軸の値を-100、他の値を0に設定することで、配置点のZ軸の負方向に100mmの位置に移動します。つまり、ロボットは配置点の上方100mmの位置に移動し、配置のアプローチ点に到達します。

アプローチ点を追加することで、ロボットが移動する際にシーンの物体（コンテナなど）と衝突するのを防ぐことができます。実際の状況に応じてｲﾁﾚｼﾞ[2]の設定を変更し、ロボットが移動する際に衝突がないことを確認してください。

配置点に移動

 
  55:  !move to placing waypoint ;
  56:ﾁｮｸｾﾝ ｲﾁ[4] 300mm/sec ｲﾁｷﾞﾒ    ;

ロボットが配置のアプローチ点から配置点に移動します。

DO設定による配置

 
  57:  !add object releasing logic here, ;
  58:  !such as "DO[1]=OFF" ;
  59:  ｲﾁｼﾞﾃｲｼ ;

ロボットが配置点に到達した後、DOコマンド（例えば「DO[1]=OFF」）を設定して、ロボットハンドを制御し、ワークを配置します。実際の状況に応じてDO設定を調整する必要があります。

PAUSE（ｲﾁｼﾞﾃｲｼ）コマンドはプログラムの実行を停止します。DO設定コマンドが設定されている場合、このPAUSEコマンドは削除できます。

配置の離れる点に移動

 
  60:  !move to departure waypoint ;
  61:  !of placing ;
  62:ﾁｮｸｾﾝ ｲﾁ[4] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;

ロボットは配置点の上方の所定位置に移動し、これを配置の離れる点と呼びます。

離れる点を追加することで、ロボットが移動する際にシーン内の物体（コンテナなど）との衝突を防ぐことができます。実際の状況に応じてｲﾁﾚｼﾞ[2]の設定を変更し、ロボットが離れる際に衝突がないことを確認してください。

Home位置に移動

 
  63:  !move back to robot home position ;
  64:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;

ロボットが配置の離れる点からHome位置に戻ります。

この情報は役に立ちましたか？

ご意見・ご要望がございましたら、以下よりお寄せください：

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

  • Preference
  • 同意する
  • 拒否する