Example Program 3: MM_S3_Vis_Path

You are currently viewing the documentation for the latest version (2.1.0). To access a different version, click the "Switch version" button located in the upper-right corner of the page.

■ If you are not sure which version of the product you are currently using, please feel free to contact Mech-Mind Technical Support.

Program Introduction

Description

The robot triggers the Mech-Vision project to run, and then obtains the planned path for picking and placing.

File path

You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the Communication Component/Robot_Interface/YASKAWA/sample/MM_S3_Vis_Path path.

Project

Mech-Vision project

The Mech-Vision project should contain a Path Planning Step, and the Port Type parameter of the Output Step should be set to Predefined (robot path).

Prerequisites

You have set up the Standard Interface communication.
Automatic calibration is completed.

This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario.

Program Description

This part describes the MM_S3_Vis_Path example program.

NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project and get planned path
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'get planned path from NO.1
'Mech-Vision project; 2nd
'argument (1) means getting pose
'in JPs
CALL JOB:MM_GET_VISPATH ARGF"1;1;51;52;53"
'check whether planned path has
'been got from Mech-Vision
'successfully
IFTHENEXP I053<>1103
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: status=1003 means no
	'point cloud in ROI
	'e.g.: status=1002 means no
	'vision results
	 PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"
'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0
'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0
'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0
'move to placing waypoint
MOVL C00004 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move back to robot home position
MOVJ C00006 VJ=50.00
END

The workflow corresponding to the above example program code is shown in the figure below.

The table below explains the above program. You can click the hyperlink to the command name to view its detailed description.

Feature Code and description

Initialize variables

'clear I50 to I69
CLEAR I050 20

CLEAR: The command to clear data.
I050: Specify to clear data of I variables starting from I variable 50.
20: Specify to clear data of 20 variables.

The entire statement indicates to clear data of integer variables I050 to I069 (a total of 20 variables) by setting them to 0.

'initialize p variables
SUB P071 P071
SUB P072 P072
SUB P073 P073

SUB: The subtraction command.
First P071: Specify the minuend as the P position variable P071 and store the result of the subtraction operation in P071.
Second P071: Specify the subtrahend as the position variable P071.

The above two statements indicate that the position variables P071, P072, and P073 are set to 0.

Move to the home position

'move to robot home position
MOVJ C00000 VJ=50.00

MOVJ: The joint position-based motion command.

C00000: The ID of the position that is taught to the robot.

You should teach the home position (C00000) in advance. For detailed instructions, see Teach Calibration Start Point in the calibration document.
After C00000 is taught, the robot axis teaching positions will be unconditionally written into C00000. The position cannot be edited.
C00000 will not appear on the teach pendant interface.

VJ=50.00: The joint velocity. Joint velocity is represented as a proportion of the maximum velocity.

The entire statement indicates that the robot moves to the taught home position by using joint position movement.

Initialize communication parameters

'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"

CALL: Call a specific command or program.
JOB: Specify the command or program to call.
MM_INIT_SOCKET: The command to initialize the communication.
ARGF: On the teach pendant interface, ARGF is displayed as a pair of English brackets.
192.168.170.22: The IP address of the IPC.
50000: The port number of the IPC.
1: Specify the communication timeout period as 1 minute.

The robot sends the MM_INIT_SOCKET command to set the IP address, port number, and timeout period of the communication object (the IPC) to 192.168.170.22, 50000, and 1 minute.

Please modify the IP address and port number of the IPC according to the actual situation. The IP address and port number must be consistent with those set in the vision system.

Move to the image-capturing position

'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0

C00001: The ID of the position that is taught to the robot. You should teach the image-capturing position (C00001) in advance. For detailed instructions, see Teach Calibration Start Point in the calibration document.
PL=0: Set the position level to 0. Position level refers to the robot’s proximity to the taught position, with a range from 0 to 8. A smaller value indicates that the robot is closer to the position.

The entire statement indicates that the robot moves to the taught image-capturing position by using joint position movement.

Establish the communication

'open socket connection
CALL JOB:MM_OPEN_SOCKET

The TCP communication between the robot and the vision system is established by using the MM_OPEN_SOCKET command.

Trigger the Mech-Vision project to run

'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"

MM_START_VIS: The command to trigger the Mech-Vision project to run.
1: The Mech-Vision project ID.
0: The Mech-Vision project is expected to return all waypoints.
2: Specify that the robot flange pose must be input to the Mech-Vision project.
30: The P variable that has an ID of 30. The variable stores the custom joint position data. In this example program, the joint position data is of no practical use.

The entire statement indicates that the robot triggers the vision system to run the Mech-Vision project with an ID of 1 and expects the Mech-Vision project to return all waypoints.

Obtain the planned path

'get planned path from NO.1
'Mech-Vision project; 2nd
'argument (1) means getting pose
'in JPs
CALL JOB:MM_GET_VISPATH ARGF"1;1;51;52;53"

MM_GET_VISPATH: The command to obtain the planned path from Mech-Vision.
First 1: Specify the Mech-Vision project ID.
Second 1: Specify the pose type of obtained waypoints as joint positions.
51: The I variable that has an ID of 51. This variable stores the number of waypoints returned by the vision system.
52: The I variable that has an ID of 52. This variable stores the sequence number of the Vision Move waypoint (picking waypoint) in the path.
53: The I variable that has an ID of 53. This variable stores the command execution status code.

The entire statement indicates that the robot obtains the planned path from the Mech-Vision project that has an ID of 1.

The returned planned path is saved to the robot memory and cannot be directly obtained. To access the planned path, you must store the planned path in a subsequent step.

