Example Program 9: MM_S9_Viz_RunInAdvance
Program Introduction
Description |
The Mech-Viz project is triggered when the robot performs picking. Then, the camera is started by the Branch by Msg Step of the project when the robot performs placing to plan the next path, shortening the cycle time. |
||
File path |
You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the |
||
Project |
Mech-Vision and Mech-Viz projects
|
||
Prerequisites |
|
| This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario. |
Program Description
This part describes the MM_S9_Viz_RunInAdvance example program.
| The only difference between the MM_S9_Viz_RunInAdvance example program and the MM_S5_Viz_SetBranch example program is that MM_S9_Viz_RunInAdvance can plan the next path (this code of this feature is bolded). As such, only the feature of planning the next path is described in the following section. For information about the parts of MM_S9_Viz_RunInAdvance that are consistent with those of MM_S5_Viz_SetBranch, see Example Program 5: MM_S5_Viz_SetBranch. |
NOP
'--------------------------------
'FUNCTION: trigger Mech-Viz
'project then set branch and get
'planned path, trigger Mech-Viz
'project and set branch in
'advance during pick&place
'process
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger Mech-Viz project
CALL JOB:MM_START_VIZ ARGF"2;30"
'set branch exit port
CALL JOB:MM_SET_BRANCH ARGF"1;1"
*LOOP
'get planned path, 1st argument
'(1) means getting pose in JPs
CALL JOB:MM_GET_VIZDATA ARGF"1;51;52;53"
'check whether planned path has
'been got from Mech-Viz
'successfully
IFTHENEXP I053<>2100
'add error handling logic here
'according to different error
'codes
'e.g.: I053=2038 means no
'point cloud in ROI
PAUSE
ENDIF
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'trigger Mech-Viz project but not
'to trigger camera capturing
CALL JOB:MM_START_VIZ ARGF"2;30"
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'set branch exit port and trigger
'camera capturing when robot
'moves out of camera’s field
'of view
CALL JOB:MM_SET_BRANCH ARGF"1;1"
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
JUMP *LOOP
*ENDLOOP
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
ENDThe workflow corresponding to the above example program code is shown in the figure below.
The following part describes the feature of planning the next path.
| Feature | Code and description | ||||||
|---|---|---|---|---|---|---|---|
Plan the next path in advance by looping (picking→triggering the next round of path planning→placing) |
The above code indicates that the program loops through the code between “*LOOP” and “JUMP *LOOP”. The above code indicates that the robot obtains the planned path from Mech-Viz by running the MM_GET_VIZDATA command. The above code indicates that the robot stores the planned path in the specified variable by running the MM_GET_JPS command. This example assumes that P071, P072, and P073 are the approach waypoint of picking, the picking waypoint, and the departure waypoint of picking. The above code indicates that the robot moves to the approach waypoint of picking and then to the picking waypoint, and then the DO command (such as “DOUT OT#(1) ON”) is run to control the tool to perform picking. The above code indicates that the robot runs the MM_START_VIZ command to start the Mech-Viz project again. Now that the robot has obtained the planned picking path and has moved to the picking waypoint, you can start the Mech-Viz project in advance to plan the next path instead of waiting for the placing to complete and then starting the Mech-Viz project.
The above code indicates that the robot moves to the departure waypoint of picking (P073), the intermediate waypoint (C00002), and then the approach waypoint of placing (C00003).
In the above example, the robot sets the exit port of the Branch by Msg Step with the MM_SET_BRANCH command. On this exit port, the Visual Recognition Step will be executed. Then, Mech-Viz will plan the next picking path in advance based on the vision result. In the above example, the robot moves to the placing waypoint (C00004), performs placing (for example, “DOUT OT#(1) OFF”), and then moves to the departure waypoint of placing (C00005) and then the home position (C00006).
When writing error-handling logic within looped code, you can use the "JUMP *ENDLOOP" statement to jump to the section of the code where communication is closed. |