Example Program 14: MM_S14_Vis_GetUserData

Program Introduction

Description

When the robot obtains the vision result, the robot also obtains the custom data from the Mech-Vision project.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/ABB/sample/MM_S14_Vis_GetUserData path.

For RobotWare6, the file extension is .mod. For RobotWare7, please modify the file extension from .mod to .modx.

Project

Mech-Vision project (one or more custom ports needed to be added to the Output Step)

Prerequisites

  1. You have set up the standard interface communication.

  2. Automatic calibration is completed.
This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario.

Program Description

This part describes the MM_S14_Vis_GetUserData example program.

Compared with the MM_S1_Vis_Basic example program, this example program contains only the following modification (the code of this modification is bolded). As such, only the modification is described in the following section. For information about the parts of MM_S14_Vis_GetUserData that are consistent with those of MM_S1_Vis_Basic, see Example Program 1: MM_S1_Vis_Basic. 
MODULE MM_S14_Vis_GetUserData
!----------------------------------------------------------
! FUNCTION: trigger Mech-Vision project and get vision result
! and custom data using command 110
! Mech-Mind, 2023-12-25
!----------------------------------------------------------
!define local num variables
LOCAL VAR num pose_num:=0;
LOCAL VAR num status:=0;
LOCAL VAR num label:=0;
LOCAL VAR num offset_x:=0;
LOCAL VAR num offset_y:=0;
LOCAL VAR num offset_z:=0;
!define local joint&pose variables
LOCAL CONST jointtarget home:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL CONST jointtarget snap_jps:=[[0,0,0,0,90,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget camera_capture:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pick_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget pickpoint:=[[500,100,300],[0.00226227,-0.99991,-0.00439596,0.0124994],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop_waypoint:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
LOCAL PERS robtarget drop:=[[302.00,0.00,558.00],[0,0,-1,0],[0,0,0,0],[9E+9,9E+9,9E+9,9E+9,9E+9,9E+9]];
!define local tooldata variables
LOCAL PERS tooldata gripper1:=[TRUE,[[0,0,0],[1,0,0,0]],[0.001,[0,0,0.001],[1,0,0,0],0,0,0]];

PROC Sample_14()
    !set the acceleration parameters
    AccSet 50, 50;
    !set the velocity parameters
    VelSet 50, 1000;
    !move to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
    !initialize communication parameters (initialization is required only once)
    MM_Init_Socket "127.0.0.1",50000,300;
    !move to image-capturing position
    MoveL camera_capture,v1000,fine,gripper1;
    !open socket connection
    MM_Open_Socket;
    !trigger NO.1 Mech-Vision project
    MM_Start_Vis 1,0,2,snap_jps;
    !get vision result from NO.1 Mech-Vision project
    MM_Get_DyData 1,pose_num,status;
    !check whether vision result has been got from Mech-Vision successfully
    IF status<>1100 THEN
        !add error handling logic here according to different error codes
        !e.g.: status=1003 means no point cloud in ROI
        !e.g.: status=1002 means no vision result
        Stop;
    ENDIF
    !close socket connection
    MM_Close_Socket;
    !save first vision point data to local variables
    MM_Get_DyPose 1,pickpoint,label;
    !save received custom data
    offset_x:=MM_UserData{1};
    offset_y:=MM_UserData{2};
    offset_z:=MM_UserData{3};
    !move to intermediate waypoint of picking
    MoveJ pick_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to picking waypoint
    MoveL pickpoint,v300,fine,gripper1;
    !add object grasping logic here, such as "setdo DO_1, 1;"
    Stop;
    !move to departure waypoint of picking
    MoveL RelTool(pickpoint,0,0,-100),v1000,fine,gripper1;
    !move to intermediate waypoint of placing
    MoveJ drop_waypoint,v1000,z50,gripper1;
    !move to approach waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move to placing waypoint
    MoveL drop,v300,fine,gripper1;
    !add object releasing logic here, such as "setdo DO_1, 0;"
    Stop;
    !move to departure waypoint of placing
    MoveL RelTool(drop,0,0,-100),v1000,fine,gripper1;
    !move back to robot home position
    MoveAbsJ home\NoEOffs,v3000,fine,gripper1;
ENDPROC
ENDMODULE

The workflow corresponding to the above example program code is shown in the figure below.

sample14

The table below describes the bolded code. You can click the hyperlink to the command name to view its detailed description.

Feature Code and description

Obtain the vision result (including the custom data)

 
!get vision result from NO.1 Mech-Vision project
MM_Get_DyData 1,pose_num,status;
For a Mech-Vision project, custom data refers to the data output by the custom ports of the Mech-Vision project.

  • MM_Get_DyData: The command to obtain the vision result. The vision points obtained by this command contain custom data in addition to poses and labels, while the vision points obtained by MM_Get_VisData command do not contain custom data.

  • 1: The Mech-Vision project ID.

  • pose_num: The variable that stores the number of vision points returned by the vision system.

  • status: The variable that stores the command execution status code.

The entire statement indicates that the robot obtains the vision result from the Mech-Vision project with an ID of 1. The vision result includes custom data.

The returned vision result is saved to the robot memory and cannot be directly obtained. To access the custom data in the vision result, you must store the vision result in a subsequent step.

Store the vision result (including the custom data)

 
!save first vision point data to local variables
MM_Get_DyPose 1,pickpoint,label;

  • MM_Get_DyPose: The command to store the vision result. This command stores custom data in addition to poses and labels. However, MM_Get_Pose can store only poses, labels and tool IDs and cannot store custom data. In addition, MM_Get_DyPose saves the custom data of vision points that was stored in the robot memory to the MM_UserData global array.

  • 1: The first vision point is stored.

  • pickpoint: The variable that stores the TCP of the first vision point, which is the TCP of the picking point.

  • label: The variable that stores the label corresponding to the first vision point.

The entire statement stores the TCP, label, and custom data of the first vision point in the specified variables.

!save received custom data
offset_x:=MM_UserData{1};
offset_y:=MM_UserData{2};
offset_z:=MM_UserData{3};

The above code assigns the MM_UserData{1}, MM_UserData {2}, and MM_UserData{3} custom data that represents three vision points (picking waypoints) to offset_x, offset_y and offset_z, respectively.

You can define the meanings of offset_x, offset_y, and offset_z. For example, they can represent the offset of the robot in each axis of the XYZ coordinate when it moves to the picking waypoint.

We Value Your Privacy

We use cookies to provide you with the best possible experience on our website. By continuing to use the site, you acknowledge that you agree to the use of cookies. If you decline, a single cookie will be used to ensure you're not tracked or remembered when you visit this website.

  • Preference
  • I accept
  • I don't accept