サンプルプログラム15：MM_S15_Viz_GetDoList

現在ご覧いただいているのは2.0.0 バージョンの内容です。異なるバージョンを参照する場合は、画面右上のボタンから切り替えが可能です。

■ 最新版をご利用される場合は、弊社ホームページよりダウンロードが可能です。ダウンロードにはパスワードが必要となりますので、サポート窓口までお問い合わせください。

■ ご利用中のバージョンが分からない場合はお気軽にサポート窓口までご連絡ください。

プログラム概要

機能

ロボットが把持経路とDO信号を取得した後、把持点に移動してDO信号を設定し、把持および配置を実行します。通常、ロボットハンドが複数のブロック吸盤を使用するデパレタイジングシーンに適しています。

ファイル場所

Mech-VisionとMech-Vizソフトウェアのインストールディレクトリにある Communication Component/Robot_Interface/KUKA/sample/MM_S15_Viz_GetDoList。

必要なプロジェクト

Mech-VisionとMech-Vizプロジェクト（ロボットハンド種類がデパレタイズ用吸盤である必要があります）

使用前提

  1. 標準インターフェース通信設定 が完了しました。

  2. 自動キャリブレーション が完了しました。
このサンプルプログラムは参考用です。ユーザーは実際の状況に応じて、このプログラムを基に変更を加える必要があります。このプログラムをそのまま使用しないでください。

プログラム説明

以下はMM_S15_Viz_GetDoListサンプルプログラムのコードと関連する説明です。

このサンプルは、MM_S2_Viz_Basicサンプルに比べて、太字部分のコードのみが追加されています。そのため、MM_S2_Viz_Basicサンプルと同じ部分のコードについては、以下で再度説明することはありません（詳細は MM_S2_Viz_Basicサンプルの説明 をご参照ください）。 
DEF  MM_S15_Viz_GetDoList ( )
;---------------------------------------------------
; FUNCTION: trigger Mech-Viz project, then get
; planned path and gripper control signal using
; command 210
; Mech-Mind, 2023-12-25
;---------------------------------------------------
   ;set current tool no. to 1
   BAS(#TOOL,1)
   ;set current base no. to 0
   BAS(#BASE,0)
   ;move to robot home position
PTP HOME Vel=100 % DEFAULT
   ;initialize communication parameters (initialization is required only once)
   MM_Init_Socket("XML_Kuka_MMIND",873,871,60)
   ;move to image-capturing position
LIN camera_capture Vel=1 m/s CPDAT1 Tool[1] Base[0]
   ;trigger Mech-Viz project
   MM_Start_Viz(2,init_jps)
   ;get planned path
   MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)
   ;check whether planned path has been got from Mech-Viz successfully
   IF status<> 2100 THEN
      ;add error handling logic here according to different error codes
      ;e.g.: status=2038 means no point cloud in ROI
      halt
   ENDIF
   ;get gripper control signal list
   MM_Get_Dolist(0,0)
   ;save waypoints of the planned path to local variables one by one
   FOR count=1 TO pos_num
     MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count])
   ENDFOR
   Xpick_point1=pick_point[1]
   Xpick_point2=pick_point[2]
   Xpick_point3=pick_point[3]
   ;follow the planned path to pick
   ;move to approach waypoint of picking
PTP pick_point1 Vel=50 % PDAT1 Tool[1] Base[0]
   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here
   halt
   ;set gripper control signal
   MM_Set_Dolist(0)
   ;move to departure waypoint of picking
PTP pick_point3 Vel=50 % PDAT3 Tool[1] Base[0]
   ;move to intermediate waypoint of placing
PTP drop_waypoint CONT Vel=100 % PDAT2 Tool[1] Base[0]
   ;move to approach waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move to placing waypoint
LIN drop Vel=0.3 m/s CPDAT4 Tool[1] Base[0]
   ;add object releasing logic here, such as "$OUT[1]=FALSE"
   halt
   ;move to departure waypoint of placing
LIN drop_app Vel=1 m/s CPDAT3 Tool[1] Base[0]
   ;move back to robot home position
PTP HOME Vel=100 % DEFAULT
END