'check whether planned path has
'been got from Mech-Vision
'successfully
IFTHENEXP I053<>1103
	'add error handling logic here
	'according to different error
	'codes
	'e.g.: status=1003 means no
	'point cloud in ROI
	'e.g.: status=1002 means no
	'vision results
	 PAUSE
ENDIF

IFTHENEXP A … ENDIF: When condition A is met, the program executes the code between IFTHENEXP and ENDIF.
<>： Not equal.

The above statement indicates that when the status code in I052 is 1103, the robot has successfully obtained the planned path; otherwise, an exception has occurred in the vision system and the program executes the code between IFTHENEXP and ENDIF. You can perform the corresponding operation based on the specific error code. In this example program, all error codes are handled in the same way, by pausing the program execution using the PAUSE command.

Close the communication

'close socket connection
CALL JOB:MM_CLOSE_SOCKET

The TCP communication between the robot and the vision system is closed by using the MM_CLOSE_SOCKET command.

Store the planned path

'save waypoints of the planned
'path to local variables one
'by one
CALL JOB:MM_GET_JPS ARGF"1;71;61;62"
CALL JOB:MM_GET_JPS ARGF"2;72;63;64"
CALL JOB:MM_GET_JPS ARGF"3;73;65;66"

MM_GET_JPS: The command to store the planned path.
1: Store the first waypoint.
71: The P variable that has an ID of 71. This variable stores the joint positions of the first waypoint.
61: The I variable that has an ID of 61. This variable stores the label of the first waypoint.
62: The I variable that has an ID of 62. This variable stores the tool ID of the first waypoint.

The entire command “CALL JOB:MM_GET_JPS ARGF"1;71;61;62"” stores the joint positions, label, and tool ID of the first waypoint in the specified variables.

In this example, the path planned by Mech-Vision consists of three waypoints: the first waypoint is the approach waypoint of picking (P071), the second waypoint is the picking waypoint (P072), and the third waypoint is the departure waypoint of picking (P073). Please store the planned path based on the actual Mech-Vision project.

Move to the approach waypoint of picking

'follow the planned path to pick
'move to approach waypoint of
'picking
MOVJ P071 VJ=50.00 PL=0

The robot moves to the approach waypoint of picking (the position represented by P071).

Move to the picking waypoint

'move to picking waypoint
MOVJ P072 VJ=10.00 PL=0

The robot moves to the picking waypoint (the position represented by P072).

Set DOs to perform picking

'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE

After the robot moves to the picking waypoint, you can set a DO command (such as “DOUT OT#(1) ON”) to control the robot to use the tool to perform picking. Please set DO commands based on the actual situation.

PAUSE indicates to pause the program execution. If you have added a statement to set a DO command, you can delete the PAUSE statement here.

Move to the departure waypoint of picking

'move to departure waypoint of
'picking
MOVJ P073 VJ=50.00 PL=0

The robot moves to the departure waypoint of picking (the position represented by P073).

Move to the intermediate waypoint

'move to intermediate waypoint of
'placing
MOVJ C00002 VJ=50.00

The robot moves to a intermediate waypoint between the departure waypoint of picking and the approach waypoint of placing.

Adding intermediate waypoints can ensure smooth robot motion and avoid unnecessary collisions. You can add multiple intermediate waypoints according to the actual situation.
You need to teach the intermediate waypoint (C00002) in advance. For information about how to teach the waypoint, see Teach Calibration Start Point in the calibration document.

Move the robot to the approach waypoint of placing

'move to approach waypoint of
'placing
MOVL C00003 V=166.6 PL=0

The robot moves from the intermediate waypoint to the approach waypoint of placing.

Adding approach waypoints of placing can prevent the robot from colliding with objects (such as bins) in the scene when moving.
You need to teach the approach waypoint of placing (C00003) in advance. For information about how to teach the waypoint, see Teach Calibration Start Point in the calibration document.

Move to the placing waypoint

'move to placing waypoint
MOVL C00004 V=50.0 PL=0

The robot moves from the approach waypoint of placing to the placing waypoint.

The placing waypoint should be located at a safe distance from other stations, personnel, and equipment, and should not exceed the robot’s maximum reach.
You need to teach the placing waypoint (C00004) in advance. For information about how to teach the waypoint, see Teach Calibration Start Point in the calibration document.

Set DO commands to perform placing

'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE

After the robot moves to the placing waypoint, you can set a DO command (such as “DOUT OT#(1) OFF”) to control the robot to use the tool to perform placing. Please set DO commands based on the actual situation.

PAUSE indicates to pause the program execution. If you have added a statement to set a DO command, you can delete the PAUSE statement here.

Move the robot to the departure waypoint of placing

'move to departure waypoint of
'placing
MOVL C00005 V=166.6 PL=0

The robot moves from the placing waypoint to the departure waypoint of placing.

Adding departure waypoints of placing can prevent the robot from colliding with objects (such as bins) in the scene when moving.
You need to teach the departure waypoint of placing (C00005) in advance. For information about how to teach the waypoint, see Teach Calibration Start Point in the calibration document.

Move to the home position

'move back to robot home position
MOVJ C00006 VJ=50.00

The robot moves from the departure waypoint of placing to the home waypoint again.

You should teach the home position (C00006) in advance. For detailed instructions, see Teach Calibration Start Point in the calibration document.

We Value Your Privacy

We use cookies to provide you with the best possible experience on our website. By continuing to use the site, you acknowledge that you agree to the use of cookies. If you decline, a single cookie will be used to ensure you're not tracked or remembered when you visit this website.

I accept

I don't accept