问题反馈

样例程序14:MM_S14_Vis_GetUserData

您正在查看最新版本(V2.1.0)的文档。如果您想查阅其他版本的文档,可以点击页面右上角“切换版本”按钮进行切换。

■ 如果您不确定当前使用的产品是哪个版本,请随时联系梅卡曼德技术支持。

程序简介

功能说明

机器人在获取视觉结果时,同时获取Mech-Vision工程输出的自定义数据。

文件路径

Mech-Vision和Mech-Viz软件安装目录下Communication Component/Robot_Interface/KUKA/sample/MM_S14_Vis_GetUserData

所需工程

Mech-Vision工程(输出步骤需添加自定义端口

使用前提

  1. 已完成标准接口通信配置

  2. 已完成自动标定

此样例程序仅是示例程序。用户需根据实际情况在此基础上进行修改,请勿直接使用该程序。

程序解读

以下为MM_S14_Vis_GetUserData样例程序的代码及相关解释说明。

与MM_S1_Vis_Basic样例相比,本样例仅修改了如下加粗部分的代码。因此,下文不再重复解释与MM_S1_Vis_Basic样例相同部分的代码(详情请参考MM_S1_Vis_Basic样例说明)。
DEF MM_S14_Vis_GetUserData ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Vision project and get
; vision result and custom data using command 110
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger NO.1 Mech-Vision project
   MM_Start_Vis(1,0,2,init_jps)
   ;get vision result from NO.1 Mech-Vision project
   MM_Get_Dy_Data(1,pos_num,status)
   ;check whether vision result has been got from Mech-Vision successfully
   IF status<> 1100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=1003 means no point cloud in ROI
      ;e.g.: status=1002 means no vision result
      halt
   ENDIF
   ;save first vision point data to local variables
   MM_Get_DyPose(1,Xpick_point,label)
   ;save received custom data
   offset_x=MM_UserData[1]
   offset_y=MM_UserData[2]
   offset_z=MM_UserData[3]
   ;calculate pick approach point based on pick point
   tool_offset={X 0,Y 0,Z -100,A 0,B 0,C 0}
   Xpick_app=Xpick_point:tool_offset
   ;move to intermediate waypoint of picking
PTP pick_waypoint CONT Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to approach waypoint of picking
LIN pick_app Vel=1 m/s CPDAT2 Tool[1] Base[0]
   ;move to picking waypoint
LIN pick_point Vel=0.3 m/s CPDAT3 Tool[1] Base[0]
   ;add object grasping logic here, such as "$OUT[1]=TRUE"
   halt
   ;move to departure waypoint of picking
LIN pick_app Vel=1 m/s CPDAT2 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT4 Tool[1] Base[0]
   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT5 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT4 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT
END

上述样例程序代码对应的流程如下图所示。

sample14

下表是对加粗代码的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。

流程 代码及说明

获取视觉结果(包含自定义数据)

;get vision result from NO.1 Mech-Vision project
MM_Get_Dy_Data(1,pos_num,status)
对于Mech-Vision工程而言,自定义数据是指Mech-Vision自定义端口输出的数据。
  • MM_Get_Dy_Data:获取视觉结果的指令。通过该指令获取的视觉点,除了包含位姿和标签外,还将包含自定义数据,而通过MM_Get_VisData指令获取的视觉点将不包含自定义数据。

  • 1:Mech-Vision工程编号。

  • pose_num:该变量保存视觉系统返回的视觉点个数。

  • status:该变量保存指令执行的状态码。

因此,整条指令表示机器人获取Mech-Vision工程1返回的视觉结果(其中包含自定义数据)。

由于返回的视觉结果保存在机器人内存中,此时用户无法直接获取到视觉结果的自定义数据,必须通过后续“转存视觉结果”才可访问。

转存视觉结果(包含自定义数据)

;save first vision point data to local variables
MM_Get_DyPose(1,Xpick_point,label)
  • MM_Get_DyPose:转存视觉结果的指令。该指令除了转存位姿和标签外,还转存自定义数据,而MM_Get_Pose指令只能转存位姿、标签和末端工具编号,无法转存自定义数据。另外,MM_Get_DyPose指令会将视觉点的自定义数据从机器人内存中转存至MM_UserData全局数组。

  • 1:将转存第一个视觉点。

  • Xpick_point:该变量将保存第一个视觉点的工具位姿,即抓取点的工具位姿。

  • label:该变量将保存第一个视觉点对应的标签。

因此,整条指令表示将第一个视觉点的工具位姿、标签和自定义数据分别转存至指定变量。

;save received custom data
offset_x=MM_UserData[1]
offset_y=MM_UserData[2]
offset_z=MM_UserData[3]

上述代码表示,将视觉点(抓取点)的三个自定义数据MM_UserData[1]、MM_UserData[2]和MM_UserData[3]分别赋值给offset_x、offset_y和offset_z。

offset_x、offset_y和offset_z的含义可由用户自己定义,例如,这三个值可以表示机器人在移动到抓取点时在XYZ各轴的偏置。

我们重视您的隐私

我们使用 cookie 为您在我们的网站上提供最佳体验。继续使用该网站即表示您同意使用 cookie。如果您拒绝,将使用一个单独的 cookie 来确保您在访问本网站时不会被跟踪或记住。