Example Program 13: MM_S13_Vis_MoveInAdvance
Program Introduction
Description |
After the Mech-Vision project is triggered to run, the robot moves in advance after the camera finishes capturing images without waiting for the Mech-Vision project to stop running. This example program is applicable to scenarios where the camera mounting method is eye in hand. |
File path |
You can navigate to the installation directory of Mech-Vision and Mech-Viz and find the file by using the |
Project |
Mech-Vision project (the camera mounting method is eye in hand) |
Prerequisites |
|
| This example program is provided for reference only. Before using the program, please modify the program according to the actual scenario. |
Program Description
This part describes the MM_S13_Vis_MoveInAdvance example program.
| The only difference between the MM_S13_Vis_MoveInAdvance example program and the MM_S1_Vis_Basic example program is that MM_S13_Vis_MoveInAdvance can move the robot after the camera captures images (this code of this feature is bolded). As such, only the feature of moving the robot after the camera captures images is described in the following section. For information about the parts of MM_S13_Vis_MoveInAdvance that are consistent with those of MM_S1_Vis_Basic, see Example Program 1: MM_S1_Vis_Basic. |
NOP
'--------------------------------
'FUNCTION: trigger Mech-Vision
'project then move to wait
'position and get vision pose in
'EIH setup
'Mech-Mind, 2023-12-25
'--------------------------------
'clear I50 to I69
CLEAR I050 20
'initialize p variables
SUB P070 P070
SUB P071 P071
'set 100mm to z of P070
SETE P070 (3) 100000
'move to robot home position
MOVJ C00000 VJ=50.00
'initialize communication
'parameters (initialization is
'required only once)
CALL JOB:MM_INIT_SOCKET ARGF"192.168.170.22;50000;1"
'move to image-capturing position
MOVJ C00001 VJ=50.00 PL=0
'open socket connection
CALL JOB:MM_OPEN_SOCKET
'trigger NO.1 Mech-Vision project
CALL JOB:MM_START_VIS ARGF"1;0;2;30"
'move to wait position for
'picking
MOVJ C00002 VJ=50.00
'get vision result from NO.1
'Mech-Vision project
CALL JOB:MM_GET_VISDATA ARGF"1;51;52"
'check whether vision result has
'been got from Mech-Vision
'successfully
IFTHENEXP I052<>1100
'add error handling logic here
'according to different error
'codes
'e.g.: I052=1003 means no point
'cloud in ROI
'e.g.: I052=1002 means no
'vision result
PAUSE
ENDIF
'close socket connection
CALL JOB:MM_CLOSE_SOCKET
'save first vision point data to
'local variables
CALL JOB:MM_GET_POSE ARGF"1;71;61;62"
'move to intermediate waypoint of
'picking
MOVJ C00003 VJ=50.00
'move to approach waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to picking waypoint
MOVL P071 V=50.0 PL=0
'add object grasping logic here,
'such as DOUT OT#(1) ON
PAUSE
'move to departure waypoint of
'picking
SFTON P070
MOVL P071 V=166.6 PL=0
SFTOF
'move to intermediate waypoint of
'placing
MOVJ C00004 VJ=50.00
'move to approach waypoint of
'placing
MOVL C00005 V=166.6 PL=0
'move to placing waypoint
MOVL C00006 V=50.0 PL=0
'add object releasing logic here,
'such as DOUT OT#(1) OFF
PAUSE
'move to departure waypoint of
'placing
MOVL C00007 V=166.6 PL=0
'move back to robot home position
MOVJ C00008 VJ=50.00
ENDThe workflow corresponding to the above example program code is shown in the figure below.
The table below describes the feature of moving the robot after the camera captures images. You can click the hyperlink to the command name to view its detailed description.
| Feature | Code and description | ||||
|---|---|---|---|---|---|
Move the robot after the camera captures images |
In eye in hand scenarios, to ensure that the robot can move after the camera captures images without waiting for the Mech-Vision project to finish running, you can go to in the top toolbar of Mech-Vision and select Return “1102: Successfully triggered” after the capture. Once this option is selected, the robot will start to move after it runs the MM_START_VIS and receives “1102: Successfully triggered”, thus reducing the cycle time. If the option is not selected and the Mech-Vision project is started successfully, the vision system will return status code 1102 to the robot immediately. The robot cannot move at this point because the robot cannot determine whether the camera has finished capturing images. In this case, the robot has to wait for the Mech-Vision project to finish before moving.
In the above code, C00002 indicates the waiting waypoint of picking. The robot moves to the waiting waypoint of picking after image capturing. This indicates that the Mech-Vision project can be run at the same time when the robot moves to shorten the cycle time.
|