Example Program 4: MM_S4_Vis_ChangeModel
Program Introduction
Description |
The robot switches the Mech-Vision parameter recipe, and then triggers the Mech-Vision project to run to obtain the vision result for picking and placing. |
||
File path |
You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the |
||
Project |
Mech-Vision project
|
||
Prerequisites |
|
| This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario. |
Program Description
This part describes the MM_S4_Vis_ChangeModel example program.
| The only difference between the MM_S4_Vis_ChangeModel example program and the MM_S1_Vis_Basic example program is that MM_S4_Vis_ChangeModel can switch the parameter recipe in the Mech-Vision project (this code of this feature is bolded). As such, only the feature of switching the parameter recipe is described in the following section. For information about the parts of MM_S4_Vis_ChangeModel that are consistent with those of MM_S1_Vis_Basic, see Example Program 1: MM_S1_Vis_Basic. |
NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project after switching recipe
'and get vision result
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P070 P070
SUB P071 P071
'set 100mm to z of P070
SETE P070 (3) 100000
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'switch recipe of NO.1
'Mech-Vision project
CALL JOB:MM_SET_MODEL ARGF"1;1"
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_VISDATA ARGF"1;51;52"
'check whether vision result has
'been got from Mech-Vision
'successfully
IFTHENEXP I052<>1100
'add error handling logic here
'according to different error
'codes
'e.g.: I052=1003 means no point
'cloud in ROI
'e.g.: I052=1002 means no
'vision result
PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save first vision point data to
'local variables
CALL JOB:MM_GET_POSE ARGF"1;71;61;62"
'move to intermediate waypoint of
'picking
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to picking waypoint
MOVL P071 V=50.0 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to intermediate waypoint of
'placing
MOVJ C00003 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00004 V=166.6 PL=0
'move to placing waypoint
MOVL C00005 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00006 V=166.6 PL=0
'move back to robot home position
MOVJ C00007 VJ=50.00
ENDThe workflow corresponding to the above example program code is shown in the figure below.
The table below describes the process of switching the parameter recipe in the Mech-Vision project. You can click the hyperlink to the command name to view its detailed description.
| Feature | Code and description |
|---|---|
Switch Mech-Vision Parameter Recipe |
In this entire statement, the parameter recipe of the Mech-Vision project whose ID is 1 is switched to recipe 1. |