问题反馈

样例程序12:MM_S12_Viz_ForLoop

您正在查看最新版本(V2.1.0)的文档。如果您想查阅其他版本的文档,可以点击页面右上角“切换版本”按钮进行切换。

■ 如果您不确定当前使用的产品是哪个版本,请随时联系梅卡曼德技术支持。

程序简介

功能说明

机器人触发Mech-Viz工程运行,并获取路径规划结果,然后通过循环转存规划路径,进而执行抓取和放置操作。

文件路径

Mech-Vision和Mech-Viz软件安装目录下Communication Component/Robot_Interface/KUKA/sample/MM_S12_Viz_ForLoop

所需工程

Mech-Vision工程和Mech-Viz工程

使用前提

  1. 已完成标准接口通信配置

  2. 已完成自动标定

此样例程序仅是示例程序。用户需根据实际情况在此基础上进行修改,请勿直接使用该程序。

程序解读

以下为MM_S12_Viz_ForLoop样例程序的代码及相关解释说明。

MM_S2_Viz_Basic是逐个转存规划的路径点,本样例是通过循环转存规划的路径点(加粗部分的代码)。因此,下文不再重复解释与MM_S2_Viz_Basic样例相同部分的代码(详情请参考MM_S2_Viz_Basic样例说明)。
DEF  MM_S12_Viz_ForLoop ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Viz project and get
; planned path, get poses using for-loop structure
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger Mech-Viz project
   MM_Start_Viz(2,init_jps)
   ;get planned path, 1st argument (1) means getting pose in JPs
   MM_Get_VizData(1,pos_num,vis_pos_num,status)
   ;check whether planned path has been got from Mech-Viz successfully
   IF status<> 2100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=2038 means no point cloud in ROI
      halt
   ENDIF
   ;save waypoints of planned path to local variables using for-loop structure
   FOR count=1 TO pos_num
      MM_Get_Jps(count,pick_point[count],label[count],toolid[count])
   ENDFOR
   Xpick_point1=pick_point[1]
   Xpick_point2=pick_point[2]
   Xpick_point3=pick_point[3]
   ;follow the planned path to pick
   ;move to approach waypoint of picking
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here, such as "$OUT[1]=TRUE"
   halt
   ;move to departure waypoint of picking
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT
END

上述样例程序代码对应的流程如下图所示。

sample12

下表为通过循环转存规划路径的逻辑解读。用户单击指令名称的超链接便可查看该指令的详细说明。

流程 代码及说明

通过循环转存规划路径

FOR count=1 TO pos_num
   MM_Get_Jps(count,pick_point[count],label[count],toolid[count])
ENDFOR
Xpick_point1=pick_point[1]
Xpick_point2=pick_point[2]
Xpick_point3=pick_point[3]
  • 第1行:FOR表示以下为循环程序片段;count用于控制循环的次数(即count从1开始,每次循环后自增1,直到大于pose_num,结束循环);pose_num为MM_Get_VizData指令的第二个参数,该参数表示视觉系统返回的路径点个数。

  • 第2行:MM_Get_Jps指令表示将某个路径点的关节角、标签和末端工具编号分别转存到指定变量,因此整条指令表示将第count编号的路径点的关节角、标签和末端工具编号依次转存到pick_point[count]、label[count]和toolid[count]变量。

  • 第3行:结束FOR循环。

  • 第4~6行:将pick_point[1]、pick_point[2]和pick_point[3]分别转存至Xpick_point1、Xpick_point2和Xpick_point3。

假设本样例规划的路径有3个路径点,则上述代码等同于MM_S2_Viz_Basic样例中如下三条指令。

MM_Get_Jps(1,Xpick_point1,label[1],toolid[1])
MM_Get_Jps(2,Xpick_point2,label[2],toolid[2])
MM_Get_Jps(3,Xpick_point3,label[3],toolid[3])

我们重视您的隐私

我们使用 cookie 为您在我们的网站上提供最佳体验。继续使用该网站即表示您同意使用 cookie。如果您拒绝,将使用一个单独的 cookie 来确保您在访问本网站时不会被跟踪或记住。