Example Program 14: MM_S14_Vis_GetUserData

Program Introduction

Description

When the robot obtains the vision result, the robot also obtains the custom output data from the Mech-Vision project.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/YASKAWA/sample/MM_S14_Vis_GetUserData path.

Project

Mech-Vision project (one or more custom ports needed to be added to the Output Step)

Prerequisites

You have set up the Standard Interface communication.
Automatic calibration is completed.

This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario.

Program Description

This part describes the MM_S14_Vis_GetUserData example program.

Compared with the MM_S1_Vis_Basic example program, this example program contains only the following modification (the code of this modification is bolded). As such, only the modification is described in the following section. For information about the parts of MM_S14_Vis_GetUserData that are consistent with those of MM_S1_Vis_Basic, see Example Program 1: MM_S1_Vis_Basic.

NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project and get vision result
'and custom data using
'command 110
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P070 P070
SUB P071 P071
'set 100mm to z of P070
SETE P070 (3) 100000
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_DYDATA ARGF"1;51;52"
'check whether vision result has
'been got from Mech-Vision
'successfully
IFTHENEXP I052<>1100
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: I052=1003 means no point
	'cloud in ROI
	'e.g.: I052=1002 means no
	'vision result
	 PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save first vision point data to
'local variables
CALL JOB:MM_GET_DYPOSE ARGF"1;71;61;61"
'received custom data is saved
'from R061
'R061 = offset_x;
'R062 = offset_y;
'R063 = offset_z;
'move to intermediate waypoint of
'picking
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to picking waypoint
MOVL P071 V=50.0 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to intermediate waypoint of
'placing
MOVJ C00003 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00004 V=166.6 PL=0
'move to placing waypoint
MOVL C00005 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00006 V=166.6 PL=0
'move back to robot home position
MOVJ C00007 VJ=50.00
END

The workflow corresponding to the above example program code is shown in the figure below.

The table below describes the bolded code. You can click the hyperlink to the command name to view its detailed description.

Feature Code and description

Obtain the vision result (including the custom data)

'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_DYDATA ARGF"1;51;52"

For a Mech-Vision project, custom data refers to the data output by the custom ports of the Mech-Vision project.

MM_GET_DYDATA: The command to obtain the vision result. The vision points obtained by this command contain custom data in addition to poses and labels, while the vision points obtained by MM_GET_VISDATA command do not contain custom data.
1: The Mech-Vision project ID.
51: The I variable that has an ID of 51. This variable stores the number of vision points returned by the vision system.
52: The I variable that has an ID of 52. The variable stores the command execution status code.

The entire statement indicates that the robot obtains the vision result from the Mech-Vision project with an ID of 1. The vision result includes custom data.

The returned vision result is saved to the robot memory and cannot be directly obtained. To access the custom data in the vision result, you must store the vision result in a subsequent step.

Store the vision result (including the custom data)

'save first vision point data to
'local variables
CALL JOB:MM_GET_DYPOSE ARGF"1;71;61;61"

MM_GET_DYPOSE: The command to store the vision result. This command stores custom data in addition to poses and labels. However, MM_GET_POSE can store only poses, labels and tool IDs and cannot store custom data. In addition, MM_GET_DYPOSE saves the custom data of vision points that was stored in the robot memory to the specified variable.
1: The first vision point is stored.
71: The P variable that has an ID of 71. The variable stores the TCP of the first vision point, which is the TCP of the picking waypoint.
The first 61: The P variable that has an ID of 61. The variable that stores the label corresponding to the first vision point.
The second 61: The R variable that has an ID of 61. R variables starting from R061 will be used to sequentially store the custom data of the first vision point.

The entire statement stores the TCP, label, and custom data of the first vision point in the specified variables.

'received custom data is saved
'from R061
'R061 = offset_x;
'R062 = offset_y;
'R063 = offset_z;

The above commented section is pseudocode. You can obtain three pieces of custom data for a specific vision point through variables R061, R062, and R063.

You can define the meaning of the custom data. For example, the three pieces of custom data could represent the robot’s offsets along the XYZ axes when moving to the picking waypoint.

Example Program 14: MM_S14_Vis_GetUserData

Program Introduction

Program Description

We Value Your Privacy