样例程序15：MM_S15_Viz_GetDoList

您正在查看最新版本（V2.1.0）的文档。如果您想查阅其他版本的文档，可以点击页面右上角“切换版本”按钮进行切换。

■ 如果您不确定当前使用的产品是哪个版本，请随时联系梅卡曼德技术支持。

程序简介

功能说明

机器人在获取抓取路径和DO信号后，移动到抓取点并设置DO信号，进而完成抓取与放置。通常用于拆垛场景，且末端工具为多分区吸盘。

文件路径

Mech-Vision和Mech-Viz软件安装目录下Communication Component/Robot_Interface/KUKA/sample/MM_S15_Viz_GetDoList。

所需工程

Mech-Vision工程和Mech-Viz工程（末端工具类型为拆垛吸盘）

使用前提

已完成标准接口通信配置。
已完成自动标定。

此样例程序仅是示例程序。用户需根据实际情况在此基础上进行修改，请勿直接使用该程序。

程序解读

以下为MM_S15_Viz_GetDoList样例程序的代码及相关解释说明。

与MM_S2_Viz_Basic样例相比，本样例仅修改了如下加粗部分的代码。因此，下文不再重复解释与MM_S2_Viz_Basic样例相同部分的代码（详情请参考MM_S2_Viz_Basic样例说明）。

DEF  MM_S15_Viz_GetDoList ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Viz project, then get
; planned path and gripper control signal using
; command 210
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger Mech-Viz project
   MM_Start_Viz(2,init_jps)
   ;get planned path
   MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)
   ;check whether planned path has been got from Mech-Viz successfully
   IF status<> 2100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=2038 means no point cloud in ROI
      halt
   ENDIF
   ;get gripper control signal list
   MM_Get_Dolist(0,0)
   ;save waypoints of the planned path to local variables one by one
   FOR count=1 TO pos_num
     MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count])
   ENDFOR
   Xpick_point1=pick_point[1]
   Xpick_point2=pick_point[2]
   Xpick_point3=pick_point[3]
   ;follow the planned path to pick
   ;move to approach waypoint of picking
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here
   halt
   ;set gripper control signal
   MM_Set_Dolist(0)
   ;move to departure waypoint of picking
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT
END

上述样例程序代码对应的流程如下图所示。

下表是对加粗代码的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。

流程代码及说明

流程	代码及说明
获取规划路径	`;get planned path MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)` MM_Get_PlanData：获取规划路径的指令。通过该指令获取的视觉移动路径点，除了包含位姿外，还将包含视觉移动规划数据或自定义数据（如有），而通过MM_Get_VizData指令获取的视觉移动路径点将不包含视觉移动规划数据或自定义数据。 0：从Mech-Viz获取规划路径。 3：预期返回的数据格式，即以“位姿（关节角形式）,移动类型,末端工具编号,速度,Mech-Viz视觉移动规划数据,自定义数据项1,…,自定义数据项N”格式返回数据。 pose_num：该变量保存视觉系统返回的路径点个数。 vis_pose_num：该变量保存视觉移动路径点（抓取点）在路径中的位置编号。 status：该变量保存指令执行的状态码。
获取吸盘DO信号	`;get gripper control signal list MM_Get_Dolist(0,0)` MM_Get_Dolist：获取吸盘DO信号的指令。第一个0：指定DO信号的来源，即从Mech-Viz获取多分区吸盘DO信号。第二个0：获取所有规划的吸盘DO信号。
转存规划路径	`FOR count=1 TO pos_num MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count]) ENDFOR Xpick_point1=pick_point[1] Xpick_point2=pick_point[2] Xpick_point3=pick_point[3]` 第1行：FOR表示以下为循环程序片段；count用于控制循环的次数（即count从1开始，每次循环后自增1，直到大于pose_num，结束循环）；pose_num为MM_Get_PlanData指令的第三个参数，该参数表示视觉系统返回的路径点个数。第2行：MM_Get_PlanJps指令表示将某个路径点的关节角、移动类型、末端工具编号和速度分别转存到指定变量，因此整条指令表示将第count编号的路径点的关节角、移动类型、末端工具编号和速度依次转存到pick_point[count]、move_type[count]、tool_num[count]和speed[count]变量。第3行：结束FOR循环。第4~6行：将pick_point[1]、pick_point[2]和pick_point[3]分别转存至Xpick_point1、Xpick_point2和Xpick_point3。
移动到抓取点进行抓取	`;move to picking waypoint PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0] ;add object grasping logic here halt ;set gripper control signal MM_Set_Dolist(0)` MM_Set_Dolist：设置吸盘DO信号的指令。 0：设置所有规划的吸盘DO信号。因此，上述语句表示，机器人在移动到抓取点（pick_point2）后，通过MM_Set_Dolist指令设置吸盘DO信号，从而完成抓取。

获取规划路径

;get planned path
MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)

MM_Get_PlanData：获取规划路径的指令。通过该指令获取的视觉移动路径点，除了包含位姿外，还将包含视觉移动规划数据或自定义数据（如有），而通过MM_Get_VizData指令获取的视觉移动路径点将不包含视觉移动规划数据或自定义数据。
0：从Mech-Viz获取规划路径。
3：预期返回的数据格式，即以“位姿（关节角形式）,移动类型,末端工具编号,速度,Mech-Viz视觉移动规划数据,自定义数据项1,…,自定义数据项N”格式返回数据。
pose_num：该变量保存视觉系统返回的路径点个数。
vis_pose_num：该变量保存视觉移动路径点（抓取点）在路径中的位置编号。
status：该变量保存指令执行的状态码。

获取吸盘DO信号

;get gripper control signal list
MM_Get_Dolist(0,0)

MM_Get_Dolist：获取吸盘DO信号的指令。
第一个0：指定DO信号的来源，即从Mech-Viz获取多分区吸盘DO信号。
第二个0：获取所有规划的吸盘DO信号。

转存规划路径

FOR count=1 TO pos_num
MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count])
ENDFOR
Xpick_point1=pick_point[1]
Xpick_point2=pick_point[2]
Xpick_point3=pick_point[3]

第1行：FOR表示以下为循环程序片段；count用于控制循环的次数（即count从1开始，每次循环后自增1，直到大于pose_num，结束循环）；pose_num为MM_Get_PlanData指令的第三个参数，该参数表示视觉系统返回的路径点个数。
第2行：MM_Get_PlanJps指令表示将某个路径点的关节角、移动类型、末端工具编号和速度分别转存到指定变量，因此整条指令表示将第count编号的路径点的关节角、移动类型、末端工具编号和速度依次转存到pick_point[count]、move_type[count]、tool_num[count]和speed[count]变量。
第3行：结束FOR循环。
第4~6行：将pick_point[1]、pick_point[2]和pick_point[3]分别转存至Xpick_point1、Xpick_point2和Xpick_point3。

移动到抓取点进行抓取

   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here
   halt
   ;set gripper control signal
   MM_Set_Dolist(0)

MM_Set_Dolist：设置吸盘DO信号的指令。
0：设置所有规划的吸盘DO信号。

因此，上述语句表示，机器人在移动到抓取点（pick_point2）后，通过MM_Set_Dolist指令设置吸盘DO信号，从而完成抓取。

样例程序15：MM_S15_Viz_GetDoList

程序简介

程序解读

我们重视您的隐私