样例程序3：MM_S3_Vis_Path
程序解读
以下为MM_S3_Vis_Path样例程序的代码及相关解释说明。
NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project and get planned path
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get planned path from NO.1
'Mech-Vision project; 2nd
'argument (1) means getting pose
'in JPs
CALL JOB:MM_GET_VISPATH ARGF"1;1;51;52;53"
'check whether planned path has
'been got from Mech-Vision
'successfully
IFTHENEXP I053<>1103
'add error handling logic here
'according to different error
'codes
'e.g.: status=1003 means no
'point cloud in ROI
'e.g.: status=1002 means no
'vision results
PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
END上述样例程序代码对应的流程如下图所示。
下表为上述程序的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。
| 流程 | 代码及说明 | ||
|---|---|---|---|
初始化变量 |
因此，整条指令表示将整型变量I050至I069（共20个）清除为0。
因此，上述三条指令表示将位置型变量P071、P072和P073设为0。 |
||
移动到Home点 |
因此，整条指令表示机器人以关节角移动方式移动到示教的Home点。 |
||
初始化通信参数 |
机器人通过MM_INIT_SOCKET指令指定通信对象（工控机）的IP地址（192.168.170.22）、端口号（50000）以及超时等待时间（1分钟）。
|
||
移动到拍照点 |
因此，整条指令表示机器人以关节角移动方式移动到示教的拍照点。 |
||
建立通信 |
机器人通过MM_OPEN_SOCKET指令与视觉系统之间建立TCP协议通信连接。 |
||
触发运行Mech-Vision工程 |
因此，整条指令表示机器人触发视觉系统运行编号为1的Mech-Vision工程，且期望Mech-Vision工程返回所有路径点。 |
||
获取规划路径 |
因此，整条指令表示机器人获取Mech-Vision工程1返回的规划路径。
因此，上述语句表示，当状态码I052为1103时，则机器人成功获取到规划路径；否则视觉系统发生异常，程序执行IFTHENEXP与ENDIF之间的代码。用户可根据具体异常状态码做相应的处理。此样例中对所有异常状态码做了相同处理，即通过PAUSE指令暂停程序的执行。 |
||
关闭通信 |
机器人通过MM_CLOSE_SOCKET指令断开与视觉系统之间的TCP协议通信连接。 |
||
转存规划路径 |
因此，“CALL JOB:MM_GET_JPS ARGF"1;71;61;62"”整条指令表示将第一个路径点的关节角、标签和末端工具编号分别转存至指定变量。
|
||
移动到抓取接近点 |
机器人移动到抓取接近点（即P071所表示的位置）。 |
||
移动到抓取点 |
机器人移动到抓取点（即P072所表示的位置）。 |
||
设置DO执行抓取 |
机器人移动到抓取点后，通过设置DO指令（例如“DOUT OT#(1) ON”），控制末端工具进行抓取。用户需根据实际场景增加设置DO的操作。
|
||
移动到抓取离开点 |
机器人移动到抓取离开点（即P073所表示的位置）。 |
||
移动到中间过渡点 |
机器人移动至抓取离开点与放置接近点之间的某个过渡点。
|
||
移动到放置接近点 |
机器人从中间过渡点移动到放置接近点。
|
||
移动到放置点 |
机器人从放置接近点移动到放置点。
|
||
设置DO执行放置 |
机器人移动到放置点后，通过设置DO指令（例如“DOUT OT#(1) OFF”），控制末端工具进行放置。用户需根据实际场景增加设置DO的操作。
|
||
移动到放置离开点 |
机器人从放置点移动到放置离开点。
|
||
移动到Home点 |
机器人从放置离开点重新移动到Home点。
|