Example Program 13: MM_S13_Vis_MoveInAdvance
Program Introduction
Description |
After the Mech-Vision project is triggered to run, the robot moves in advance after the camera finishes capturing images without waiting for the Mech-Vision project to stop running. This example program is applicable to scenarios where the camera mounting method is eye in hand. |
File path |
You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the |
Project |
Mech-Vision project (the camera mounting method is eye in hand) |
Prerequisites |
|
| This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario. |
Program Description
This part describes the MM_S13_Vis_MoveInAdvance example program.
| The only difference between the MM_S13_Vis_MoveInAdvance example program and the MM_S1_Vis_Basic example program is that MM_S13_Vis_MoveInAdvance can move the robot after the camera captures images (this code of this feature is bolded). As such, only the feature of moving the robot after the camera captures images is described in the following part. For information about the parts of MM_S13_Vis_MoveInAdvance that are consistent with those of MM_S1_Vis_Basic, see Example Program 1: MM_S1_Vis_Basic. |
1: !-------------------------------- ;
2: !FUNCTION: trigger Mech-Vision ;
3: !then move to wait position and ;
4: !get vision pose in EIH setup ;
5: !Mech-Mind, 2023-12-25 ;
6: !-------------------------------- ;
7: ;
8: !set current uframe NO. to 0 ;
9: UFRAME_NUM=0 ;
10: !set current tool NO. to 1 ;
11: UTOOL_NUM=1 ;
12: !move to robot home position ;
13:J P[1] 100% FINE ;
14: !initialize communication ;
15: !parameters(initialization is ;
16: !required only once) ;
17: CALL MM_INIT_SKT('8','127.0.0.1',50000,5) ;
18: !move to image-capturing position ;
19:L P[2] 1000mm/sec FINE ;
20: !trigger NO.1 Mech-Vision project ;
21: CALL MM_START_VIS(1,0,1,10) ;
22: !move to wait position for ;
23: !picking ;
24:J P[3] 50% CNT100 ;
25: !get vision result from NO.1 ;
26: !Mech-Vision project ;
27: CALL MM_GET_VIS(1,51,53) ;
28: !check whether vision result has ;
29: !been got from Mech-Vision ;
30: !successfully ;
31: IF R[53]<>1100,JMP LBL[99] ;
32: !save first vision point data to ;
33: !local variables ;
34: CALL MM_GET_POS(1,60,70,80) ;
35: !move to intermediate waypoint ;
36: !of picking ;
37:J P[4] 50% CNT100 ;
38: !move to approach waypoint ;
39: !of picking ;
40:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
41: !move to picking waypoint ;
42:L PR[60] 300mm/sec FINE ;
43: !add object grasping logic here, ;
44: !such as "DO[1]=ON" ;
45: PAUSE ;
46: !move to departure waypoint ;
47: !of picking ;
48:L PR[60] 1000mm/sec FINE Tool_Offset,PR[1] ;
49: !move to intermediate waypoint ;
50: !of placing ;
51:J P[5] 50% CNT100 ;
52: !move to approach waypoint ;
53: !of placing ;
54:L P[6] 1000mm/sec FINE Tool_Offset,PR[2] ;
55: !move to placing waypoint ;
56:L P[6] 300mm/sec FINE ;
57: !add object releasing logic here, ;
58: !such as "DO[1]=OFF" ;
59: PAUSE ;
60: !move to departure waypoint ;
61: !of placing ;
62:L P[6] 1000mm/sec FINE Tool_Offset,PR[2] ;
63: !move back to robot home position ;
64:J P[1] 100% FINE ;
65: END ;
66: ;
67: LBL[99:vision error] ;
68: !add error handling logic here ;
69: !according to different ;
70: !error codes ;
71: !e.g.: status=1003 means no ;
72: !point cloud in ROI ;
73: !e.g.: status=1002 means no ;
74: !vision results ;
75: PAUSE ;The workflow corresponding to the above example program code is shown in the figure below.
The table below describes the feature of moving the robot after the camera captures images. You can click the hyperlink to the command name to view its detailed description.
| Feature | Code and description | ||||
|---|---|---|---|---|---|
Move the robot after the camera captures images |
In eye in hand scenarios, to ensure that the robot can move after the camera captures images without waiting for the Mech-Vision project to finish running, you can go to in the top toolbar of Mech-Vision and select Return “1102: Successfully triggered” after the capture. Once this option is selected, the robot will start to move after it triggers the Mech-Vision project and receives “1102: Successfully triggered”, thus reducing the cycle time. If the option is not selected and the Mech-Vision project is started successfully, the vision system will return status code 1102 to the robot immediately. The robot cannot move at this point because the robot cannot determine whether the camera has finished capturing images. In this case, the robot has to wait for the Mech-Vision project to finish before moving.
The above code indicates that the robot can move to the waiting waypoint of picking (P[3], you have to teach this waypoint in advance) after image capturing. This indicates that the Mech-Vision project can be run at the same time when the robot moves to shorten the cycle time.
|