サンプルプログラム14：MM_S14_Vis_GetUserData

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project and get vision result ;
   4:  !and custom data using ;
   5:  !command 110 ;
   6:  !Mech-Mind, 2023-12-25 ;
   7:  !-------------------------------- ;
   8:   ;
   9:  !set current uframe NO. to 0 ;
  10:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  11:  !set current tool NO. to 1 ;
  12:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  13:  !move to robot home position ;
  14:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  15:  !initialize communication ;
  16:  !parameters(initialization is ;
  17:  !required only once) ;
  18:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  19:  !move to image-capturing position ;
  20:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  21:  !trigger NO.1 Mech-Vision project ;
  22:  ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10) ;
  23:  !get vision result from NO.1 ;
  24:  !Mech-Vision project ;
  25:  ﾖﾋﾞﾀﾞｼ MM_GET_DY_DT(1,51,53) ;
  26:  !check whether vision result has ;
  27:  !been got from Mech-Vision ;
  28:  !successfully ;
  29:  ﾓｼ ﾚｼﾞ[53]<>1100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  30:  !save first vision point data to ;
  31:  !local variables ;
  32:  ﾖﾋﾞﾀﾞｼ MM_GET_DYPOS(1,60,70,90) ;
  33:  !save received custom data ;
  34:  ﾚｼﾞ[10]=ﾚｼﾞ[90]    ;
  35:  ﾚｼﾞ[11]=ﾚｼﾞ[91]    ;
  36:  ﾚｼﾞ[12]=ﾚｼﾞ[92]    ;
  37:  !move to intermediate waypoint ;
  38:  !of picking ;
  39:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  40:  !move to approach waypoint ;
  41:  !of picking ;
  42:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  43:  !move to picking waypoint ;
  44:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ    ;
  45:  !add object grasping logic here, ;
  46:  !such as "DO[1]=ON" ;
  47:  ｲﾁｼﾞﾃｲｼ ;
  48:  !move to departure waypoint ;
  49:  !of picking ;
  50:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  51:  !move to intermediate waypoint ;
  52:  !of placing ;
  53:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  54:  !move to approach waypoint ;
  55:  !of placing ;
  56:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  57:  !move to placing waypoint ;
  58:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;
  59:  !add object releasing logic here, ;
  60:  !such as "DO[1]=OFF" ;
  61:  ｲﾁｼﾞﾃｲｼ ;
  62:  !move to departure waypoint ;
  63:  !of placing ;
  64:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  65:  !move back to robot home position ;
  66:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  67:  ｼｭｳﾘｮｳ ;
  68:   ;
  69:  ﾗﾍﾞﾙ[99:vision error] ;
  70:  !add error handling logic here ;
  71:  !according to different ;
  72:  !error codes ;
  73:  !e.g.: status=1003 means no ;
  74:  !point cloud in ROI ;
  75:  !e.g.: status=1002 means no ;
  76:  !vision results ;
  77:  ｲﾁｼﾞﾃｲｼ ;

Copied!