上記のサンプルプログラムの処理流れは、下図の通りです。

sample15

下表は太字部分のコードとその説明です。コマンド名のリンクをクリックすることで、その詳細を確認できます。

処理流れ コートと説明

計画された経路を取得

 
;get planned path
MM_Get_PlanData(0,3,pos_num,vis_pos_num,status)

  • MM_Get_PlanData：計画された経路を取得するためのコマンド。このコマンドを使用して取得した「ビジョン処理による移動」の経路点は、位置姿勢に加えて、「ビジョン処理による移動」の計画結果やカスタムデータ（ある場合）も含まれます。一方、MM_Get_VizData コマンドを使用して取得した「ビジョン処理による移動」の経路点には、「ビジョン処理による移動」の計画結果やカスタムデータは含まれていません。

  • 0：Mech-Vizから計画された経路を取得します。

  • 3：返されるデータ形式。「位置姿勢（関節角度形式）、移動方式、ロボットハンド番号、速度、Mech-Vizの「ビジョン処理による移動」の計画結果、カスタムデータ項目1、…、カスタムデータ項目N」といった形式でデータを返します。

  • pose_num：この変数はビジョンシステムから返された経路点の数を保存します。

  • vis_pose_num：この変数は、「ビジョン処理による移動」の経路点（把持点）が経路全体における位置番号を保存します。

  • status：この変数はコマンド実行のステータスコードを保存します。

吸盤のDO信号を取得

 
;get gripper control signal list
MM_Get_Dolist(0,0)

  • MM_Get_Dolist：吸盤のDO信号を取得するためのコマンド。

  • 最初の0：DO信号の出力先を指定します。つまり、Mech-Vizから複数ブロック吸盤のDO信号を取得します。

  • 2番目の0：計画されたすべての吸盤のDO信号を取得します。

計画された経路を保存

 
FOR count=1 TO pos_num
MM_Get_PlanJps(count,3,pick_point[count],move_type[count],tool_num[count],speed[count])
ENDFOR
Xpick_point1=pick_point[1]
Xpick_point2=pick_point[2]
Xpick_point3=pick_point[3]

  • 1行目：FORは以下がループプログラム部分を示します。countはループの回数を制御します（countは1から始まり、毎回ループ後に1増加し、pose_numより大きくなるとループが終了します）。pose_numは MM_Get_PlanData コマンドにおける3番目のパラメータで、このパラメータはビジョンシステムが返す経路点の数を示します。

  • 2行目：MM_Get_PlanJps コマンドは、ある経路点の関節角度、移動方式、ロボットハンド番号、速度をそれぞれ指定された変数に保存することを意味します。つまり、このコマンドはcount番目の経路点の関節角度、移動方式、ロボットハンド番号、速度をそれぞれpick_point[count]、move_type[count]、tool_num[count]、speed[count]に保存することを意味します。

  • 3行目：FORループを終了します。

  • 4~6行目：pick_point[1]、pick_point[2]、pick_point[3]をそれぞれXpick_point1、Xpick_point2、Xpick_point3に保存します。

把持点に移動して把持を実行

 
   ;move to picking waypoint
PTP pick_point2 Vel=10 % PDAT2 Tool[1] Base[0]
   ;add object grasping logic here
   halt
   ;set gripper control signal
   MM_Set_Dolist(0)

  • MM_Set_Dolist：吸盤のDO信号を設定するためのコマンド。

  • 0：計画された吸盤のDO信号をすべて設定します。

上記のコードは、ロボットが把持点（pick_point2）に移動した後、MM_Set_Dolistコマンドを使用して吸盤のDO信号を設定し、把持を完了することを意味します。

この情報は役に立ちましたか？

ご意見・ご要望がございましたら、以下よりお寄せください：

Mech-Mindは、お客様のプライバシーを重視しています

このサイトでは最高の体験を提供するために Cookie を使用しています。サイトの閲覧を続ける場合、Cookie の使用に同意したことになります。「拒否する」を選択すると、このサイトを訪れた際に追跡や記憶が行われないように単独の Cookie が使用されます。

  • Preference
  • 同意する
  • 拒否する