サンプルプログラム13：MM_S13_Vis_MoveInAdvance

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !then move to wait position and ;
   4:  !get vision pose in EIH setup ;
   5:  !Mech-Mind, 2023-12-25 ;
   6:  !-------------------------------- ;
   7:   ;
   8:  !set current uframe NO. to 0 ;
   9:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  10:  !set current tool NO. to 1 ;
  11:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  12:  !move to robot home position ;
  13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  14:  !initialize communication ;
  15:  !parameters(initialization is ;
  16:  !required only once) ;
  17:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  18:  !move to image-capturing position ;
  19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  20:  !trigger NO.1 Mech-Vision project ;
  21:  ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,1,10) ;
  22:  !move to wait position for ;
  23:  !picking ;
  24:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  25:  !get vision result from NO.1 ;
  26:  !Mech-Vision project ;
  27:  ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
  28:  !check whether vision result has ;
  29:  !been got from Mech-Vision ;
  30:  !successfully ;
  31:  ﾓｼ ﾚｼﾞ[53]<>1100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  32:  !save first vision point data to ;
  33:  !local variables ;
  34:  ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
  35:  !move to intermediate waypoint ;
  36:  !of picking ;
  37:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  38:  !move to approach waypoint ;
  39:  !of picking ;
  40:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  41:  !move to picking waypoint ;
  42:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ    ;
  43:  !add object grasping logic here, ;
  44:  !such as "DO[1]=ON" ;
  45:  ｲﾁｼﾞﾃｲｼ ;
  46:  !move to departure waypoint ;
  47:  !of picking ;
  48:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  49:  !move to intermediate waypoint ;
  50:  !of placing ;
  51:ｶｸｼﾞｸ ｲﾁ[5] 50% ﾅﾒﾗｶ100    ;
  52:  !move to approach waypoint ;
  53:  !of placing ;
  54:ﾁｮｸｾﾝ ｲﾁ[6] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  55:  !move to placing waypoint ;
  56:ﾁｮｸｾﾝ ｲﾁ[6] 300mm/sec ｲﾁｷﾞﾒ    ;
  57:  !add object releasing logic here, ;
  58:  !such as "DO[1]=OFF" ;
  59:  ｲﾁｼﾞﾃｲｼ ;
  60:  !move to departure waypoint ;
  61:  !of placing ;
  62:ﾁｮｸｾﾝ ｲﾁ[6] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  63:  !move back to robot home position ;
  64:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  65:  ｼｭｳﾘｮｳ ;
  66:   ;
  67:  ﾗﾍﾞﾙ[99:vision error] ;
  68:  !add error handling logic here ;
  69:  !according to different ;
  70:  !error codes ;
  71:  !e.g.: status=1003 means no ;
  72:  !point cloud in ROI ;
  73:  !e.g.: status=1002 means no ;
  74:  !vision results ;
  75:  ｲﾁｼﾞﾃｲｼ ;

Copied!