サンプルプログラム17：MM_S17_Vis_ParseLabel

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project and get vision result, ;
   4:  !then parse the label info ;
   5:  !Mech-Mind, 2023-12-25 ;
   6:  !-------------------------------- ;
   7:   ;
   8:  !set current uframe NO. to 0 ;
   9:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  10:  !set current tool NO. to 1 ;
  11:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  12:  !move to robot home position ;
  13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  14:  !initialize communication ;
  15:  !parameters(initialization is ;
  16:  !required only once) ;
  17:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  18:  !move to image-capturing position ;
  19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  20:  !trigger NO.1 Mech-Vision project ;
  21:  ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10) ;
  22:  !get vision result from NO.1 ;
  23:  !Mech-Vision project ;
  24:  ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
  25:  !check whether vision result has ;
  26:  !been got from Mech-Vision ;
  27:  !successfully ;
  28:  ﾓｼ ﾚｼﾞ[53]<>1100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  29:  !save first vision point data to ;
  30:  !local variables ;
  31:  ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
  32:  !parse label info received from ;
  33:  !Mech-Vision, eg. "R[70]=56" ;
  34:  !will decompose into 5 and 6 ;
  35:  ﾚｼﾞ[30]=ﾚｼﾞ[70] DIV 10    ;
  36:  ﾚｼﾞ[31]=ﾚｼﾞ[70] MOD 10    ;
  37:  !add handling logic according to ;
  38:  !decomposed label value ;
  39:  IF (ﾚｼﾞ[30]=5) THEN ;
  40:  !add handling logic a ;
  41:  ｲﾁｼﾞﾃｲｼ ;
  42:  ELSE ;
  43:  !add handling logic b ;
  44:  ｲﾁｼﾞﾃｲｼ ;
  45:  ENDIF ;
  46:  !move to intermediate waypoint ;
  47:  !of picking ;
  48:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  49:  !move to approach waypoint ;
  50:  !of picking ;
  51:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  52:  !move to picking waypoint ;
  53:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ    ;
  54:  !add object grasping logic here, ;
  55:  !such as "DO[1]=ON" ;
  56:  ｲﾁｼﾞﾃｲｼ ;
  57:  !move to departure waypoint ;
  58:  !of picking ;
  59:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  60:  !move to intermediate waypoint ;
  61:  !of placing ;
  62:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  63:  !move to approach waypoint ;
  64:  !of placing ;
  65:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  66:  !move to placing waypoint ;
  67:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;
  68:  !add object releasing logic here, ;
  69:  !such as "DO[1]=OFF" ;
  70:  ｲﾁｼﾞﾃｲｼ ;
  71:  !move to departure waypoint ;
  72:  !of placing ;
  73:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  74:  !move back to robot home position ;
  75:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  76:  ｼｭｳﾘｮｳ ;
  77:   ;
  78:  ﾗﾍﾞﾙ[99:vision error] ;
  79:  !add error handling logic here ;
  80:  !according to different ;
  81:  !error codes ;
  82:  !e.g.: status=1003 means no ;
  83:  !point cloud in ROI ;
  84:  !e.g.: status=1002 means no ;
  85:  !vision results ;
  86:  ｲﾁｼﾞﾃｲｼ ;

Copied!