样例程序3：MM_S3_Vis_Path
程序解读
以下为MM_S3_Vis_Path样例程序的代码及相关解释说明。
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !project and get planned path ;
4: !Mech-Mind, 2023-12-25 ;
5: !-------------------------------- ;
6: ;
7: !set current uframe NO. to 0 ;
8: UFRAME_NUM=0 ;
9: !set current tool NO. to 1 ;
10: UTOOL_NUM=1 ;
11: !move to robot home position ;
12:J P[1] 100% FINE ;
13: !initialize communication ;
14: !parameters(initialization is ;
15: !required only once) ;
16: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
17: !move to image-capturing position ;
18:L P[2] 1000mm/sec FINE ;
19: !trigger NO.1 Mech-Vision project ;
20: CALL MM_START_VIS(1,0,2,10) ;
21: !get planned path from NO.1 ;
22: !Mech-Vision project; 2nd ;
23: !argument (1) means getting pose ;
24: !in JPs ;
25: CALL MM_GET_VISP(1,1,51,52,53) ;
26: !check whether planned path has ;
27: !been got from Mech-Vision ;
28: !successfully ;
29: IF R[53]<>1103,JMP LBL[99] ;
30: !save waypoints of the planned ;
31: !path to local variables one ;
32: !by one ;
33: CALL MM_GET_JPS(1,60,70,80) ;
34: CALL MM_GET_JPS(2,61,71,81) ;
35: CALL MM_GET_JPS(3,62,72,82) ;
36: !follow the planned path to pick ;
37: !move to approach waypoint ;
38: !of picking ;
39:J PR[60] 50% FINE ;
40: !move to picking waypoint ;
41:J PR[61] 10% FINE ;
42: !add object grasping logic here, ;
43: !such as "DO[1]=ON" ;
44: PAUSE ;
45: !move to departure waypoint ;
46: !of picking ;
47:J PR[62] 50% FINE ;
48: !move to intermediate waypoint ;
49: !of placing ;
50:J P[3] 50% CNT100 ;
51: !move to approach waypoint ;
52: !of placing ;
53:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
54: !move to placing waypoint ;
55:L P[4] 300mm/sec FINE ;
56: !add object releasing logic here, ;
57: !such as "DO[1]=OFF" ;
58: PAUSE ;
59: !move to departure waypoint ;
60: !of placing ;
61:L P[4] 1000mm/sec FINE Tool_Offset,PR[2] ;
62: !move back to robot home position ;
63:J P[1] 100% FINE ;
64: END ;
65: ;
66: LBL[99:vision error] ;
67: !add error handling logic here ;
68: !according to different ;
69: !error codes ;
70: !e.g.: status=1003 means no ;
71: !point cloud in ROI ;
72: !e.g.: status=1002 means no ;
73: !vision results ;
74: PAUSE ;上述样例程序代码对应的流程如下图所示。
下表为上述程序的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。
| 流程 | 代码及说明 | ||
|---|---|---|---|
设置坐标系 |
因此，上述两条指令表示，设置当前所选的用户坐标系和工具坐标系。 |
||
移动到Home点 |
因此，整条指令表示机器人以关节角移动方式移动至示教的Home点。
|
||
初始化通信参数 |
因此，整条指令表示，机器人通过MM_INIT_SKT指令指定通信对象（工控机）的IP地址、端口号以及超时等待时间，从而与视觉系统建立连接。
|
||
移动到拍照点 |
因此，整条指令表示机器人以直线移动方式移动至示教的拍照点，速度为1000mm/sec。
|
||
触发运行Mech-Vision工程 |
因此，整条指令表示机器人触发视觉系统运行编号为1的Mech-Vision工程，且期望Mech-Vision工程返回所有路径点。 |
||
获取规划路径 |
因此，整条指令表示机器人获取Mech-Vision工程1返回的规划路径。
因此，上述语句表示，当状态码R[53]为1103时，则机器人成功获取到规划路径；否则视觉系统发生异常，程序跳转到LBL[99]处执行。以下为LBL[99]处的代码。 用户可根据具体异常状态码做相应的处理。此样例中对所有异常状态码做了相同处理，即通过PAUSE指令停止程序的执行。 |
||
转存规划路径 |
因此，“CALL MM_GET_JPS(1,60,70,80)”整条指令表示将第一个路径点的关节角、标签和末端工具编号分别转存至指定寄存器。
|
||
移动到抓取接近点 |
机器人移动到抓取接近点（即PR[60]所表示的位置）。 |
||
移动到抓取点 |
机器人移动到抓取点（即PR[61]所表示的位置）。 |
||
设置DO执行抓取 |
机器人移动到抓取点后，通过设置DO指令（例如“DO[1]=ON”），控制末端工具进行抓取。用户需根据实际场景增加设置DO的操作。
|
||
移动到抓取离开点 |
机器人移动到抓取离开点（即PR[62]所表示的位置）。 |
||
移动到中间过渡点 |
因此，整条指令表示机器人以关节角移动方式移动至抓取离开点与放置接近点之间的某个过渡点。
|
||
移动到放置接近点 |
|
||
移动到放置点 |
机器人从放置接近点移动到放置点。 |
||
设置DO执行放置 |
机器人移动到放置点后，通过设置DO指令（例如“DO[1]=OFF”），控制末端工具进行放置。用户需根据实际场景增加设置DO的操作。
|
||
移动到放置离开点 |
机器人移动到放置点上方的某处，即到达放置离开点。
|
||
移动到Home点 |
机器人从放置离开点重新移动到Home点。 |