サンプルプログラム4：MM_S4_Vis_ChangeModel

   1:  !-------------------------------- ;
   2:  !FUNCTION: trigger Mech-Vision ;
   3:  !project after switching recipe ;
   4:  !and get vision result ;
   5:  !Mech-Mind, 2023-12-25 ;
   6:  !-------------------------------- ;
   7:   ;
   8:  !set current uframe NO. to 0 ;
   9:  ﾕｰｻﾞｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=0 ;
  10:  !set current tool NO. to 1 ;
  11:  ﾂｰﾙｻﾞﾋｮｳﾊﾞﾝｺﾞｳ=1 ;
  12:  !move to robot home position ;
  13:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  14:  !initialize communication ;
  15:  !parameters(initialization is ;
  16:  !required only once) ;
  17:  ﾖﾋﾞﾀﾞｼ MM_INIT_SKT('8','127.0.0.1',50000,5) ;
  18:  !move to image-capturing position ;
  19:ﾁｮｸｾﾝ ｲﾁ[2] 1000mm/sec ｲﾁｷﾞﾒ    ;
  20:  !switch recipe of NO.1 ;
  21:  !Mech-Vision project, ;
  22:  !"MM_SET_MOD(Proj_num,Model_num)" ;
  23:  ﾖﾋﾞﾀﾞｼ MM_SET_MOD(1,1) ;
  24:  !trigger NO.1 Mech-Vision project ;
  25:  ﾖﾋﾞﾀﾞｼ MM_START_VIS(1,0,2,10) ;
  26:  !get vision result from NO.1 ;
  27:  !Mech-Vision project ;
  28:  ﾖﾋﾞﾀﾞｼ MM_GET_VIS(1,51,53) ;
  29:  !check whether vision result has ;
  30:  !been got from Mech-Vision ;
  31:  !successfully ;
  32:  ﾓｼ ﾚｼﾞ[53]<>1100,ｼﾞｬﾝﾌﾟ ﾗﾍﾞﾙ[99] ;
  33:  !save first vision point data to ;
  34:  !local variables ;
  35:  ﾖﾋﾞﾀﾞｼ MM_GET_POS(1,60,70,80) ;
  36:  !move to intermediate waypoint ;
  37:  !of picking ;
  38:ｶｸｼﾞｸ ｲﾁ[3] 50% ﾅﾒﾗｶ100    ;
  39:  !move to approach waypoint ;
  40:  !of picking ;
  41:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  42:  !move to picking waypoint ;
  43:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 300mm/sec ｲﾁｷﾞﾒ    ;
  44:  !add object grasping logic here, ;
  45:  !such as "DO[1]=ON" ;
  46:  ｲﾁｼﾞﾃｲｼ ;
  47:  !move to departure waypoint ;
  48:  !of picking ;
  49:ﾁｮｸｾﾝ ｲﾁﾚｼﾞ[60] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[1]    ;
  50:  !move to intermediate waypoint ;
  51:  !of placing ;
  52:ｶｸｼﾞｸ ｲﾁ[4] 50% ﾅﾒﾗｶ100    ;
  53:  !move to approach waypoint ;
  54:  !of placing ;
  55:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  56:  !move to placing waypoint ;
  57:ﾁｮｸｾﾝ ｲﾁ[5] 300mm/sec ｲﾁｷﾞﾒ    ;
  58:  !add object releasing logic here, ;
  59:  !such as "DO[1]=OFF" ;
  60:  ｲﾁｼﾞﾃｲｼ ;
  61:  !move to departure waypoint ;
  62:  !of placing ;
  63:ﾁｮｸｾﾝ ｲﾁ[5] 1000mm/sec ｲﾁｷﾞﾒ ﾂｰﾙﾎｾｲ,ｲﾁﾚｼﾞ[2]    ;
  64:  !move back to robot home position ;
  65:ｶｸｼﾞｸ ｲﾁ[1] 100% ｲﾁｷﾞﾒ    ;
  66:  ｼｭｳﾘｮｳ ;
  67:   ;
  68:  ﾗﾍﾞﾙ[99:vision error] ;
  69:  !add error handling logic here ;
  70:  !according to different ;
  71:  !error codes ;
  72:  !e.g.: status=1003 means no ;
  73:  !point cloud in ROI ;
  74:  !e.g.: status=1002 means no ;
  75:  !vision results ;
  76:  ｲﾁｼﾞﾃｲｼ ;

Copied!